[gentoo-commits] repo/gentoo:master commit in: dev-libs/libportal/, profiles/

[gentoo-commits] repo/gentoo:master commit in: dev-libs/libportal/, profiles/

[Matt Turner]

commit:     e9ec8163901179c69a6efa92db92e5c039236d1e
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri Sep  8 14:59:38 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Sep 10 14:01:08 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e9ec8163

dev-libs/libportal: Version bump to 0.7.1

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32688
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libportal/Manifest               |   1 +
 dev-libs/libportal/libportal-0.7.1.ebuild | 109 ++++++++++++++++++++++++++++++
 profiles/package.mask                     |   1 +
 3 files changed, 111 insertions(+)

diff --git a/dev-libs/libportal/Manifest b/dev-libs/libportal/Manifest
index ad68bc5788d2..b1d905f79160 100644
--- a/dev-libs/libportal/Manifest
+++ b/dev-libs/libportal/Manifest
@@ -1 +1,2 @@
 DIST libportal-0.6.tar.xz 63816 BLAKE2B 396659bd1fd00885b49363a3f6fc0ccf5324c87417cfcab48c966ef61ab2fa35d300be84656261fdf4313b77fc13058d7b7c9aadb0591c1ef17b80434f8ec19d SHA512 f5f76a0dd0c66521b745c276e41f298addbbd41dd5fb3df9381ea85c122387878cb0e51ffac1e17f9e82548ab222d2c2fe92ab0d018de8a9ae9b2dfd65e454c4
+DIST libportal-0.7.1.tar.xz 74268 BLAKE2B b519fa88735d640a74e18cc791ec69862f136b793a7c855b1f3873cf6b15626d69088747f1a7ff54f8cd96f79e82e3df31e5349e3da57906e769b8f809f4ba34 SHA512 cbc50bfd86787fffc975fc53835acc6c3c0fd54b7ee02fce1983f1bd0fc40b15a0537780cd5e943ecedcf951840080a0f55a23a96e706223e52a6144ee70332c

diff --git a/dev-libs/libportal/libportal-0.7.1.ebuild b/dev-libs/libportal/libportal-0.7.1.ebuild
new file mode 100644
index 000000000000..873af4b69fc7
--- /dev/null
+++ b/dev-libs/libportal/libportal-0.7.1.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit meson python-any-r1 vala virtualx
+
+DESCRIPTION="Flatpak portal library"
+HOMEPAGE="https://github.com/flatpak/libportal"
+SRC_URI="https://github.com/flatpak/libportal/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-3"
+SLOT="0/1-1-1-1" # soname of libportal{,-gtk3,-gtk4,-qt5}.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="gtk gtk-doc +introspection qt5 test +vala"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.58:2
+	introspection? ( dev-libs/gobject-introspection:= )
+	gtk? (
+		x11-libs/gtk+:3
+		gui-libs/gtk:4
+	)
+	qt5? (
+		dev-qt/qtcore:=
+		dev-qt/qtgui:=
+		dev-qt/qtx11extras:=
+		dev-qt/qtwidgets:=
+	)
+"
+DEPEND="${RDEPEND}
+	qt5? (
+		test? ( dev-qt/qttest:= )
+	)
+"
+BDEPEND="
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+	qt5? (
+		test? ( dev-qt/linguist-tools )
+	)
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+		')
+	)
+	vala? ( $(vala_depend) )
+"
+
+python_check_deps() {
+	python_has_version \
+		"dev-python/pytest[${PYTHON_USEDEP}]" \
+		"dev-python/dbus-python[${PYTHON_USEDEP}]" \
+		"dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	if use test; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature gtk backend-gtk3)
+		$(meson_feature gtk backend-gtk4)
+		$(meson_feature qt5 backend-qt5)
+		-Dportal-tests=false
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc docs)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Tests only exist for Qt5
+	if use qt5; then
+		virtx meson_src_test
+	else
+		# run meson_src_test to notice if tests are added
+		meson_src_test
+	fi
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-1 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}

diff --git a/profiles/package.mask b/profiles/package.mask
index 9c2286d89cf5..7693aace38ff 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -462,6 +462,7 @@ acct-group/spi
 >=dev-libs/gobject-introspection-1.77
 >=dev-libs/gobject-introspection-common-1.77
 >=dev-libs/libdex-0.3.0
+>=dev-libs/libportal-0.7
 >=dev-util/gdbus-codegen-2.77
 >=dev-util/glib-utils-2.77
 >=games-puzzle/gnome-sudoku-45_alpha