From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1538080-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id B716715800A
for <garchives@archives.gentoo.org>; Sun, 16 Jul 2023 18:46:43 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 02E63E0929;
Sun, 16 Jul 2023 18:46:43 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id DFDA8E0924
for <gentoo-commits@lists.gentoo.org>; Sun, 16 Jul 2023 18:46:42 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 2C4DA335DCC
for <gentoo-commits@lists.gentoo.org>; Sun, 16 Jul 2023 18:46:42 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 8E4BEB66
for <gentoo-commits@lists.gentoo.org>; Sun, 16 Jul 2023 18:46:39 +0000 (UTC)
From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Sam James" <sam@gentoo.org>
Message-ID: <1689532936.f1048e9aac05e9400b986035ecd10c8a7d8a774c.sam@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-libs/osl/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-libs/osl/Manifest media-libs/osl/osl-1.12.13.0.ebuild
X-VCS-Directories: media-libs/osl/
X-VCS-Committer: sam
X-VCS-Committer-Name: Sam James
X-VCS-Revision: f1048e9aac05e9400b986035ecd10c8a7d8a774c
X-VCS-Branch: master
Date: Sun, 16 Jul 2023 18:46:39 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: ef379eaa-f0d8-4254-917f-04faf9c6048b
X-Archives-Hash: 3573e4c7c6c34b00ec98376b966f1143
commit: f1048e9aac05e9400b986035ecd10c8a7d8a774c
Author: Sebastian Parborg <darkdefende <AT> gmail <DOT> com>
AuthorDate: Sun Jul 2 22:55:26 2023 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jul 16 18:42:16 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f1048e9a
media-libs/osl: Version bump and fix compilation on arm64
Closes: https://bugs.gentoo.org/908870
Signed-off-by: Sebastian Parborg <darkdefende <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/31722
Signed-off-by: Sam James <sam <AT> gentoo.org>
media-libs/osl/Manifest | 1 +
media-libs/osl/osl-1.12.13.0.ebuild | 110 ++++++++++++++++++++++++++++++++++++
2 files changed, 111 insertions(+)
diff --git a/media-libs/osl/Manifest b/media-libs/osl/Manifest
index 75ed128ae73e..7bf7586baeaa 100644
--- a/media-libs/osl/Manifest
+++ b/media-libs/osl/Manifest
@@ -1,2 +1,3 @@
DIST osl-1.12.11.0.tar.gz 20287156 BLAKE2B 178db816980929cc61a0deea63f715a9f10adc41c6dd264bca8df451ef9531c4ee9477f6374f160b2a7d6fb72289a3edcbe5a3e8050ff2fdcc6bfe57fda58626 SHA512 9cf7b08f43e66d280cb90bf8c579f3a7d949934ac8e7a9289113a4a34158a43e32c9b73863f2a94a628ebc1a988923c3a7d32f0944745ae7c74dc164fdd5125e
+DIST osl-1.12.13.0.tar.gz 20286745 BLAKE2B 75a2a5d10000ba26cd11463dde710d5be3b8b2d227de45263d8bd39fd87ca064f7c6d2b2f9cea2fdb8f29ccaa94d3ef60e2ff2e0e6d867385e2298dd10ef61b6 SHA512 d7e6ab79f77f2854cbb4fa2fbe5fc92659bb015b1bbffcee2ef86185cf20235990fa3b20308601aa298fedc85d3fcd4451b7b7ff0df7def97027efe4fb8a02bc
DIST osl-1.12.7.0.tar.gz 20250356 BLAKE2B a9398243546b1bfc1e3f9602f6112a72a8e7cb6ace54e93d0e5f30d943474e82c3317596597d6a09e0f2cf04b1b21f05c31a2357e3d667d710cd2aa340f5fd63 SHA512 ec0391dfc95140fee4fa8332991cdcb0978dafc436f3e07d0293e2baa2014b8765e6b60631ae5a8bbd6e16dbcf37f04c076d7d6b2d8bfa58b78471f0d92c433f
diff --git a/media-libs/osl/osl-1.12.13.0.ebuild b/media-libs/osl/osl-1.12.13.0.ebuild
new file mode 100644
index 000000000000..dd1d1fecff02
--- /dev/null
+++ b/media-libs/osl/osl-1.12.13.0.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+# Check this on updates
+LLVM_MAX_SLOT=15
+
+inherit cmake flag-o-matic llvm toolchain-funcs python-single-r1
+
+DESCRIPTION="Advanced shading language for production GI renderers"
+HOMEPAGE="http://opensource.imageworks.com/?p=osl"
+# If a development release, please don't keyword!
+SRC_URI="https://github.com/imageworks/OpenShadingLanguage/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/OpenShadingLanguage-${PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64"
+
+X86_CPU_FEATURES=(
+ sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
+ avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
+)
+CPU_FEATURES=( ${X86_CPU_FEATURES[@]/#/cpu_flags_x86_} )
+
+IUSE="doc partio qt5 test ${CPU_FEATURES[@]%:*} python"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+ dev-libs/boost:=
+ dev-libs/pugixml
+ >=media-libs/openexr-3:0=
+ >=media-libs/openimageio-2.3.12.0:=
+ <sys-devel/clang-$((${LLVM_MAX_SLOT} + 1)):=
+ sys-libs/zlib:=
+ python? (
+ ${PYTHON_DEPS}
+ $(python_gen_cond_dep '
+ dev-python/pybind11[${PYTHON_USEDEP}]
+ ')
+ )
+ partio? ( media-libs/partio )
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+ sys-devel/bison
+ sys-devel/flex
+ virtual/pkgconfig
+"
+
+llvm_check_deps() {
+ has_version -r "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+ llvm_pkg_setup
+
+ use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+ local cpufeature
+ local mysimd=()
+ for cpufeature in "${CPU_FEATURES[@]}"; do
+ use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
+ done
+
+ # If no CPU SIMDs were used, completely disable them
+ [[ -z ${mysimd} ]] && mysimd=("0")
+
+ # This is currently needed on arm64 to get the NEON SIMD wrapper to compile the code successfully
+ # Even if there are no SIMD features selected, it seems like the code will turn on NEON support if it is available.
+ use arm64 && append-flags -flax-vector-conversions
+
+ local gcc="$(tc-getCC)"
+ local mycmakeargs=(
+ -DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+ -DINSTALL_DOCS=$(usex doc)
+ -DUSE_CCACHE=OFF
+ -DLLVM_STATIC=OFF
+ -DOSL_BUILD_TESTS=$(usex test)
+ -DSTOP_ON_WARNING=OFF
+ -DUSE_PARTIO=$(usex partio)
+ -DUSE_QT=$(usex qt5)
+ -DUSE_PYTHON=$(usex python)
+ -DPYTHON_VERSION="${EPYTHON/python}"
+ -DUSE_SIMD="$(IFS=","; echo "${mysimd[*]}")"
+ )
+
+ cmake_src_configure
+}
+
+src_test() {
+ # TODO: investigate failures
+ local myctestargs=(
+ -E "(osl-imageio|osl-imageio.opt|render-background|render-bumptest|render-mx-furnace-burley-diffuse|render-mx-furnace-sheen|render-mx-burley-diffuse|render-mx-conductor|render-mx-generalized-schlick|render-mx-generalized-schlick-glass|render-microfacet|render-oren-nayar|render-uv|render-veachmis|render-ward|render-raytypes.opt|color|color.opt|example-deformer)"
+ )
+
+ cmake_src_test
+}