[gentoo-commits] repo/gentoo:master commit in: dev-python/iminuit/

["Michał Górny" <mgorny@gentoo.org>]

commit:     fb36ad2e83570729aeab1281b922a218096fcbad
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 23 07:22:07 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jul  2 15:09:04 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fb36ad2e

dev-python/iminuit: Bump to 2.22.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/iminuit/Manifest              |  1 +
 dev-python/iminuit/iminuit-2.22.0.ebuild | 52 ++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/dev-python/iminuit/Manifest b/dev-python/iminuit/Manifest
index 1031fe323734..2644f892ba55 100644
--- a/dev-python/iminuit/Manifest
+++ b/dev-python/iminuit/Manifest
@@ -1 +1,2 @@
 DIST iminuit-2.21.3.tar.gz 437827 BLAKE2B 5196e896769f6312bb6ba9af8d6f03bea6023a9459ccbe8553e4c10ba5dc2ed90e4e4b57bdd104f7b72e7514a50c0d4c717c76adf206d7eaddcd3c4c54c4d210 SHA512 5e48d4451caf56688143fa4590528fb4ed0660e144dbb3d1c409b84f793593478979728b4af9748b7bbdb7063e2ef7e05476a2ecd52af089f351522aadfc9ba4
+DIST iminuit-2.22.0.tar.gz 2324676 BLAKE2B e45952ee6a7f7b6ef3e1ac570abf167423c59ee82841b360278d43c4ab1e07667e143a439f7354e8257007a198c015388b9acf0a5e9aa487814d6619999eab2e SHA512 e9eda1bc7741c35bd9e9e650a626b45a2f5e4362a7c1dead57dcc461fa6e6cdbab8cfd4203c483017f8fa43e6cf1e75e074d40b92cbc3f271140d950ee4da158

diff --git a/dev-python/iminuit/iminuit-2.22.0.ebuild b/dev-python/iminuit/iminuit-2.22.0.ebuild
new file mode 100644
index 000000000000..b8a08320e0b8
--- /dev/null
+++ b/dev-python/iminuit/iminuit-2.22.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=scikit-build-core
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit cmake distutils-r1 virtualx pypi
+
+DESCRIPTION="Minuit numerical function minimization in Python"
+HOMEPAGE="
+	https://github.com/scikit-hep/iminuit/
+	https://pypi.org/project/iminuit/
+"
+
+LICENSE="MIT LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# warnings caught as exceptions, sigh
+		# https://github.com/scikit-hep/iminuit/pull/907
+		tests/test_cost.py::test_UnbinnedNLL_visualize
+
+		# precision error
+		tests/test_cost.py::test_Template_with_model_2D
+	)
+
+	epytest -p no:pytest-describe || die "Tests failed with ${EPYTHON}"
+}