[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-calculator/

["Matt Turner" <mattst88@gentoo.org>]

commit:     580118b228e82c38093194a6a05250a660ecc32b
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri Aug  4 02:53:05 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Aug  4 14:36:34 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=580118b2

gnome-extra/gnome-calculator: Version bump to 45_beta

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32165
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-calculator/Manifest              |  1 +
 .../gnome-calculator-45_beta.ebuild                | 74 ++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/gnome-extra/gnome-calculator/Manifest b/gnome-extra/gnome-calculator/Manifest
index f7b79dd7fcff..291c23d86c19 100644
--- a/gnome-extra/gnome-calculator/Manifest
+++ b/gnome-extra/gnome-calculator/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-calculator-44.0.tar.xz 1075480 BLAKE2B a4e7af52e06a59a1a07baf3e34dbfc90dc8852cab3f44fe2018e3279cf7dab7c9cffe23bff2d7cc8b9b3708b652b9b8ae2fa65ff403c559fc1bfd060e4645575 SHA512 7c1428873c00a2052b966a0687f2a944dce67e889c8e113a794a7d5f0bafe9ff52562e2b1985bcf48d05a5a0a2f4ff97e490a43810b5243367fce9c6ada79fa6
 DIST gnome-calculator-45.alpha.tar.xz 1090752 BLAKE2B 7db9b24e74b193333b1c12ad404a11565685d4f7eddd2659cd0705b328ac8f3de477baab094be4d1b592899beb9d1f5069e18c702df22d630b464db47f4b47fe SHA512 51b6e09921b80121493a5597742965555243452e780a794d2a8b50f391879fcf13cea458ce34e8a2f6e90c0edfd8e8a553b73b5e17a9b4ab735b4d12ce059e7d
+DIST gnome-calculator-45.beta.tar.xz 1094460 BLAKE2B dda75a6e1d0e1e6d4053f0e151477e1705b4a9a8ebd08a2e3df73c9c475317f47ea08da14f1a1baef5ece1925b2e04ce98d145f834dba6e3a51224a9a2bbfa32 SHA512 217b2acbd30fc80e625bb0e656ddec24c182e02f195db31c07cd7603962a0c7b63fdf1b86eeb4b51e8b7bed15a16ac52ccef941b74b464a4e9440b659880be40

diff --git a/gnome-extra/gnome-calculator/gnome-calculator-45_beta.ebuild b/gnome-extra/gnome-calculator/gnome-calculator-45_beta.ebuild
new file mode 100644
index 000000000000..d2baf4a89433
--- /dev/null
+++ b/gnome-extra/gnome-calculator/gnome-calculator-45_beta.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson vala virtualx xdg
+
+DESCRIPTION="A calculator application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Calculator"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+introspection test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+# gtksourceview vapi definitions in dev-lang/vala itself are too old, and newer vala removes them
+# altogether, thus we need them installed by gtksourceview[vala]
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libxml2:2
+	net-libs/libsoup:3.0
+	>=dev-libs/libgee-0.20.0:0.8
+	dev-libs/mpc:=
+	dev-libs/mpfr:0=
+	>=gui-libs/gtk-4.4.1:4
+	>=gui-libs/libadwaita-1.2.0:1
+	>=gui-libs/gtksourceview-5.3.0:5
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	net-libs/libsoup:3.0[vala]
+	gui-libs/gtksourceview:5[vala]
+	gui-libs/libhandy:1[vala]
+"
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddisable-ui=false
+		#-Dvala-version # doesn't do anything in 3.34
+		$(meson_use !introspection disable-introspection)
+		$(meson_use test ui-tests)
+		-Dgcalc=true
+		-Dgci=true
+		-Dapp=true
+		-Ddoc=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	XDG_SESSION_TYPE=x11 virtx dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}