[gentoo-commits] repo/gentoo:master commit in: dev-python/sphinx/

["Michał Górny" <mgorny@gentoo.org>]

commit:     21ae1e1b7c5eea6c662d58a47059502b979830c1
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 31 12:55:31 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Aug 31 13:05:59 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=21ae1e1b

dev-python/sphinx: Bump to 7.2.5

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/sphinx/Manifest            |   1 +
 dev-python/sphinx/sphinx-7.2.5.ebuild | 125 ++++++++++++++++++++++++++++++++++
 2 files changed, 126 insertions(+)

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index aa272082340c..478df0cf386c 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -8,3 +8,4 @@ DIST sphinx-7.2.0.gh.tar.gz 7060825 BLAKE2B c911e49903b3682a08271871ec79b907f41a
 DIST sphinx-7.2.2.gh.tar.gz 7061263 BLAKE2B 71b9ad7240bc487efb5fa446799aa3d7dd1fd24eb3340ec27b8642ee4eb464de1941912e4106f1d1038c04a8b98cfd782f336b8cf4d7a3a24b858931262ac66c SHA512 a15232c6e50ea2263e9dc6ece79e906d787e541e6a5d0c85c8c9a6a50dd0c95da3743023928be1b05cccdcf79c67f1d5b16ad300e5d67da2a511e81a2c54608f
 DIST sphinx-7.2.3.gh.tar.gz 7063906 BLAKE2B 346ac3de17ae02b9b5167f3a13bf52ead9712b3ef2e71fc3d63882ff413e48b2b3c6688cc1eef9545193ef51ac0a1a0d56dad4442b8c8c79ae0b91159510486b SHA512 1bafc21415e606430da178e1ea43e6abb8ab24fdef0f4f94a049cde32d6dead71417454195fa23c00f674ef50b2ee903a9fd31d817d4c49fcfbcd06cfa4b4835
 DIST sphinx-7.2.4.gh.tar.gz 7064614 BLAKE2B 806717bf44b4d78cb28f0a0255d8be82260222c4d9f6bdc9d00269037b67725efd076a174f8863f8310a1a03809628f28e19599e2a24fb4235abefc68ea29c9d SHA512 18f926f34042a1b85d42f62ac684d75472422fd21d33f1f06c8ccc4d8ab27edee27f6252e1515d9ab2789273e928548d9452f6e9b8ee31f8344d6a2782d65057
+DIST sphinx-7.2.5.gh.tar.gz 7067300 BLAKE2B 27e0c7f8916e36990e214f4c5013434ff0e1e0045513efdf4b16eb56f0865d4cb52db802a41e7f62cc18aae58457d03be6720c129854cc63f35a7537b361ba2d SHA512 6006ebd8d9034ef9bcb4963dcc1029503b4f9895d65c550cdbf0cbb898759127cca66079849703e17cae8420ed7cc43f6bd567b5cfa8127fb9d3be916be52c93

diff --git a/dev-python/sphinx/sphinx-7.2.5.ebuild b/dev-python/sphinx/sphinx-7.2.5.ebuild
new file mode 100644
index 000000000000..89674848a183
--- /dev/null
+++ b/dev-python/sphinx/sphinx-7.2.5.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.9[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.21[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.18.1[${PYTHON_USEDEP}]
+	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.14[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.25.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-2.0[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.9[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+	!dev-python/namespace-sphinxcontrib
+"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		app-text/dvipng
+		>=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
+		dev-python/filelock[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-67.0[${PYTHON_USEDEP}]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		virtual/imagemagick-tools[jpeg,png,svg]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+	"${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# we can't use distutils_enable_sphinx because it would
+	# introduce a dep on itself
+	use doc && build_sphinx doc
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	local EPYTEST_DESELECT=(
+		# these tests require Internet access
+		tests/test_build_latex.py::test_latex_images
+		# TODO
+		tests/test_ext_autodoc.py::test_cython
+		tests/test_ext_autodoc_autoclass.py::test_classes
+		tests/test_ext_autodoc_autofunction.py::test_classes
+		# looks like a bug in lualatex
+		"tests/test_build_latex.py::test_build_latex_doc[lualatex-howto-None]"
+		"tests/test_build_latex.py::test_build_latex_doc[lualatex-manual-None]"
+		# doesn't like paths?
+		tests/test_directive_other.py::test_include_source_read_event
+		# flaky
+		tests/test_build_linkcheck.py
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
+		tests/test_ext_autodoc.py::test_automethod_for_builtin
+		tests/test_ext_autodoc.py::test_partialfunction
+		tests/test_ext_autodoc_autofunction.py::test_builtin_function
+		tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
+		tests/test_ext_autodoc_preserve_defaults.py::test_preserve_defaults_special_constructs
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+		tests/test_util_inspect.py::test_isattributedescriptor
+		tests/test_util_typing.py::test_is_invalid_builtin_class
+	)
+
+	# note: pytest-xdist causes random test failures
+	epytest
+}