[gentoo-commits] repo/gentoo:master commit in: profiles/, dev-libs/gobject-introspection/

["Matt Turner" <mattst88@gentoo.org>]

commit:     4767794699c15871b7759a2d2b53717cbe269d40
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri Sep  8 15:14:33 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Sep  9 00:16:59 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=47677946

dev-libs/gobject-introspection: Version bump to 1.78.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/gobject-introspection/Manifest            |  1 +
 .../gobject-introspection-1.78.0.ebuild            | 79 ++++++++++++++++++++++
 profiles/package.mask                              |  1 +
 3 files changed, 81 insertions(+)

diff --git a/dev-libs/gobject-introspection/Manifest b/dev-libs/gobject-introspection/Manifest
index 2d9f357291f1..aeb50dcc6068 100644
--- a/dev-libs/gobject-introspection/Manifest
+++ b/dev-libs/gobject-introspection/Manifest
@@ -1 +1,2 @@
 DIST gobject-introspection-1.76.1.tar.xz 1055416 BLAKE2B 2251c34b543c95f95bdec6853c8234db1b2e6271e729eaa5abf28e39c7718b326e0813a1214c62fb4634fd11218c4c856e6651de09081b01c9fcf8f73b8cf316 SHA512 84331a30f8854d2259609650c21aadd6363ea1417a75828bd395f8f4346da1c6d6550cff5f2c9f5f6fd6fbf2a9d27b5880c2ee1616fa905c5f362384d481a916
+DIST gobject-introspection-1.78.0.tar.xz 1060136 BLAKE2B ae95ad5cec48f0eb001e1ba65cd6e88ab8846d1ab6721ac421f6077f1a69fca1989a0631a7c852361d4b92f7f25503e3f505e734055d3f61530f829924f37972 SHA512 b7749295437255d45f5f842195315105d7b85bddb20bf205c7bd7f0c9e9e77fe1db2c84af6d784b54fb0d8eef488895f5eb9439ccf4ca81d03e802802b13e5dd

diff --git a/dev-libs/gobject-introspection/gobject-introspection-1.78.0.ebuild b/dev-libs/gobject-introspection/gobject-introspection-1.78.0.ebuild
new file mode 100644
index 000000000000..56ef5420626c
--- /dev/null
+++ b/dev-libs/gobject-introspection/gobject-introspection-1.78.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="xml(+)"
+inherit gnome.org meson python-single-r1 xdg
+
+DESCRIPTION="Introspection system for GObject-based libraries"
+HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+IUSE="doctool gtk-doc test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+# virtual/pkgconfig needed at runtime, bug #505408
+RDEPEND="
+	>=dev-libs/gobject-introspection-common-${PV}
+	>=dev-libs/glib-2.$(($(ver_cut 2) - 1)).0:2
+	dev-libs/libffi:=
+	doctool? (
+		$(python_gen_cond_dep '
+			dev-python/mako[${PYTHON_USEDEP}]
+			dev-python/markdown[${PYTHON_USEDEP}]
+		')
+	)
+	virtual/pkgconfig
+	${PYTHON_DEPS}
+"
+# Wants real bison, not app-alternatives/yacc
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.19
+		app-text/docbook-xml-dtd:4.3
+		app-text/docbook-xml-dtd:4.5
+	)
+	sys-devel/bison
+	sys-devel/flex
+	test? (
+		x11-libs/cairo[glib]
+		$(python_gen_cond_dep '
+			dev-python/mako[${PYTHON_USEDEP}]
+			dev-python/markdown[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature test cairo)
+		$(meson_feature doctool)
+		#-Dglib_src_dir
+		$(meson_use gtk-doc gtk_doc)
+		#-Dcairo_libname
+		-Dpython="${EPYTHON}"
+		#-Dgir_dir_prefix
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"/usr/bin/
+	python_optimize "${ED}"/usr/$(get_libdir)/gobject-introspection/giscanner
+
+	# Prevent collision with gobject-introspection-common
+	rm -v "${ED}"/usr/share/aclocal/introspection.m4 \
+		"${ED}"/usr/share/gobject-introspection-1.0/Makefile.introspection || die
+	rmdir "${ED}"/usr/share/aclocal || die
+}

diff --git a/profiles/package.mask b/profiles/package.mask
index f6c4cb827998..21d5ca7e4fa9 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -413,6 +413,7 @@ acct-group/spi
 >=dev-cpp/gtkmm-4.11
 >=dev-libs/gjs-1.77
 >=dev-libs/glib-2.77
+>=dev-libs/gobject-introspection-1.77
 >=dev-libs/gobject-introspection-common-1.77
 >=dev-libs/libdex-0.3.0
 >=dev-util/gdbus-codegen-2.77