[gentoo-commits] repo/gentoo:master commit in: app-accessibility/orca/

["Matt Turner" <mattst88@gentoo.org>]

commit:     9070892d52b627bc74c8ee75bba5f05009f49822
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri Sep 15 14:34:50 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Sep 15 16:52:54 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9070892d

app-accessibility/orca: Version bump to 45.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32807
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 app-accessibility/orca/Manifest         |  1 +
 app-accessibility/orca/orca-45.0.ebuild | 59 +++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/app-accessibility/orca/Manifest b/app-accessibility/orca/Manifest
index 943e4d658a20..209f2910650e 100644
--- a/app-accessibility/orca/Manifest
+++ b/app-accessibility/orca/Manifest
@@ -1,2 +1,3 @@
 DIST orca-44.1.tar.xz 3760772 BLAKE2B 1e2825e9183b86563d85f106f80b7fa84d7d0cc06c818cb72c2a307c9c85a421cbbfc581df7829afde558ddf468bc048382d059ae995661a5163d390585961b4 SHA512 951a60b7efd9b61762404c20b62d476c1ebc3fc2662c0be1feef307fa1761feb5195c89ce725db1585dde4c39d96e1aa74c2b5c934115a3c2669880c3c7ac200
+DIST orca-45.0.tar.xz 3949908 BLAKE2B 135dff79cda2a1a116256f2c1b68a40d29b17e5507fd3407d61dfc2478339aab1d7627c3aaac5f388a0140008e8a492820f0e56caac7ea83216c50f4f3fa32d8 SHA512 3213d5f0b8e0eacc5daad3df3e521548c5e6dd5ad8584e50d60a7fd054fee86793e956d3db3dcdc223d34d72bcfbfa0b436bc40f6e965528eafa2abf36259c83
 DIST orca-45.rc.tar.xz 3923500 BLAKE2B e7f919e0badf804612d2c778abab598437dca812507b2d5e5ba6b7fc34897ed8baaa739d3f72a1e56db13badf725675d468a525ab663db6e1eaa08191abd3654 SHA512 897e667b7c9fd98d01eafb79f1fcd02da078fa5d023a22301ba7ea2a84cd18c05684c4c297a1edd22232c5f72d64fa5fb78b35037ea4d8cfd3fdfa350c3500a7

diff --git a/app-accessibility/orca/orca-45.0.ebuild b/app-accessibility/orca/orca-45.0.ebuild
new file mode 100644
index 000000000000..d9924573dce0
--- /dev/null
+++ b/app-accessibility/orca/orca-45.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="https://wiki.gnome.org/Projects/Orca"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="+braille"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=app-accessibility/at-spi2-core-2.48:2[introspection]
+	>=dev-libs/glib-2.28:2
+	media-libs/gstreamer:1.0[introspection]
+	>=x11-libs/gtk+-3.6.2:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+		>=dev-python/pygobject-3.18:3[${PYTHON_USEDEP}]
+	')
+	braille? (
+		$(python_gen_cond_dep '
+			>=app-accessibility/brltty-5.0-r3[python,${PYTHON_USEDEP}]
+			dev-libs/liblouis[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		>=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_USEDEP}]
+		>=dev-python/pyatspi-2.46[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+	')
+	x11-libs/libwnck:3[introspection]
+	x11-libs/pango[introspection]
+"
+BDEPEND="
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+#	app-text/yelp-tools
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_with braille liblouis)
+}
+
+src_install() {
+	gnome2_src_install
+	python_optimize
+}