[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

["Sam James" <sam@gentoo.org>]

commit:     18823cfea1ab9bfb4d96b56b6d2e5d93f481f77a
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 16 07:02:11 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Sep 16 07:03:32 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=18823cfe

sys-kernel/gentoo-kernel-bin: patch 6.1.53 for NFS issue

Bring us up to genpatches-6.1-60 for a backported NFS fix.

Bug: https://bugs.gentoo.org/914204
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   4 +
 .../gentoo-kernel-bin-6.1.53-r1.ebuild             | 127 +++++++++++++++++++++
 2 files changed, 131 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 1d9b4b0c9710..b745b1487857 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -44,6 +44,10 @@ DIST gentoo-kernel-6.1.53-1.amd64.gpkg.tar 72509440 BLAKE2B 1cd4c14f7f52f8a8bf0f
 DIST gentoo-kernel-6.1.53-1.arm64.gpkg.tar 65218560 BLAKE2B 576f4e81241184842d38e1fecc17635a7fcb8657a7ab1b96f629d92ae5231bdeca08c4cedade4d75c07a915d3584ba2f494b4cb92a0d0450e74d0f5bc6b555eb SHA512 07bdac4e29a292631b560d409f0eaf256a9d51d90293051d81b368be13d02ca264e23135fff8e51dd932720fab7d71f66418279ea237f541792e52bc4d5792e3
 DIST gentoo-kernel-6.1.53-1.ppc64le.gpkg.tar 59811840 BLAKE2B cee9232bdae834b254321018b485b61b3083cdd01bcdaada32162f8513af67596534efd653fe0352fcbd093d0532f7c74b28ede6993bc22e4544676306dd8dd5 SHA512 0ebc131f6a0e6ef882f584faa1d2c963ba8c3d461326719617bcb97488bd0de8d45453c530e8b41ed4f2b6fb29f6bf29893350f09cd9dfbeaf7d5dc9a101eb95
 DIST gentoo-kernel-6.1.53-1.x86.gpkg.tar 61972480 BLAKE2B e87669b4450e1955ef82b781eb4880be2dbaf7b33b9fc90ac04878a7a57c80bd75f7e8388517937dda2e651eb9c83115cac21cefd055739736dd09a23e135712 SHA512 71f36656fc836794b51e2a6be746272f408456e3d26a19aa28b12c5eedeb2344bc3e99f8d6fc19e63b0e1f36725d63fb90b2388b9eee3d7555ef93e9fbf37f64
+DIST gentoo-kernel-6.1.53-r1-1.amd64.gpkg.tar 72478720 BLAKE2B 9bce87f82539a8f6dd68f3bfe17ca7fce0f34353fa55fc3bd21324c15545d7843a627e690a3354b2ef780165cca01ea4c22bd8782a5baf3f2602cc8a8a7bf1d8 SHA512 dfcc892437c33fbced96946ccd02131995cdb07b13a00cfeefd469b9f9eff5673e41f713b4399a0aa3aa291fe479051a4f706e4c01993eaf1b8ac4f4b60382ce
+DIST gentoo-kernel-6.1.53-r1-1.arm64.gpkg.tar 65208320 BLAKE2B 4148c417ce291133c6b7fcca376f9db7d9f8a5254ef263146b15b29fb12a93af38a6082e6c49c50c09e831587003cdb459e645e759d3f6e095cccaf93c76994d SHA512 da6fb9218c69f4da49bc1de22a47943460bbd4630c75b0e3b75952e7991c545db96f1ff753b969d85997d2152f910401086f0a68926ea0814eeb979da912b4d1
+DIST gentoo-kernel-6.1.53-r1-1.ppc64le.gpkg.tar 59822080 BLAKE2B 657c66102de78813e80599101c63a19b75a113ab581c5af1c284f205ffbcee5257b55ddcdb7fa2dbf491dcf7619c3f23678a9cbd787b4e375e7b15991782657c SHA512 756f30a9cbea8864443e38096804491cbe113a7f8f781b82ff4229392b34befa7eb0985036d02092994041a2eccbd69a9101e04051f0f4f9f5c1dd3ef948673d
+DIST gentoo-kernel-6.1.53-r1-1.x86.gpkg.tar 61962240 BLAKE2B 1809d9cd755a88ed2513658f02c033d6a7ed7acf821f2e179e1812c9afb1fef3d947e6dfd6fedcf1cabfb77b05820db4d6d888ffc7f45facfb657e9ec614a986 SHA512 68ad5671a6f8d5e9a6e562ba5bfbb1ea2427944bc8dd22fff88bd5b8114271640e9161e6f20fc0c2c6de66ca2db78cf585b9296897490634171898346f71d560
 DIST gentoo-kernel-6.4.16-1.amd64.gpkg.tar 81786880 BLAKE2B adbe09acd265ad50d6cc362be262b94b10fcfc517dd5e463007eef455477c1de7b9340ca472a60c28bd7fbcc02f8538c25b036d736e656500bf749a67ba914cb SHA512 cd3c7a1641b500620f3a8770a2994d53161582ac3c5eca72cb64e4e15cbbd40db1d8bf839a5427662574eb8d4124f2c6b2b74dc087e70b6992d2c522939b87a5
 DIST gentoo-kernel-6.4.16-1.arm64.gpkg.tar 71290880 BLAKE2B b42a0cf9dc72716eaf9d14137c06d8229e06a4431b50ae269bada18d977c9fad3eef9b7b5181cb8f7b35b88987ab2db17bd85b1742220ebc8d022f50eef066f6 SHA512 789f3bb759b470f4e29735706a73c64df0646c882c6bad3b051dd395faa89ce2c1cafceec34ff28d9c5c4adf6cca4f5eec6b875bf0e398c925431f9086f3e756
 DIST gentoo-kernel-6.4.16-1.ppc64le.gpkg.tar 63488000 BLAKE2B e0604a0b4bf8d7aa7a257798148fac11e0c4a072e0a775c57ddfa74681a265a775081b91e64732e45656fa303e817c2afa8f5c281ad2c5ffdc4373674d5917d3 SHA512 4aa5e73de475bd77f5a0e155033945b5770e761433e3cd983fe5efface2b971545439e99d0c048ed3bc21aa825d3eefa4ecf6615bd0099374c50cc0fd9e90243

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-6.1.53-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-6.1.53-r1.ebuild
new file mode 100644
index 000000000000..83c6a5e4fa8f
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-6.1.53-r1.ebuild
@@ -0,0 +1,127 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit kernel-install toolchain-funcs unpacker
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${PF/-bin}-1
+
+DESCRIPTION="Pre-built Linux kernel with Gentoo patches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	amd64? (
+		https://dev.gentoo.org/~mgorny/binpkg/amd64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.amd64.gpkg.tar
+	)
+	arm64? (
+		https://dev.gentoo.org/~mgorny/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.arm64.gpkg.tar
+	)
+	ppc64? (
+		https://dev.gentoo.org/~mgorny/binpkg/ppc64le/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.ppc64le.gpkg.tar
+	)
+	x86? (
+		https://dev.gentoo.org/~mgorny/binpkg/x86/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.x86.gpkg.tar
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}
+"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	app-alternatives/yacc
+"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH="$(tc-arch-kernel)"
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "${BINPKG}/image/usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/${BINPKG}/image/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"${BINPKG}/image/lib/modules/${KPV}"
+}
+
+src_install() {
+	mv "${BINPKG}"/image/{lib,usr} "${ED}"/ || die
+
+	# FIXME: requires proper mount-boot
+	if [[ -d ${BINPKG}/image/boot/dtbs ]]; then
+		mv "${BINPKG}"/image/boot "${ED}"/ || die
+	fi
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}