[gentoo-commits] repo/gentoo:master commit in: app-text/libebook/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     38a0e88e6ac16fa63cd95c6c153c799c01b46d58
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Tue Jul 11 13:20:07 2023 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Wed Jul 12 18:38:06 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=38a0e88e

app-text/libebook: EAPI8 bump, fix UnusedInherits

Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/31838
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-text/libebook/libebook-0.1.3-r3.ebuild | 58 ++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/app-text/libebook/libebook-0.1.3-r3.ebuild b/app-text/libebook/libebook-0.1.3-r3.ebuild
new file mode 100644
index 000000000000..b5272379bd95
--- /dev/null
+++ b/app-text/libebook/libebook-0.1.3-r3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="libe-book-${PV}"
+inherit autotools
+
+DESCRIPTION="Library parsing various ebook formats"
+HOMEPAGE="https://sourceforge.net/projects/libebook/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="doc test tools"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-text/liblangtag
+	dev-libs/icu:=
+	dev-libs/librevenge
+	dev-libs/libxml2
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	dev-util/gperf
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cppunit )
+"
+
+PATCHES=( "${FILESDIR}/${P}-icu-68.patch" )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-werror
+		$(use_with doc docs)
+		$(use_enable test tests)
+		$(use_with tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}