[gentoo-commits] repo/gentoo:master commit in: gui-apps/waybar/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     f1576683a949ef2078b7507cd094e5896cb6af8b
Author:     Kai-Chun Ning <kaichun.ning <AT> gmail <DOT> com>
AuthorDate: Thu Jul  6 12:18:27 2023 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Fri Jul  7 21:57:26 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f1576683

gui-apps/waybar: add 0.9.19

Signed-off-by: Kai-Chun Ning <kaichun.ning <AT> gmail.com>
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 gui-apps/waybar/Manifest             |   1 +
 gui-apps/waybar/waybar-0.9.19.ebuild | 102 +++++++++++++++++++++++++++++++++++
 2 files changed, 103 insertions(+)

diff --git a/gui-apps/waybar/Manifest b/gui-apps/waybar/Manifest
index c98223c28500..3beb5feaecbf 100644
--- a/gui-apps/waybar/Manifest
+++ b/gui-apps/waybar/Manifest
@@ -1 +1,2 @@
 DIST waybar-0.9.17.tar.gz 220836 BLAKE2B 78a9065f4b20c1047ce5296c8eb3b6d05ecb1e4b9994b250937e7f681cf6d7f773a5de59189544eab90ad91cfd2abf170ec76c1b125a1d7b09a22f8a7a9d43e0 SHA512 51aba7649c0e2ad3ccf22f6ede3cdf9be9c84268d31d39c5eac62e150e3b115f5560b70ebd54242fd856abec0cca5eba405f1ec153cac4cd6623523f6b19189f
+DIST waybar-0.9.19.tar.gz 249917 BLAKE2B f2c5427544e8fe5d76302e34d3d02d214aa447865e1c33c86b21b9f025c8744ae6b95b5456a97f39dfbd12ab4408f9995f823718e0b2a486633f90303af0efa4 SHA512 32120bcf39b3b16d44a42e9121645e6d28c34b73dc54d30f4dcb40cb600865e3948fc839fde2f30c956e58627f7bef7f5e93a537223ca03350a016c77dde70c7

diff --git a/gui-apps/waybar/waybar-0.9.19.ebuild b/gui-apps/waybar/waybar-0.9.19.ebuild
new file mode 100644
index 000000000000..8fcd80c7603f
--- /dev/null
+++ b/gui-apps/waybar/waybar-0.9.19.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Highly customizable Wayland bar for Sway and Wlroots based compositors"
+HOMEPAGE="https://github.com/Alexays/Waybar"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Alexays/${PN^}.git"
+else
+	SRC_URI="https://github.com/Alexays/${PN^}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN^}-${PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="evdev experimental jack +libinput +logind mpd mpris network +popups pipewire pulseaudio sndio systemd test tray +udev upower wifi"
+REQUIRED_USE="
+	mpris? ( logind )
+	upower? ( logind )
+"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	>=app-text/scdoc-1.9.2
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-cpp/cairomm:0
+	dev-cpp/glibmm:2
+	dev-cpp/gtkmm:3.0
+	dev-libs/glib:2
+	dev-libs/jsoncpp:=
+	dev-libs/libinput:=
+	dev-libs/libsigc++:2
+	>=dev-libs/libfmt-7.0.0:=
+	>=dev-libs/spdlog-1.8.5:=
+	dev-libs/date:=
+	dev-libs/wayland
+	gui-libs/wlroots:=
+	x11-libs/gtk+:3[wayland]
+	x11-libs/libxkbcommon
+	evdev? ( dev-libs/libevdev:= )
+	jack? ( virtual/jack )
+	libinput? ( dev-libs/libinput:= )
+	logind? (
+		|| ( sys-apps/systemd
+			 sys-auth/elogind )
+	)
+	mpd? ( media-libs/libmpdclient )
+	mpris? ( >=media-sound/playerctl-2 )
+	network? ( dev-libs/libnl:3 )
+	popups? ( gui-libs/gtk-layer-shell )
+	pipewire? ( media-video/wireplumber:0/0.4 )
+	pulseaudio? ( media-libs/libpulse )
+	sndio? ( media-sound/sndio:= )
+	systemd? ( sys-apps/systemd:= )
+	tray? (
+		dev-libs/libdbusmenu[gtk3]
+		dev-libs/libayatana-appindicator
+	)
+	udev? ( virtual/libudev:= )
+	upower? ( sys-power/upower )
+	wifi? ( sys-apps/util-linux )
+"
+DEPEND="${RDEPEND}
+	dev-libs/wayland-protocols
+	test? ( dev-cpp/catch:0 )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=enabled
+		-Dcava=disabled
+		$(meson_feature evdev libevdev)
+		$(meson_feature jack)
+		$(meson_feature libinput)
+		$(meson_feature logind)
+		$(meson_feature mpd)
+		$(meson_feature mpris)
+		$(meson_feature network libnl)
+		$(meson_feature popups gtk-layer-shell)
+		$(meson_feature pulseaudio)
+		$(meson_feature pipewire wireplumber)
+		$(meson_feature sndio)
+		$(meson_feature systemd)
+		$(meson_feature test tests)
+		$(meson_feature tray dbusmenu-gtk)
+		$(meson_feature udev libudev)
+		$(meson_feature upower upower_glib)
+		$(meson_feature wifi rfkill)
+		$(meson_use experimental)
+	)
+	meson_src_configure
+}