[gentoo-commits] repo/gentoo:master commit in: dev-db/pgbouncer/

["罗百科" <patrick@gentoo.org>]

commit:     e485db0cd8780ff1dbf9e489c3d774de2ff11663
Author:     Patrick Lauer <patrick <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 22 16:29:26 2023 +0000
Commit:     罗百科 <patrick <AT> gentoo <DOT> org>
CommitDate: Sat Jul 22 16:34:16 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e485db0c

dev-db/pgbouncer: add 1.19.1, 1.20.0

Signed-off-by: Patrick Lauer <patrick <AT> gentoo.org>

 dev-db/pgbouncer/Manifest                |  2 +
 dev-db/pgbouncer/pgbouncer-1.19.1.ebuild | 79 ++++++++++++++++++++++++++++++++
 dev-db/pgbouncer/pgbouncer-1.20.0.ebuild | 79 ++++++++++++++++++++++++++++++++
 3 files changed, 160 insertions(+)

diff --git a/dev-db/pgbouncer/Manifest b/dev-db/pgbouncer/Manifest
index cf53948311d9..f8e0bd2fe82a 100644
--- a/dev-db/pgbouncer/Manifest
+++ b/dev-db/pgbouncer/Manifest
@@ -1,3 +1,5 @@
 DIST pgbouncer-1.16.1.tar.gz 591450 BLAKE2B 137193ad614586d708598fd7003af4dee69f03f88a7235ba4074b63d57ffc3ee1c41fbccb49c5df7c23a2272b33810f8c2a9084d98e2e695a3b5f5ec317e0227 SHA512 9ecb7c7ae136d85e3da434094909df3a6ff06ce8586a1848c0c00914d87a877aecbb26ea30ad8230062160f3177621cc16deb4a490e9a2a649c8032dacb86341
 DIST pgbouncer-1.17.0.tar.gz 598294 BLAKE2B 697411c612b4d53c779c3170692e49afd250c28a1674a835403aa6e0ee27f1e52627b97d0ed478868f8658be7ce2323fdfd1604e5a00d739f3152c55332479b2 SHA512 5913ce542f0f694f114db8a2f339e536fb2b5887efb160b7ce3c708ae3d638bee95943104eafb9fbc4fc225649bd5625da2ccf1b56489afe33ebf8aacac48863
 DIST pgbouncer-1.18.0.tar.gz 600825 BLAKE2B 5c701d6534b9127cb8aef4e47c956644e657506104f5d9844724cc27901f48d271471ff0fe7f863bc064a30906c0ab9dfa9d0ca9472753d183419e57ae2ad333 SHA512 1c2bd55c6909a012917fcf1b139ab4bac89de1d02b346b8ade2205c15105a0c6f4f6632bf5844f654cb19e3312b8ed22bf2d14094a17f5515325c826662d5935
+DIST pgbouncer-1.19.1.tar.gz 623569 BLAKE2B b62d19e097d4fb1bccda315c9a67876aecaa8647ab092cc0157591fe64644c2c84b2785efab08ac338429e3c7d2cdd2bbff20404e71d67a9b1b5695367c2586e SHA512 1f1f56f778cf1ad7bd6a9809b54443d570eb04c2d5fe416d3bc9aa2ee8e4b3404753a15d9096c88c3a86dee534aff0268d460f862326694097ae67c83f08a589
+DIST pgbouncer-1.20.0.tar.gz 638020 BLAKE2B 1aa253b4f211e70e882e9b7789bfcdee3436b56d88d0448a122a6975deb379ff6034f563f3ec87997a3f8c2f0e6c25a09916989d486542356a5a5d41ef6e2039 SHA512 6386f80bb8dcdf6e9882f94dde1c5ff4b58cd6eb877233952e483d5fa765072588f12dfb39eab5989dee54eaa595db541042654ad47c1ea4b754304ecc69f3dd

diff --git a/dev-db/pgbouncer/pgbouncer-1.19.1.ebuild b/dev-db/pgbouncer/pgbouncer-1.19.1.ebuild
new file mode 100644
index 000000000000..0552eb5d92a9
--- /dev/null
+++ b/dev-db/pgbouncer/pgbouncer-1.19.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Lightweight connection pooler for PostgreSQL"
+HOMEPAGE="https://www.pgbouncer.org/"
+SRC_URI="https://www.pgbouncer.org/downloads/files/${PV}/pgbouncer-${PV}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+c-ares debug doc pam ssl systemd udns"
+
+# At-most-one-of, one can be enabled but not both
+REQUIRED_USE="?? ( c-ares udns )"
+
+RDEPEND="
+	>=dev-libs/libevent-2.0:=
+	>=sys-libs/glibc-2.10
+	acct-user/pgbouncer
+	c-ares? ( >=net-dns/c-ares-1.10 )
+	ssl? ( >=dev-libs/openssl-1.0.1:=[-bindist(-)] )
+	systemd? ( sys-apps/systemd )
+	udns? ( >=net-libs/udns-0.1 )
+"
+
+DEPEND="${RDEPEND}"
+
+# Tests require a local database server, wants to fiddle with iptables,
+# and doesn't support overriding.
+RESTRICT="test"
+
+src_prepare() {
+	eapply "${FILESDIR}"/pgbouncer-1.12-dirs.patch
+
+	default
+}
+
+src_configure() {
+	# --enable-debug is only used to disable stripping
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--enable-debug \
+		$(use_with c-ares cares) \
+		$(use_enable debug cassert) \
+		$(use_with pam) \
+		$(use_with ssl openssl) \
+		$(use_with systemd) \
+		$(use_with udns)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS
+	use doc && dodoc doc/*.md
+
+	newconfd "${FILESDIR}/${PN}.confd-r1" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd-r2" "${PN}"
+
+	insinto /etc
+	doins etc/pgbouncer.ini
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/logrotate" pgbouncer
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		einfo "Please read the config.txt for Configuration Directives"
+		einfo
+		einfo "For Administration Commands, see:"
+		einfo "    man pgbouncer"
+		einfo
+		einfo "By default, PgBouncer does not have access to any database."
+		einfo "GRANT the permissions needed for your application and make sure that it"
+		einfo "exists in PgBouncer's auth_file."
+	fi
+}

diff --git a/dev-db/pgbouncer/pgbouncer-1.20.0.ebuild b/dev-db/pgbouncer/pgbouncer-1.20.0.ebuild
new file mode 100644
index 000000000000..0552eb5d92a9
--- /dev/null
+++ b/dev-db/pgbouncer/pgbouncer-1.20.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Lightweight connection pooler for PostgreSQL"
+HOMEPAGE="https://www.pgbouncer.org/"
+SRC_URI="https://www.pgbouncer.org/downloads/files/${PV}/pgbouncer-${PV}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+c-ares debug doc pam ssl systemd udns"
+
+# At-most-one-of, one can be enabled but not both
+REQUIRED_USE="?? ( c-ares udns )"
+
+RDEPEND="
+	>=dev-libs/libevent-2.0:=
+	>=sys-libs/glibc-2.10
+	acct-user/pgbouncer
+	c-ares? ( >=net-dns/c-ares-1.10 )
+	ssl? ( >=dev-libs/openssl-1.0.1:=[-bindist(-)] )
+	systemd? ( sys-apps/systemd )
+	udns? ( >=net-libs/udns-0.1 )
+"
+
+DEPEND="${RDEPEND}"
+
+# Tests require a local database server, wants to fiddle with iptables,
+# and doesn't support overriding.
+RESTRICT="test"
+
+src_prepare() {
+	eapply "${FILESDIR}"/pgbouncer-1.12-dirs.patch
+
+	default
+}
+
+src_configure() {
+	# --enable-debug is only used to disable stripping
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--enable-debug \
+		$(use_with c-ares cares) \
+		$(use_enable debug cassert) \
+		$(use_with pam) \
+		$(use_with ssl openssl) \
+		$(use_with systemd) \
+		$(use_with udns)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS
+	use doc && dodoc doc/*.md
+
+	newconfd "${FILESDIR}/${PN}.confd-r1" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd-r2" "${PN}"
+
+	insinto /etc
+	doins etc/pgbouncer.ini
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/logrotate" pgbouncer
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		einfo "Please read the config.txt for Configuration Directives"
+		einfo
+		einfo "For Administration Commands, see:"
+		einfo "    man pgbouncer"
+		einfo
+		einfo "By default, PgBouncer does not have access to any database."
+		einfo "GRANT the permissions needed for your application and make sure that it"
+		einfo "exists in PgBouncer's auth_file."
+	fi
+}