[gentoo-commits] repo/gentoo:master commit in: app-admin/xkcdpass/

["Ben Kohler" <bkohler@gentoo.org>]

commit:     a8c141b807c89ccddd56f991f17c12ffc231f5ad
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  8 13:00:21 2023 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Sat Jul  8 18:41:39 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a8c141b8

app-admin/xkcdpass: update EAPI 7 -> 8, use PEP517 build

Closes: https://bugs.gentoo.org/909863

Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 app-admin/xkcdpass/xkcdpass-1.19.3-r1.ebuild | 40 ++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

diff --git a/app-admin/xkcdpass/xkcdpass-1.19.3-r1.ebuild b/app-admin/xkcdpass/xkcdpass-1.19.3-r1.ebuild
new file mode 100644
index 000000000000..d76304959988
--- /dev/null
+++ b/app-admin/xkcdpass/xkcdpass-1.19.3-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+inherit distutils-r1 pypi
+
+DESCRIPTION="Password generator inspired by XKCD 936"
+HOMEPAGE="https://github.com/redacted/XKCD-password-generator"
+
+LICENSE="BSD CC-BY-3.0
+	l10n_de? ( GPL-3 )
+	l10n_it? ( CC-BY-SA-3.0 )
+	l10n_no? ( CC-BY-4.0 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="l10n_de +l10n_en l10n_es l10n_fi l10n_fr l10n_it l10n_no l10n_pt"
+
+distutils_enable_tests pytest
+REQUIRED_USE="test? ( l10n_en )"
+
+src_prepare() {
+	default
+
+	use l10n_de || rm ${PN}/static/{ger-anlx,eff_large_de_sample.wordlist}
+	use l10n_en || rm ${PN}/static/{eff-short,eff-special,legacy}
+	use l10n_es || rm ${PN}/static/spa-mich
+	use l10n_fi || rm ${PN}/static/fin-kotus
+	use l10n_fr || rm ${PN}/static/fr-*
+	use l10n_it || rm ${PN}/static/ita-wiki
+	use l10n_no || rm ${PN}/static/nor-nb
+	use l10n_pt || rm ${PN}/static/pt-*
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	doman ${PN}.1
+}