[gentoo-commits] repo/gentoo:master commit in: dev-python/pytest-testinfra/

["Michał Górny" <mgorny@gentoo.org>]

commit:     8916d7f05e64aeb62e5adb4b7cc206d8829ad72e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 25 09:48:11 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Aug 25 09:49:29 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8916d7f0

dev-python/pytest-testinfra: Bump to 9.0.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pytest-testinfra/Manifest               |  1 +
 .../pytest-testinfra/pytest-testinfra-9.0.0.ebuild | 57 ++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/dev-python/pytest-testinfra/Manifest b/dev-python/pytest-testinfra/Manifest
index 9edeb078a9b6..09885e963357 100644
--- a/dev-python/pytest-testinfra/Manifest
+++ b/dev-python/pytest-testinfra/Manifest
@@ -1 +1,2 @@
 DIST pytest-testinfra-8.1.0.tar.gz 84156 BLAKE2B 169ccd6afc4260f3dd42c8eff8112395adc7216cfd3e5f7abeb9b9d3db0cd766465dd94a5ca500d610db469f0e51298b6fc26f3c0ffd27f2fc215d859c99e52d SHA512 2f98cc15952c5607ecc1db76bae90aa9d299951cd1f4c5f8ba6085a7f4e6babac7f4ef4e44e089829f7382139164259007125f505c18129cc7135b840d709931
+DIST pytest-testinfra-9.0.0.tar.gz 83896 BLAKE2B 8d75bf051ec91916dcb9bc727409eefbf53f8635b5dd953d2c1d05a1d4daa37ade01a23bcc004f77ced37d8fb30684df211d16d95839c1a8d8e5d5c4df5336ca SHA512 bbf66597c473b868f0dde0437d666f8235e835a35bfd12b4a86f9970e26c1963d83101e7e0e3b3817e23798bee342f47ac7666041f0e09038236f9ddca4afecf

diff --git a/dev-python/pytest-testinfra/pytest-testinfra-9.0.0.ebuild b/dev-python/pytest-testinfra/pytest-testinfra-9.0.0.ebuild
new file mode 100644
index 000000000000..6af6abc9e956
--- /dev/null
+++ b/dev-python/pytest-testinfra/pytest-testinfra-9.0.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Write unit tests in Python to test actual state of your servers"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-testinfra/
+	https://pypi.org/project/pytest-testinfra/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	dev-python/pytest[${PYTHON_USEDEP}]
+"
+# Ansible is called via its CLI
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		app-admin/ansible
+		$(python_gen_cond_dep '
+			app-admin/salt[${PYTHON_USEDEP}]
+		' python3_10)
+		dev-python/paramiko[${PYTHON_USEDEP}]
+		dev-python/pywinrm[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x EPYTEST_DESELECT=()
+
+	# This is the only test which actually fails if salt cannot be imported
+	if ! has_version "dev-python/salt[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			test/test_backends.py::test_backend_importables
+		)
+	fi
+
+	epytest
+}
+
+pkg_postinst() {
+	elog "For the list of available connection back-ends and their dependencies,"
+	elog "please consult https://testinfra.readthedocs.io/en/latest/backends.html"
+}