[gentoo-commits] repo/gentoo:master commit in: dev-util/catfish/

["Michał Górny" <mgorny@gentoo.org>]

commit:     d5235f131a2b2180c5b094e7d70dc3243e4d36e5
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  6 13:11:36 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Aug  6 13:11:36 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d5235f13

dev-util/catfish: Bump to 4.18.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-util/catfish/Manifest              |  1 +
 dev-util/catfish/catfish-4.18.0.ebuild | 50 ++++++++++++++++++++++++++++++++++
 2 files changed, 51 insertions(+)

diff --git a/dev-util/catfish/Manifest b/dev-util/catfish/Manifest
index 828120c934fe..1c3822c21a8b 100644
--- a/dev-util/catfish/Manifest
+++ b/dev-util/catfish/Manifest
@@ -1 +1,2 @@
 DIST catfish-4.16.4.tar.bz2 284259 BLAKE2B 97b0cc1f082dc20865a465c282581a23b85df89cc0745d6b69617eee94ff88d04f1e63c1acf64b524345fcbdb1817feda289dc49a57e08b747b2d57388180e40 SHA512 729359e737d5faf8a97caf82d1bc709be46baf76d93f0a7007e27fa96d3f2dfe9e2c316cdba991a38c5333db26c37f18cc4ca7f8468087cad754d44bd1e2677c
+DIST catfish-4.18.0.tar.bz2 295952 BLAKE2B bf05a8f272217936b8f010157c585ab90a9b5858c06a72c6145da62999221725a990d544c67a8469b08d3accbcf28af59bc59a6585e3c8781fb88dc48fb026c0 SHA512 57a3cc5043281bd9527e4faa6a3afcba2e8948fb6dc9e8d93d26ceb0358a84850b3e892105f81b4f2a30bb2964d65b2083fd07b55f145f3ae6ea653acd098539

diff --git a/dev-util/catfish/catfish-4.18.0.ebuild b/dev-util/catfish/catfish-4.18.0.ebuild
new file mode 100644
index 000000000000..9f39a9e09cbe
--- /dev/null
+++ b/dev-util/catfish/catfish-4.18.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="A frontend for find, (s)locate, doodle, tracker, beagle, strigi and pinot"
+HOMEPAGE="https://docs.xfce.org/apps/catfish/start"
+SRC_URI="https://archive.xfce.org/src/apps/catfish/${PV%.*}/${P}.tar.bz2"
+
+# yep, GPL-2 only
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.42
+	dev-libs/gobject-introspection
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	x11-libs/gdk-pixbuf[introspection]
+	>=x11-libs/gtk+-3.22:3[introspection]
+	x11-libs/pango[introspection]
+	>=xfce-base/xfconf-4.14[introspection]
+	virtual/freedesktop-icon-theme
+"
+BDEPEND="
+	dev-python/python-distutils-extra[${PYTHON_USEDEP}]
+	sys-devel/gettext
+"
+
+src_install() {
+	distutils-r1_src_install
+	rm -r "${ED}"/usr/share/doc/catfish || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}