[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

["Michał Górny" <mgorny@gentoo.org>]

commit:     83bba299b5541d4c9a00774717f8c666ae055fa2
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Sep  4 12:46:37 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Sep  4 12:46:37 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=83bba299

dev-python/django: Bump to 4.2.5

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest            |  2 +
 dev-python/django/django-4.2.5.ebuild | 98 +++++++++++++++++++++++++++++++++++
 2 files changed, 100 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index e669651ca89e..4333ee26b738 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -4,3 +4,5 @@ DIST Django-4.1.10.checksum.txt 2559 BLAKE2B 103d1de6ec0da3a2440ea339388e2525ef5
 DIST Django-4.1.10.tar.gz 10513572 BLAKE2B 0f1ef14fcf40cb6952fc459855a4e633e2d21c252a4732b27f8e980af6277ef69869a65a7bd0508fd7cdbd82742cb838170d965219b2919679ac92abfef087b6 SHA512 f31ad6fcce3bea0e0f895ec14b063485edec70872aa9c317243a38fb49b6c863159afc5aa31fb5c7a824c737f520f25cfbef55781c23fa0a204b61cefc66fb01
 DIST Django-4.2.4.checksum.txt 2571 BLAKE2B 062b53fc43bc12343a11161904c8938fe852f8868c4de6282f567b495992ce06494d327b495b03c8dc92cccf76396efe4b12dfbd0616d2b3c58c2e6239760e63 SHA512 0d4599816935645f141d1267b6ca22db238b614576c7225da9ba2cc84957e5668be25654a10a1bfc715e9e6e355db9a6f824dc11303fcb14af10a60a056950d4
 DIST Django-4.2.4.tar.gz 10393648 BLAKE2B 1c0c19f58bc3e02d12593b942eca23f5eaf8ee5106f6d518d97fad46f0c65dcdd94b192142969d95be9537fb1cca08a0ca55e089702d8bd51122f381adc0a319 SHA512 e773a54ce6ad82abfac462f543c54e414c216ecb28025fab9bf92e4f1add4fbc9acf831e765b638f560a71f6d7591eaa1a8ed6175c3379d5662a94b6a64f2c77
+DIST Django-4.2.5.checksum.txt 2554 BLAKE2B 7c0e9719a28a19bccbf8dc95e2d4ea07f5307b6df44f2d47c1a2a426a3021f0e1c0f83e93df256c64bb11a9d5d45605b9fe22ac5ae20d70f8fcb5a69d5859979 SHA512 4aaab80511a0442fb65ead16a468e2d2a152f1fea6c9a631e79933c6be43e0077aa443cbe13c6a9776b5a897b57c976d9b7b3e1472156b1a3e3f7d865ca79eb3
+DIST Django-4.2.5.tar.gz 10418606 BLAKE2B 271745dce0ec4d03f118afb328d0154e3e42a29775cb05dd8271f114770e568da19f0c9e3a2dd28379ad0e7dd0d89db37cd64856d2af5927fbe02fccd7bf1e91 SHA512 bf6a7bbb8f0a47d1e97ad9a231340567e5ee10bf399be6ff0edc2538db8cb8a082ea93529954140e7fab0672654e6fe9238d61381419495b53737b4a6dc9de1e

diff --git a/dev-python/django/django-4.2.5.ebuild b/dev-python/django/django-4.2.5.ebuild
new file mode 100644
index 000000000000..0afb8410b128
--- /dev/null
+++ b/dev-python/django/django-4.2.5.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/asgiref-4[${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.6.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.3.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20230606 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/django-4.0-bashcomp.patch
+	"${FILESDIR}"/django-4.2.3-py312.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+}