[gentoo-commits] repo/gentoo:master commit in: dev-libs/libmspack/

["Sam James" <sam@gentoo.org>]

commit:     96dda33c1cb9d22b89b08bb14b0f448eae3457c3
Author:     Matt Jolly <Matt.Jolly <AT> footclan <DOT> ninja>
AuthorDate: Thu Aug  3 01:41:13 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Aug 13 07:50:24 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=96dda33c

dev-libs/libmspack: add 0.11_alpha

Signed-off-by: Matt Jolly <Matt.Jolly <AT> footclan.ninja>
Closes: https://github.com/gentoo/gentoo/pull/32152
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/libmspack/Manifest                    |  1 +
 dev-libs/libmspack/libmspack-0.11_alpha.ebuild | 67 ++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/dev-libs/libmspack/Manifest b/dev-libs/libmspack/Manifest
index 698014b9766f..8bde9da8b8e8 100644
--- a/dev-libs/libmspack/Manifest
+++ b/dev-libs/libmspack/Manifest
@@ -1 +1,2 @@
 DIST libmspack-0.10.1alpha.tar.gz 963274 BLAKE2B 39bcb3b7ea419d6d00850b70c217c802a2095dd4398038e594ae7c01ca12e71508218c1cfca5ae8b102636ab9517b13d55c1e411b31e87d28aa46331cd0127e6 SHA512 a7b5f7caa49190c5021f3e768b92f2e51cc0ce685c9ab6ed6fb36de885c73231b58d47a8a3b5c5aa5c9ac56c25c500eb683d84dbf11f09f97f6cb4fff5adc245
+DIST libmspack-0.11alpha.tar.gz 509478 BLAKE2B 7e386ab5ae160000bab9e5523f2ebf3907a5cb564fb7cc8945ca15daf5c8ff2563f6680383c52f6de95d1aa992d6616e2f80133740c8329390a8e5c76ba84301 SHA512 40c487e5b4e2f63a6cada26d29db51f605e8c29525a1cb088566d02cf2b1cc9dba263f80e2101d7f8e9d69cf7684a15bcaf791fb4891ad013a56afc7256dfa62

diff --git a/dev-libs/libmspack/libmspack-0.11_alpha.ebuild b/dev-libs/libmspack/libmspack-0.11_alpha.ebuild
new file mode 100644
index 000000000000..2a4ad5dfcc64
--- /dev/null
+++ b/dev-libs/libmspack/libmspack-0.11_alpha.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/kyz/libmspack.git"
+	inherit git-r3
+	MY_P="${PN}-9999"
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+	MY_PV="${PV/_alpha/alpha}"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="https://www.cabextract.org.uk/libmspack/libmspack-${MY_PV}.tar.gz"
+fi
+
+DESCRIPTION="A library for Microsoft compression formats"
+HOMEPAGE="https://www.cabextract.org.uk/libmspack/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="debug doc"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	if [[ ${PV} == *9999 ]] ; then
+		# Re-create file layout from release tarball
+		pushd "${WORKDIR}" > /dev/null || die
+
+		cp -aL "${S}"/${PN} "${WORKDIR}"/${PN}-source || die
+		rm -r "${S}" || die
+		mv "${WORKDIR}"/${PN}-source "${S}" || die
+
+		popd > /dev/null || die
+	fi
+
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable debug)
+}
+
+src_test() {
+	default
+
+	cd "${S}"/test || die
+	./cabd_test || die
+}
+
+src_install() {
+	use doc && HTML_DOCS=( doc/. )
+
+	default
+
+	if use doc ; then
+		rm "${ED}"/usr/share/doc/"${PF}"/html/{Makefile*,Doxyfile*} || die
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+	find "${ED}" -name "*.a" -delete || die
+}