[gentoo-commits] repo/gentoo:master commit in: dev-python/django-sortedm2m/

["Michał Górny" <mgorny@gentoo.org>]

commit:     f0ad29bc4d8bfcda9e83b231d7aa714a2f9a3d6b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  8 14:38:49 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jul  8 14:38:49 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f0ad29bc

dev-python/django-sortedm2m: PEP517

Closes: https://bugs.gentoo.org/909914
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../django-sortedm2m-3.1.1-r1.ebuild               | 43 ++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/dev-python/django-sortedm2m/django-sortedm2m-3.1.1-r1.ebuild b/dev-python/django-sortedm2m/django-sortedm2m-3.1.1-r1.ebuild
new file mode 100644
index 000000000000..13fb9a284421
--- /dev/null
+++ b/dev-python/django-sortedm2m/django-sortedm2m-3.1.1-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Drop-in replacement for django's many to many field with sorted relations"
+HOMEPAGE="
+	https://pypi.org/project/django-sortedm2m/
+	https://github.com/jazzband/django-sortedm2m/
+"
+SRC_URI="
+	https://github.com/jazzband/django-sortedm2m/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/django[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+	)
+"
+
+python_test() {
+	local -x PYTHONPATH=test_project:${PYTHONPATH}
+	local -x DB_ENGINE=sqlite3
+	local -x DB_NAME=":memory:"
+	django-admin test -v 2 --settings=settings --noinput sortedm2m_tests ||
+		die "Tests fail with ${EPYTHON}"
+}