[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-firewall/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     631a24127a9ec77c99f26886a38a34e7a0352ab5
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Aug  1 10:06:57 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Aug  1 10:57:32 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=631a2412

kde-plasma/plasma-firewall: 5.27.7 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-firewall/Manifest                |  1 +
 .../plasma-firewall/plasma-firewall-5.27.7.ebuild  | 65 ++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index a4c596d4fb24..8a9e8d9af808 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1 +1,2 @@
 DIST plasma-firewall-5.27.6.tar.xz 363172 BLAKE2B a999196d3680c959615c09989475312f855f58ce27054627c03daa289369ee12db2754740113e0c0330ddf5096ac12adec03b42003488c7213e0516d07c0dded SHA512 93ba3a0aab403df2174892962cb68c55da6c5ed14bbac1c6de939fdae3077d700e05688f29f16f59107b9b0dccd8d75808c566a55e115bf151452a55a7ea2ca8
+DIST plasma-firewall-5.27.7.tar.xz 363268 BLAKE2B 4cab2564843f7bfe13d3ba0ae72b8819ce2fad79b4f6fd9846bb8ddfb6ae6a17d622ade3bd77639cd7723c09ce5c9b7fa83da710f33e12ddbb9523a4f8b45510 SHA512 e75d01e0002fa31dd46cf79013effc2285ea7423917beaed7e1e8e9bed7f2ef4caab0594a6a4f123865a3a92399e1af508891bc5fdde58349eabc7d99af35ebd

diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.27.7.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.27.7.ebuild
new file mode 100644
index 000000000000..2fa7d8d9b143
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.27.7.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+PYTHON_COMPAT=( python3_{10..11} )
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}