[gentoo-commits] repo/gentoo:master commit in: app-pda/usbmuxd/

["Sam James" <sam@gentoo.org>]

commit:     8c71042a6e6b99c3eabe5845754809745cd74134
Author:     BalkanMadman <zurabid2016 <AT> gmail <DOT> com>
AuthorDate: Sun Jul  9 20:03:55 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jul 16 17:57:00 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8c71042a

app-pda/usbmuxd: revbump, close 3 bugs, update EAPI 7 -> 8

Updated dependencies, its required versions, added systemd dependcy when
corresponding USE flag is set, removed redundant autotools eclass, added
udev_reload.

Closes: https://bugs.gentoo.org/854843
Closes: https://bugs.gentoo.org/732984
Closes: https://bugs.gentoo.org/732912
Signed-off-by: BalkanMadman <zurabid2016 <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/31769
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-pda/usbmuxd/usbmuxd-1.1.1-r1.ebuild | 49 +++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/app-pda/usbmuxd/usbmuxd-1.1.1-r1.ebuild b/app-pda/usbmuxd/usbmuxd-1.1.1-r1.ebuild
new file mode 100644
index 000000000000..e7f3c8e166d5
--- /dev/null
+++ b/app-pda/usbmuxd/usbmuxd-1.1.1-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd udev
+
+DESCRIPTION="USB multiplex daemon for use with Apple iPhone/iPod Touch devices"
+HOMEPAGE="https://libimobiledevice.org/"
+SRC_URI="https://github.com/libimobiledevice/usbmuxd/releases/download/${PV}/${P}.tar.bz2"
+
+# src/utils.h is LGPL-2.1+, rest is found in COPYING*
+LICENSE="|| ( GPL-2 GPL-3 ) LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="selinux systemd"
+
+DEPEND="
+	acct-user/usbmux
+	>=app-pda/libimobiledevice-1.3.0:=
+	>=app-pda/libplist-2.2:=
+	virtual/libusb:1=
+"
+
+RDEPEND="
+	${DEPEND}
+	virtual/udev
+	selinux? ( sec-policy/selinux-usbmuxd )
+	systemd? ( sys-apps/systemd )
+"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_configure() {
+	econf \
+		"$(use_with systemd)" \
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)" \
+		--with-udevrulesdir="$(get_udevdir)"/rules.d
+}
+
+pkg_postrm() {
+	udev_reload
+}
+
+pkg_postinst() {
+	udev_reload
+}