[gentoo-commits] repo/gentoo:master commit in: media-gfx/chafa/

["Jakov Smolić" <jsmolic@gentoo.org>]

commit:     19936fb7de562dc98cbe27723cd51797cbd26721
Author:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 12 08:37:01 2023 +0000
Commit:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
CommitDate: Wed Jul 12 08:37:47 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=19936fb7

media-gfx/chafa: Fix automagic libwebp dependency and linking error

Closes: https://bugs.gentoo.org/909429
Signed-off-by: Jakov Smolić <jsmolic <AT> gentoo.org>

 media-gfx/chafa/chafa-1.12.5-r1.ebuild | 43 ++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/media-gfx/chafa/chafa-1.12.5-r1.ebuild b/media-gfx/chafa/chafa-1.12.5-r1.ebuild
new file mode 100644
index 000000000000..6151f335b407
--- /dev/null
+++ b/media-gfx/chafa/chafa-1.12.5-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+DESCRIPTION="versatile and fast Unicode/ASCII/ANSI graphics renderer"
+HOMEPAGE="https://hpjansson.org/chafa/ https://github.com/hpjansson/chafa"
+SRC_URI="https://hpjansson.org/chafa/releases/${P}.tar.xz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+tools webp"
+
+RDEPEND="
+	dev-libs/glib:2
+	media-gfx/imagemagick:0=
+	tools? ( >=media-libs/freetype-2.0.0 )
+	webp? ( media-libs/libwebp:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	# bug 909429
+	use webp && append-ldflags -lwebp
+
+	econf \
+		--disable-man \
+		$(use_with tools) \
+		$(use_with webp)
+}
+
+src_install() {
+	local DOCS=( AUTHORS NEWS README TODO )
+	default
+
+	use tools && doman docs/chafa.1
+
+	find "${ED}" -name '*.la' -delete || die
+}