[gentoo-commits] repo/gentoo:master commit in: dev-python/APScheduler/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     9fdef454a0b4720e808c8681bb070b18010379bd
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 13 18:29:27 2023 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Sun Aug 13 18:29:27 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9fdef454

dev-python/APScheduler: add 3.10.2

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/APScheduler/APScheduler-3.10.2.ebuild | 63 ++++++++++++++++++++++++
 dev-python/APScheduler/Manifest                  |  1 +
 2 files changed, 64 insertions(+)

diff --git a/dev-python/APScheduler/APScheduler-3.10.2.ebuild b/dev-python/APScheduler/APScheduler-3.10.2.ebuild
new file mode 100644
index 000000000000..c5cde2e53f6b
--- /dev/null
+++ b/dev-python/APScheduler/APScheduler-3.10.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="In-process task scheduler with Cron-like capabilities"
+HOMEPAGE="
+	https://github.com/agronholm/apscheduler/
+	https://pypi.org/project/APScheduler/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/tzlocal-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/sqlalchemy-1.4[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-tornado[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	# disable test fixtures using external servers (mongodb, redis...)
+	# these fixtures are using markers in git master, so the patch
+	# should be no longer necessary with next major bump
+	"${FILESDIR}"/APScheduler-3.8.1-external-server-tests.patch
+)
+
+EPYTEST_DESELECT=(
+	tests/test_jobstores.py::test_repr_mongodbjobstore
+	tests/test_jobstores.py::test_repr_redisjobstore
+	tests/test_jobstores.py::test_repr_zookeeperjobstore
+	tests/test_executors.py::test_broken_pool
+)
+
+python_prepare_all() {
+	# suppress setuptools warning #797751
+	sed -e 's|^upload-dir|upload_dir|' -i setup.cfg || die
+	sed -e '/addopts/d' -i setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p asyncio -p tornado
+}

diff --git a/dev-python/APScheduler/Manifest b/dev-python/APScheduler/Manifest
index 97a332998728..eb39473acb40 100644
--- a/dev-python/APScheduler/Manifest
+++ b/dev-python/APScheduler/Manifest
@@ -1 +1,2 @@
 DIST APScheduler-3.10.1.tar.gz 100376 BLAKE2B 6b5aed1197ec6cdcf2c82d73c2809d9fd304401ad5ac482cdd0dfc310356248b9ba5f0cf611f5484f4098c92d7b6f8b81f117fe5fd645b5d20ba0fbb7f1d6c97 SHA512 bba68c97d2e7cda6503a8471a61bf57c11b9c8b6dde4d1da65f7d134bf72f631b3f70815ac7db3f75313833c780ee6ded0b8d0e1c9a86e05e741788bcd041008
+DIST APScheduler-3.10.2.tar.gz 100853 BLAKE2B 540517028af71f8325c74d9fc87c44aeb20440be5a670aaa488069090acec5d19c950ab2df67e55e83b52140343e384a1214d7c7390ce50d3d5fca99bac492c8 SHA512 42a1c7df47ab41c06f87e9d0828950c78abe50e1f6648d5eda425db74edf1d07473129d1a1b9a4a82c32dfadacba9b3dca2e5b2772ba733007c502b31c34d43d