[gentoo-commits] repo/proj/guru:dev commit in: x11-misc/input-leap/

[gentoo-commits] repo/proj/guru:dev commit in: x11-misc/input-leap/

[Vitaly Zdanevich]

commit:     4abfc9c7ebab6d9d07524417dd0d1471de42fcaf
Author:     Vitaly Zdanevich <zdanevich.vitaly <AT> ya <DOT> ru>
AuthorDate: Wed Jul 26 05:53:16 2023 +0000
Commit:     Vitaly Zdanevich <zdanevich.vitaly <AT> ya <DOT> ru>
CommitDate: Wed Jul 26 05:53:16 2023 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=4abfc9c7

x11-misc/input-leap: new package 9999

Signed-off-by: Vitaly Zdanevich <zdanevich.vitaly <AT> ya.ru>

 x11-misc/input-leap/input-leap-9999.ebuild | 77 ++++++++++++++++++++++++++++++
 x11-misc/input-leap/metadata.xml           | 11 +++++
 2 files changed, 88 insertions(+)

diff --git a/x11-misc/input-leap/input-leap-9999.ebuild b/x11-misc/input-leap/input-leap-9999.ebuild
new file mode 100644
index 000000000..4e1f1de73
--- /dev/null
+++ b/x11-misc/input-leap/input-leap-9999.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop virtualx xdg cmake git-r3
+
+DESCRIPTION="Share a mouse and keyboard between computers (fork of Barrier)"
+HOMEPAGE="https://github.com/input-leap/input-leap"
+EGIT_REPO_URI="https://github.com/input-leap/input-leap.git"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="gui test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	net-misc/curl
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXi
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libXtst
+	gui? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+		net-dns/avahi[mdnsresponder-compat]
+	)
+	dev-libs/openssl:0=
+"
+DEPEND="
+	${RDEPEND}
+	dev-cpp/gtest
+	dev-cpp/gulrak-filesystem
+	x11-base/xorg-proto
+"
+
+DOCS=(
+	ChangeLog
+	README.md
+	doc/${PN}.conf.example{,-advanced,-basic}
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DBARRIER_BUILD_GUI=$(usex gui)
+		-DBARRIER_BUILD_INSTALLER=OFF
+		-DBARRIER_BUILD_TESTS=$(usex test)
+		-DBARRIER_REVISION=00000000
+		-DBARRIER_USE_EXTERNAL_GTEST=ON
+		-DBARRIER_VERSION_STAGE=gentoo
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/bin/unittests || die
+	virtx "${BUILD_DIR}"/bin/integtests || die
+}
+
+src_install() {
+	cmake_src_install
+	einstalldocs
+	doman doc/${PN}{c,s}.1
+
+	if use gui; then
+		doicon -s scalable res/${PN}.svg
+		doicon -s 256 res/${PN}.png
+		make_desktop_entry ${PN} Barrier ${PN} Utility
+	fi
+}

diff --git a/x11-misc/input-leap/metadata.xml b/x11-misc/input-leap/metadata.xml
new file mode 100644
index 000000000..8dd9226f2
--- /dev/null
+++ b/x11-misc/input-leap/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>zdanevich.vitaly@ya.ru</email>
+		<name>Vitaly Zdanevich</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">input-leap/input-leap</remote-id>
+	</upstream>
+</pkgmetadata>

[gentoo-commits] repo/proj/guru:dev commit in: x11-misc/input-leap/

[Takuya Wakazono]

commit:     374f7c09150c97cc3bd8c9496566ce05a4ff85e0
Author:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
AuthorDate: Sun Sep 29 11:40:25 2024 +0000
Commit:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
CommitDate: Sun Sep 29 11:40:25 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=374f7c09

x11-misc/input-leap: sync with upstream

- remove custom src_install, the default cmake_src_install is sufficient
- migrate to Qt6

Closes: https://bugs.gentoo.org/930734
Signed-off-by: Takuya Wakazono <pastalian46 <AT> gmail.com>

 x11-misc/input-leap/input-leap-9999.ebuild | 34 +++++++++---------------------
 1 file changed, 10 insertions(+), 24 deletions(-)

diff --git a/x11-misc/input-leap/input-leap-9999.ebuild b/x11-misc/input-leap/input-leap-9999.ebuild
index 4e1f1de73..70bb891e4 100644
--- a/x11-misc/input-leap/input-leap-9999.ebuild
+++ b/x11-misc/input-leap/input-leap-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-inherit desktop virtualx xdg cmake git-r3
+inherit virtualx xdg cmake git-r3
 
 DESCRIPTION="Share a mouse and keyboard between computers (fork of Barrier)"
 HOMEPAGE="https://github.com/input-leap/input-leap"
@@ -25,10 +25,7 @@ RDEPEND="
 	x11-libs/libXrandr
 	x11-libs/libXtst
 	gui? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtnetwork:5
-		dev-qt/qtwidgets:5
+		dev-qt/qtbase:6[gui,network,widgets]
 		net-dns/avahi[mdnsresponder-compat]
 	)
 	dev-libs/openssl:0=
@@ -39,6 +36,10 @@ DEPEND="
 	dev-cpp/gulrak-filesystem
 	x11-base/xorg-proto
 "
+BDEPEND="
+	virtual/pkgconfig
+	gui? ( dev-qt/qttools:6[linguist] )
+"
 
 DOCS=(
 	ChangeLog
@@ -48,12 +49,9 @@ DOCS=(
 
 src_configure() {
 	local mycmakeargs=(
-		-DBARRIER_BUILD_GUI=$(usex gui)
-		-DBARRIER_BUILD_INSTALLER=OFF
-		-DBARRIER_BUILD_TESTS=$(usex test)
-		-DBARRIER_REVISION=00000000
-		-DBARRIER_USE_EXTERNAL_GTEST=ON
-		-DBARRIER_VERSION_STAGE=gentoo
+		-DINPUTLEAP_BUILD_GUI=$(usex gui)
+		-DINPUTLEAP_BUILD_TESTS=$(usex test)
+		-DINPUTLEAP_USE_EXTERNAL_GTEST=ON
 	)
 
 	cmake_src_configure
@@ -63,15 +61,3 @@ src_test() {
 	"${BUILD_DIR}"/bin/unittests || die
 	virtx "${BUILD_DIR}"/bin/integtests || die
 }
-
-src_install() {
-	cmake_src_install
-	einstalldocs
-	doman doc/${PN}{c,s}.1
-
-	if use gui; then
-		doicon -s scalable res/${PN}.svg
-		doicon -s 256 res/${PN}.png
-		make_desktop_entry ${PN} Barrier ${PN} Utility
-	fi
-}