[gentoo-commits] repo/gentoo:master commit in: sys-block/f3/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     b0a915f211ccb97476f690a791a660558581a881
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Tue Jul 11 12:55:58 2023 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sat Jul 15 00:51:19 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b0a915f2

sys-block/f3: EAPI8 bump, remove broken HOMEPAGE

Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 sys-block/f3/f3-8.0-r1.ebuild | 62 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/sys-block/f3/f3-8.0-r1.ebuild b/sys-block/f3/f3-8.0-r1.ebuild
new file mode 100644
index 000000000000..69e189a0304e
--- /dev/null
+++ b/sys-block/f3/f3-8.0-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Utilities to detect broken or counterfeit flash storage"
+HOMEPAGE="https://github.com/AltraMayor/f3"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/AltraMayor/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/AltraMayor/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="extra"
+
+RDEPEND="elibc_musl? ( sys-libs/argp-standalone )"
+DEPEND="${RDEPEND}
+	extra? (
+		sys-block/parted
+		virtual/udev
+	)"
+
+DOCS=( changelog README.rst )
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's:-ggdb::' \
+		-e 's:^PREFIX =:PREFIX ?=:' \
+		Makefile || die
+
+	# bug #715518
+	use elibc_musl && append-ldflags -largp
+
+	tc-export CC
+}
+
+src_compile() {
+	default
+
+	if use extra; then
+		emake V=1 extra
+	fi
+}
+
+src_install() {
+	emake PREFIX="${ED}/usr" install
+
+	if use extra; then
+		emake PREFIX="${ED}/usr" install-extra
+	fi
+
+	einstalldocs
+}