[gentoo-commits] repo/gentoo:master commit in: media-libs/freetype/

["Sam James" <sam@gentoo.org>]

commit:     c60252e7bd697066da6bea2c3f059bb59cbc8d25
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 25 23:29:02 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Aug 26 01:43:52 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c60252e7

media-libs/freetype: add 2.13.2

Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/freetype/Manifest               |   3 +
 media-libs/freetype/freetype-2.13.2.ebuild | 255 +++++++++++++++++++++++++++++
 2 files changed, 258 insertions(+)

diff --git a/media-libs/freetype/Manifest b/media-libs/freetype/Manifest
index 82595a305ebe..c2ddbdc138ef 100644
--- a/media-libs/freetype/Manifest
+++ b/media-libs/freetype/Manifest
@@ -1,9 +1,12 @@
 DIST freetype-2.12.1.tar.xz 2471916 BLAKE2B c4737dc0c6e44e0a911545d604fdb2e8e8b3f5185d3f5dfe4e4561ee2d75b3e5a31afcbb2089306fec4b31ba10324a6ec6499c3735b2b7591c71e96fee4ed278 SHA512 6482de1748dc2cc01e033d21a3b492dadb1f039d13d9179685fdcf985e24d7f587cbca4c27ed8a7fdb7d9ad59612642ac5f4db062443154753295363f45c052f
 DIST freetype-2.13.0.tar.xz 2492440 BLAKE2B 11aac3cddb3e71cc0e6a616ed609294d6641aa0011842aa8230eace826955883aca0063331660025be14582b44aa189718ce21e0e5193a66bb5d7cffa1d0fb7f SHA512 b93a69a92b99f54c4fc4a276066bc7a87597df132e42ef93f6d973f1425e64bebcc568defa511d39fb04ab4d3a2090a6db1e54cf992a80ff57d658fee28a9110
 DIST freetype-2.13.1.tar.xz 2508168 BLAKE2B edadf2cdd8eb17362239cc5ab7fdff7cb1ca398908d3a9fa0547c3922b098df331cc87e939cee62ce20a78b01f14372c952c823c30af9ac227fc7da10000d37b SHA512 045c43f9a3ca33e7d6a98c286895b94ea6ccfbb83851270d1b1861b31ef3ee5a574d8e49c6414c4e14bdfb9276dc49a0677b3be3e4f40ef279dcda99b769b962
+DIST freetype-2.13.2.tar.xz 2501764 BLAKE2B cebc82180d9afaeb112a65ba78903d7bf7a9295a803166a033585ad2325add6023f05066852240c4665e56285345ba503b01ecd461d48f0478a8f3f56136988e SHA512 a5917edaa45cb9f75786f8a4f9d12fdf07529247e09dfdb6c0cf7feb08f7588bb24f7b5b11425fb47f8fd62fcb426e731c944658f6d5a59ce4458ad5b0a50194
 DIST freetype-doc-2.12.1.tar.xz 2038632 BLAKE2B 81225caf1a2c586a8a282a22eaaf23412270d19002bc5b07e94d946d41d089f798724982e354d1701488de37c35bf68f36de88796565f0ebaa3f9fb35c51f532 SHA512 276b91b93e375096bc0f9fa76408a6ea9fa89d4d06e9c9179f88d27d41df3f3bc0ce6939ea7a3fd7c93cb694e78fd6bfb154e969188279e2bca82dcc3afd108d
 DIST freetype-doc-2.13.0.tar.xz 2084016 BLAKE2B aa88eb5a30223a683348902624827bd7df218129fad0dcbb0f2453b9acf3930da634e9c67eda31191e868ca68db92059ed37cc0bd0287dc4458743538fdfe126 SHA512 d4367513e1ca48691aa6d64c36bf53603f67a67214378a2ae3810b2227084647743ee0d7137453f31c966ccb9ce19c2a72b3b5445d4accbce9a63d71f6b6800e
 DIST freetype-doc-2.13.1.tar.xz 2173864 BLAKE2B d61b58221d5eeb6d0c16ffbcc89ff1102992ac8f83193930971fb30f425bbfb882e9a29cf4c67754e497e19afc43cf87d23e304b5b9fb87bba51351b3dd5cb03 SHA512 e18f0851c52689628fb7fa520c6165895650412bfe1ebab8417bf5738d5cc7d1877e78e4afbede0996938f33554f53a0ea7b837fe81497a12b10daae5b8829ed
+DIST freetype-doc-2.13.2.tar.xz 2173920 BLAKE2B 273ab405b6c7097ace9c7882fddb22d2a0cf8cc1594e9d141ca18d13a3745ee2e481bd2ee214cba6d99224ef0d67fdcba1b08aa06e3556a80cda29f3b6026f97 SHA512 ca3438dcf6f995af556d8db3cb3cfdcabb81ab5a7dd88464ff757e3e418b3219b0011857cde8a338372e30d8375486ac8e50914da2ea948dc874f70010bce60c
 DIST ft2demos-2.12.1.tar.xz 263656 BLAKE2B fd48dc68bd832e7532e9fae869a19699ab3337e599118bb9f1b76c3bcdcecec3cd3f55f7387508d29baf85b8de4a549aaa0e8af34d988743b1737458e255bdcf SHA512 cd9356152a64d807c75b797d005ca1dd0bde69cc2fadedec101d125cb54b2aaff1f7afa2f20839caba7db66325df7c11ed4883b7e906110356b28d9900caaae7
 DIST ft2demos-2.13.0.tar.xz 333952 BLAKE2B 34155615eb967dda2b62e47bb4095a6bf367dd79b7bd93dfc4dc172476b3bf704af4039623d55ee08d2d6a5365b4783e86a570e34b70af2e543bac64d40833b0 SHA512 7d686e9febdda587b74647cc38fa22f0722d0306ecb05430e319e05b6132c999d20728bcd7a6506b8d8ad45a6859443e2b69d766802497357a8f0ba3352404ba
 DIST ft2demos-2.13.1.tar.xz 339736 BLAKE2B 1d0371d70f81039b4338b76089a15b6d445862de40e50b4d22a9e298d15751746779e569f68dcbc3996773c2ab902ee4ad299b6b3b5479ec20d55ec3a177b9ed SHA512 c03205266a420c589eec2a95ca082ab1c5606215a477500fe1a2f31c2f30c327a61e1fececec4ca3268f1a8b92a0bc8310bacf26f276ec09062fa5c5b0878511
+DIST ft2demos-2.13.2.tar.xz 341140 BLAKE2B 5e2c3eb2fccb359d03e154b94d349baab27aa465e40274ea99be1e19c8519ec9c434749c78a41743540bd38064a7c68e5389ff99443b8e320e617c4fe7f4558b SHA512 aa83ba4212ff7c4453b72f036136cb9b04cacf7d196388a3e4752613e000b3bb45a4dcf63d3d1d5b3d6ada10720304b532fb6e33ed6a5b399dcce45c27af9ade

diff --git a/media-libs/freetype/freetype-2.13.2.ebuild b/media-libs/freetype/freetype-2.13.2.ebuild
new file mode 100644
index 000000000000..6f8fac775721
--- /dev/null
+++ b/media-libs/freetype/freetype-2.13.2.ebuild
@@ -0,0 +1,255 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic libtool multilib-minimal toolchain-funcs
+
+DESCRIPTION="High-quality and portable font engine"
+HOMEPAGE="https://www.freetype.org/"
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+else
+	SRC_URI="
+		mirror://sourceforge/freetype/${P/_/}.tar.xz
+		mirror://nongnu/freetype/${P/_/}.tar.xz
+		utils? (
+			mirror://sourceforge/freetype/ft2demos-${PV}.tar.xz
+			mirror://nongnu/freetype/ft2demos-${PV}.tar.xz
+		)
+		doc? (
+			mirror://sourceforge/freetype/${PN}-doc-${PV}.tar.xz
+			mirror://nongnu/freetype/${PN}-doc-${PV}.tar.xz
+		)
+	"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+LICENSE="|| ( FTL GPL-2+ )"
+SLOT="2"
+IUSE="X +adobe-cff brotli bzip2 +cleartype-hinting debug doc fontforge harfbuzz +png static-libs svg utils"
+
+RDEPEND="
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	brotli? ( app-arch/brotli[${MULTILIB_USEDEP}] )
+	bzip2? ( >=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}] )
+	harfbuzz? ( >=media-libs/harfbuzz-1.3.0[truetype,${MULTILIB_USEDEP}] )
+	png? ( >=media-libs/libpng-1.2.51:0=[${MULTILIB_USEDEP}] )
+	utils? (
+		svg? ( >=gnome-base/librsvg-2.46.0[${MULTILIB_USEDEP}] )
+		X? ( >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}] )
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+PATCHES=(
+)
+
+_egit_repo_handler() {
+	if [[ ${PV} == 9999 ]] ; then
+		local phase="${1}"
+		case ${phase} in
+			fetch|unpack)
+				:;
+			;;
+			*)
+				die "Please use this function with either \"fetch\" or \"unpack\""
+			;;
+		esac
+
+		local EGIT_REPO_URI
+		EGIT_REPO_URI="https://gitlab.freedesktop.org/freetype/freetype.git"
+		git-r3_src_${phase}
+		if use utils ; then
+			EGIT_REPO_URI="https://gitlab.freedesktop.org/freetype/freetype-demos.git"
+			local EGIT_CHECKOUT_DIR="${WORKDIR}/ft2demos-${PV}"
+			git-r3_src_${phase}
+		fi
+	else
+		default
+	fi
+}
+
+pkg_pretend() {
+	if use svg && ! use utils ; then
+		einfo "The \"svg\" USE flag only has effect when the \"utils\" USE flag is also enabled."
+	fi
+}
+
+src_unpack() {
+	_egit_repo_handler ${EBUILD_PHASE}
+
+	if [[ ${PV} == 9999 ]] ; then
+		# Need to copy stuff from dlg subproject (bug #758902)
+		local dlg_inc_dir="${S}/subprojects/dlg/include/dlg"
+		local dlg_src_dir="${S}/subprojects/dlg/src/dlg"
+		local dlg_dest_dir="${S}/include"
+		mkdir -p "${dlg_dest_dir}/dlg" || die
+		cp "${dlg_inc_dir}"/{dlg,output}.h "${dlg_dest_dir}/dlg" || die
+		cp "${dlg_src_dir}"/* "${dlg_dest_dir}" || die
+	fi
+}
+
+src_prepare() {
+	if [[ ${PV} == 9999 ]] ; then
+		# Do NOT automagically mess with submodules!
+		sed '/setup: copy_submodule/d' -i builds/toplevel.mk || die
+
+		# Inspired by shipped autogen.sh script
+		eval $(sed -n \
+			-e 's/^#define  *\(FREETYPE_MAJOR\)  *\([0-9][0-9]*\).*/\1=\2/p' \
+			-e 's/^#define  *\(FREETYPE_MINOR\)  *\([0-9][0-9]*\).*/\1=\2/p' \
+			-e 's/^#define  *\(FREETYPE_PATCH\)  *\([0-9][0-9]*\).*/\1=\2/p' \
+			include/freetype/freetype.h || die)
+		FREETYPE="${FREETYPE_MAJOR}.${FREETYPE_MINOR}"
+		[[ "${FREETYPE_PATCH}" != 0 ]] && FREETYPE+=".${FREETYPE_PATCH}"
+
+		pushd builds/unix &>/dev/null || die
+		sed -e "s;@VERSION@;${FREETYPE};" \
+			< configure.raw > configure.ac || die
+		unset FREETYPE_MAJOR FREETYPE_MINOR FREETYPE_PATCH FREETYPE
+		popd &>/dev/null || die
+	fi
+
+	default
+
+	pushd builds/unix &>/dev/null || die
+	# eautoheader produces broken ftconfig.in
+	AT_NOEAUTOHEADER="yes" AT_M4DIR="." eautoreconf
+	popd &>/dev/null || die
+
+	# This is the same as the 01 patch from infinality
+	sed '/AUX_MODULES += \(gx\|ot\)valid/s@^# @@' -i modules.cfg || die
+
+	enable_option() {
+		sed -i -e "/#define $1/ { s:/\* ::; s: \*/:: }" \
+			include/${PN}/config/ftoption.h \
+			|| die "unable to enable option $1"
+	}
+
+	disable_option() {
+		sed -i -e "/#define $1/ { s:^:/* :; s:$: */: }" \
+			include/${PN}/config/ftoption.h \
+			|| die "unable to disable option $1"
+	}
+
+	if ! use cleartype-hinting ; then
+		disable_option TT_CONFIG_OPTION_SUBPIXEL_HINTING
+	fi
+
+	# Can be disabled with FREETYPE_PROPERTIES="pcf:no-long-family-names=1"
+	# via environment (new since v2.8)
+	enable_option PCF_CONFIG_OPTION_LONG_FAMILY_NAMES
+
+	# See https://freetype.org/patents.html (expired!)
+	enable_option FT_CONFIG_OPTION_SUBPIXEL_RENDERING
+
+	if ! use adobe-cff ; then
+		enable_option CFF_CONFIG_OPTION_OLD_ENGINE
+	fi
+
+	if use debug ; then
+		enable_option FT_DEBUG_LEVEL_TRACE
+		enable_option FT_DEBUG_MEMORY
+	fi
+
+	if use utils ; then
+		cd "${WORKDIR}/ft2demos-${PV}" || die
+		# Disable tests needing X11 when USE="-X". (bug #177597)
+		if ! use X ; then
+			sed -i -e "/EXES\ +=\ ftdiff/ s:^:#:" Makefile || die
+		fi
+		cd "${S}" || die
+	fi
+
+	# bug #869803
+	rm docs/reference/sitemap.xml.gz || die
+
+	# We need non-/bin/sh to run configure
+	if [[ -n ${CONFIG_SHELL} ]] ; then
+		sed -i -e "1s:^#![[:space:]]*/bin/sh:#!${CONFIG_SHELL}:" \
+			"${S}"/builds/unix/configure || die
+	fi
+
+	elibtoolize --patch-only
+}
+
+multilib_src_configure() {
+	append-flags -fno-strict-aliasing
+
+	export GNUMAKE=gmake
+
+	local myeconfargs=(
+		--disable-freetype-config
+		--enable-shared
+		--with-zlib
+		$(use_with brotli)
+		$(use_with bzip2)
+		$(use_with harfbuzz)
+		$(use_with png)
+		$(use_enable static-libs static)
+		$(usex utils $(use_with svg librsvg) --without-librsvg)
+
+		# Avoid using libpng-config
+		LIBPNG_CFLAGS="$($(tc-getPKG_CONFIG) --cflags libpng)"
+		LIBPNG_LDFLAGS="$($(tc-getPKG_CONFIG) --libs libpng)"
+	)
+
+	case ${CHOST} in
+		mingw*|*-mingw*) ;;
+		# Workaround windows mis-detection: bug #654712
+		# Have to do it for both ${CHOST}-windres and windres
+		*) myeconfargs+=( ac_cv_prog_RC= ac_cv_prog_ac_ct_RC= ) ;;
+	esac
+
+	export CC_BUILD="$(tc-getBUILD_CC)"
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_compile() {
+	default
+
+	if multilib_is_native_abi && use utils ; then
+		einfo "Building utils"
+		# Fix for Prefix, bug #339334
+		emake \
+			X11_PATH="${EPREFIX}/usr/$(get_libdir)" \
+			FT2DEMOS=1 TOP_DIR_2="${WORKDIR}/ft2demos-${PV}"
+	fi
+}
+
+multilib_src_install() {
+	default
+
+	if multilib_is_native_abi && use utils ; then
+		einfo "Installing utils"
+		emake DESTDIR="${D}" FT2DEMOS=1 \
+			TOP_DIR_2="${WORKDIR}/ft2demos-${PV}" install
+	fi
+}
+
+multilib_src_install_all() {
+	if use fontforge ; then
+		# fontforge can probably cope with fewer of these, but this is simpler
+		einfo "Installing internal headers required for fontforge"
+		local header
+		find src/truetype include/freetype/internal -name '*.h' | \
+		while read header ; do
+			mkdir -p "${ED}/usr/include/freetype2/internal4fontforge/$(dirname ${header})" || die
+			cp ${header} "${ED}/usr/include/freetype2/internal4fontforge/$(dirname ${header})" || die
+		done
+	fi
+
+	dodoc docs/{CHANGES,CUSTOMIZE,DEBUG,INSTALL.UNIX,*.txt,PROBLEMS,TODO}
+	if [[ ${PV} != 9999 ]] && use doc ; then
+		docinto html
+		dodoc -r docs/*
+	fi
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}