[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-commander/

["Matt Turner" <mattst88@gentoo.org>]

commit:     0168ab3b7d2b038b771d188b30c215a60086df65
Author:     Uwe Scholz <u.scholz83 <AT> gmx <DOT> de>
AuthorDate: Sat Jul  8 16:50:08 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Jul 26 20:30:59 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0168ab3b

gnome-extra/gnome-commander: add 1.16.1

Closes: https://bugs.gentoo.org/906473
Closes: https://github.com/gentoo/gentoo/pull/31846
Signed-off-by: Uwe Scholz <u.scholz83 <AT> gmx.de>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-commander/Manifest               |  1 +
 .../gnome-commander/gnome-commander-1.16.1.ebuild  | 62 ++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/gnome-extra/gnome-commander/Manifest b/gnome-extra/gnome-commander/Manifest
index 808849d89f15..6e2c6eee1eac 100644
--- a/gnome-extra/gnome-commander/Manifest
+++ b/gnome-extra/gnome-commander/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-commander-1.14.3.tar.xz 6862280 BLAKE2B 802a3d147c056b08025164b68d48dfc731a0db0d78ada3c5e81866e0918903d82c101fc688bb6a101760605fa17e6d45bb18800aa659b7150e376844d00d0a22 SHA512 a3a89b922c23b49587d1b459760a263c886636735549c8dcd592b1ccb838838a3748ec83eb65ca8bbb62d82d4b588479a7673314d6924075b733b31318e52756
 DIST gnome-commander-1.16.0.tar.xz 6235496 BLAKE2B a888acc48e6b402d12aec5e447c3354cf7d9a6c9138787728231f4dca837cc7fa57f7dd0b678618e63ce90ba405441e819bafe4d86cb7feee0ed2f7bf09bf212 SHA512 9e23afb9b58e1f24e8a67f81fcf9c9bbae02c07d184cf9ffd4bc56d1e4b705ea355b95ce16209d50b743898cdb7bf0b6b8730eaa44f09001d9fa9a834fcbccae
+DIST gnome-commander-1.16.1.tar.xz 6240500 BLAKE2B c24b9647f19faa55479e88b11524bc88a1720feffe9a4de638bebbd54aea17a6975d8319eb52281bbc6006907294d86c1f1874eb252a51f9fe5075748f84d24c SHA512 3a42671350e071552f82e44cf09e7598c9851a8d0b47cedc059a23347e8da71e1cc140f16191b31b1e66b74d803240db63a0eb8ba6a189dfc64315783fb954e0

diff --git a/gnome-extra/gnome-commander/gnome-commander-1.16.1.ebuild b/gnome-extra/gnome-commander/gnome-commander-1.16.1.ebuild
new file mode 100644
index 000000000000..d9ff00029c93
--- /dev/null
+++ b/gnome-extra/gnome-commander/gnome-commander-1.16.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2 meson optfeature
+
+DESCRIPTION="A graphical, full featured, twin-panel file manager"
+HOMEPAGE="https://gcmd.github.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc exif gsf pdf samba taglib test +unique"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	doc? ( gnome-extra/yelp )
+	>=dev-libs/glib-2.70.0:2
+	>=x11-libs/gtk+-2.24.0:2
+	exif? ( >=media-gfx/exiv2-0.14 )
+	gsf? ( >=gnome-extra/libgsf-1.12:= )
+	pdf? ( >=app-text/poppler-0.18 )
+	samba? ( gnome-base/gvfs[samba] )
+	taglib? ( >=media-libs/taglib-1.4 )
+	unique? ( >=dev-libs/libunique-0.9.3:1 )
+"
+BDEPEND="
+	doc? ( app-text/yelp-tools )
+	dev-util/glib-utils
+	dev-util/gtk-doc-am
+	sys-devel/flex
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+DEPEND="
+	${RDEPEND}
+	test? ( >=dev-cpp/gtest-1.7.0 )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature exif exiv2)
+		$(meson_feature gsf libgsf)
+		$(meson_feature pdf poppler)
+		$(meson_feature samba)
+		$(meson_feature taglib)
+		$(meson_feature unique)
+		$(meson_feature test tests)
+		$(meson_use doc help)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	optfeature "synchronizing files and directories" dev-util/meld
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}