[gentoo-commits] repo/gentoo:master commit in: media-video/ffmpeg-chromium/

["James Le Cuirot" <chewi@gentoo.org>]

commit:     b2912bac0ae24566dd8202a1a3fedd79981a9e87
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 21 08:24:56 2023 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Wed Jun 21 08:27:14 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b2912bac

media-video/ffmpeg-chromium: Drop old 112

Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 media-video/ffmpeg-chromium/Manifest               |   1 -
 .../ffmpeg-chromium/ffmpeg-chromium-112.ebuild     | 233 ---------------------
 2 files changed, 234 deletions(-)

diff --git a/media-video/ffmpeg-chromium/Manifest b/media-video/ffmpeg-chromium/Manifest
index 2163fbebb490..2a8f8055040d 100644
--- a/media-video/ffmpeg-chromium/Manifest
+++ b/media-video/ffmpeg-chromium/Manifest
@@ -1,4 +1,3 @@
 DIST ffmpeg-chromium-102.tar.gz 15165192 BLAKE2B ecf9b9ff538730d8a265e25e3d30900b119bfa5baa8e097e58151d744c95b3e768b96f477f6394015cd77a8ae35991c7cdaee5fb2f700d129b6c6d7ee87b34d9 SHA512 f5aa4c47e801d2547321c7995240e004706f9b5835610f9726ac45a63ac58a62de64d463ddeb8c1a001d31d89a4dbaee3a1be568c33316f29dc2b675b2f3161a
 DIST ffmpeg-chromium-106.tar.xz 9707176 BLAKE2B 8ab9b006328e15faa38b8014f2870e7a9fd9eaacc723cd6079bfaadc05db4d1f8c542dff5a331e1f93c9c877eea6d2ed0dc2bf567c77680227b22b2a9baf8834 SHA512 9f04feee42bf548cbda542be16f186bfe0d8179289a1512cf77ec492a8608b2c9d5c758f93fb6d229be67c20762075dd266fa4b203556f8b7ec4bf66579f2b6b
-DIST ffmpeg-chromium-112.tar.xz 9888952 BLAKE2B 48a2e0e93a890ae3ec436b2c9504c6f5d063c2ed04ed67db9c8b17f1d1111ce56519a8af8c44635901de7f46fb2f0529818e70874a17432c64c1192968a3ae4b SHA512 f0d5e7cd77d5daeddf1c2d47b3435bf9306fdbf23239890cbbaef86ad6e462e9606da5282c39dcd5f32ac6a721b5dd5f01c1f1525f6a66a0dad8a927db2c3217
 DIST ffmpeg-chromium-114.tar.xz 9934024 BLAKE2B cc11bd00bcf6bef5f946a16f1544881c71503207ba3c6ec57cdc37124ea562366dced2e029f31e57a6f78ec7073412ac0b8ec470d14975a3cc40fad2e96ec5df SHA512 1b1743664d58f5b92971d113ea441604e0b46f28b22df1b02ab0431b8e884789fb6d81b4f50ff1526f716381abcc63e1b336d23edd9ea28abe8b3526fba08ce9

diff --git a/media-video/ffmpeg-chromium/ffmpeg-chromium-112.ebuild b/media-video/ffmpeg-chromium/ffmpeg-chromium-112.ebuild
deleted file mode 100644
index 45bd93ba86c5..000000000000
--- a/media-video/ffmpeg-chromium/ffmpeg-chromium-112.ebuild
+++ /dev/null
@@ -1,233 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit flag-o-matic toolchain-funcs
-
-COMMIT="ee0c52d52036ecadfd38affec86c04937480bedb"
-DESCRIPTION="FFmpeg built specifically for codec support in Chromium-based browsers"
-HOMEPAGE="https://ffmpeg.org/"
-SRC_URI="https://dev.gentoo.org/~chewi/distfiles/${P}.tar.xz"
-
-SLOT="${PV}"
-LICENSE="
-	!gpl? ( LGPL-2.1 )
-	gpl? ( GPL-2 )
-"
-
-KEYWORDS="amd64 ~arm ~arm64"
-
-# Options to use as use_enable in the foo[:bar] form.
-# This will feed configure with $(use_enable foo bar)
-# or $(use_enable foo foo) if no :bar is set.
-# foo is added to IUSE.
-FFMPEG_FLAG_MAP=(
-		cpudetection:runtime-cpudetect debug
-		+gpl
-		vaapi vdpau vulkan
-		# decoders
-		mmal +opus:libopus
-		nvenc:ffnvcodec
-		# Threads; we only support pthread for now but ffmpeg supports more
-		+threads:pthreads
-)
-
-IUSE="
-	${FFMPEG_FLAG_MAP[@]%:*}
-"
-
-# Strings for CPU features in the useflag[:configure_option] form
-# if :configure_option isn't set, it will use 'useflag' as configure option
-ARM_CPU_FEATURES=(
-	cpu_flags_arm_thumb:armv5te
-	cpu_flags_arm_v6:armv6
-	cpu_flags_arm_thumb2:armv6t2
-	cpu_flags_arm_neon:neon
-	cpu_flags_arm_vfp:vfp
-	cpu_flags_arm_vfpv3:vfpv3
-	cpu_flags_arm_v8:armv8
-)
-ARM_CPU_REQUIRED_USE="
-	arm64? ( cpu_flags_arm_v8 )
-	cpu_flags_arm_v8? (  cpu_flags_arm_vfpv3 cpu_flags_arm_neon )
-	cpu_flags_arm_neon? ( cpu_flags_arm_thumb2 cpu_flags_arm_vfp )
-	cpu_flags_arm_vfpv3? ( cpu_flags_arm_vfp )
-	cpu_flags_arm_thumb2? ( cpu_flags_arm_v6 )
-	cpu_flags_arm_v6? ( cpu_flags_arm_thumb )
-"
-X86_CPU_FEATURES_RAW=( 3dnow:amd3dnow 3dnowext:amd3dnowext aes:aesni avx:avx avx2:avx2 fma3:fma3 fma4:fma4 mmx:mmx mmxext:mmxext sse:sse sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4 sse4_2:sse42 xop:xop )
-X86_CPU_FEATURES=( ${X86_CPU_FEATURES_RAW[@]/#/cpu_flags_x86_} )
-X86_CPU_REQUIRED_USE="
-	cpu_flags_x86_avx2? ( cpu_flags_x86_avx )
-	cpu_flags_x86_fma4? ( cpu_flags_x86_avx )
-	cpu_flags_x86_fma3? ( cpu_flags_x86_avx )
-	cpu_flags_x86_xop?  ( cpu_flags_x86_avx )
-	cpu_flags_x86_avx?  ( cpu_flags_x86_sse4_2 )
-	cpu_flags_x86_aes? ( cpu_flags_x86_sse4_2 )
-	cpu_flags_x86_sse4_2?  ( cpu_flags_x86_sse4_1 )
-	cpu_flags_x86_sse4_1?  ( cpu_flags_x86_ssse3 )
-	cpu_flags_x86_ssse3?  ( cpu_flags_x86_sse3 )
-	cpu_flags_x86_sse3?  ( cpu_flags_x86_sse2 )
-	cpu_flags_x86_sse2?  ( cpu_flags_x86_sse )
-	cpu_flags_x86_sse?  ( cpu_flags_x86_mmxext )
-	cpu_flags_x86_mmxext?  ( cpu_flags_x86_mmx )
-	cpu_flags_x86_3dnowext?  ( cpu_flags_x86_3dnow )
-	cpu_flags_x86_3dnow?  ( cpu_flags_x86_mmx )
-"
-
-CPU_FEATURES_MAP=(
-	${ARM_CPU_FEATURES[@]}
-	${X86_CPU_FEATURES[@]}
-)
-IUSE="${IUSE}
-	${CPU_FEATURES_MAP[@]%:*}"
-
-CPU_REQUIRED_USE="
-	${ARM_CPU_REQUIRED_USE}
-	${X86_CPU_REQUIRED_USE}
-"
-
-RDEPEND="
-	mmal? ( media-libs/raspberrypi-userland )
-	opus? ( >=media-libs/opus-1.0.2-r2 )
-	vaapi? ( >=media-libs/libva-1.2.1-r1:0= )
-	nvenc? ( >=media-libs/nv-codec-headers-9.1.23.1 )
-	vdpau? ( >=x11-libs/libvdpau-0.7 )
-	vulkan? ( >=media-libs/vulkan-loader-1.2.189:= )
-"
-
-DEPEND="${RDEPEND}
-"
-BDEPEND="
-	>=sys-devel/make-3.81
-	virtual/pkgconfig
-	cpu_flags_x86_mmx? ( || ( >=dev-lang/nasm-2.13 >=dev-lang/yasm-1.3 ) )
-"
-
-REQUIRED_USE="
-	${CPU_REQUIRED_USE}"
-RESTRICT="
-	test
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-100.patch
-	"${FILESDIR}"/chromium.patch
-)
-
-src_prepare() {
-	export revision=git-N-g${COMMIT:0:10}
-	default
-
-	# -fdiagnostics-color=auto gets appended after user flags which
-	# will ignore user's preference.
-	sed -i -e '/check_cflags -fdiagnostics-color=auto/d' configure || die
-
-	echo 'include $(SRC_PATH)/ffbuild/libffmpeg.mak' >> Makefile || die
-}
-
-src_configure() {
-	local myconf=( )
-
-	# bug 842201
-	use ia64 && tc-is-gcc && append-flags \
-		-fno-tree-ccp \
-		-fno-tree-dominator-opts \
-		-fno-tree-fre \
-		-fno-code-hoisting \
-		-fno-tree-pre \
-		-fno-tree-vrp
-
-	local ffuse=( "${FFMPEG_FLAG_MAP[@]}" )
-
-	for i in "${ffuse[@]#+}" ; do
-		myconf+=( $(use_enable ${i%:*} ${i#*:}) )
-	done
-
-	# CPU features
-	for i in "${CPU_FEATURES_MAP[@]}" ; do
-		use ${i%:*} || myconf+=( --disable-${i#*:} )
-	done
-
-	# Try to get cpu type based on CFLAGS.
-	# Bug #172723
-	# We need to do this so that features of that CPU will be better used
-	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
-	# will just ignore it.
-	for i in $(get-flag mcpu) $(get-flag march) ; do
-		[[ ${i} = native ]] && i="host" # bug #273421
-		myconf+=( --cpu=${i} )
-		break
-	done
-
-	# LTO support, bug #566282, bug #754654, bug #772854
-	is-flagq "-flto*" && myconf+=( "--enable-lto" )
-	filter-lto
-
-	# Mandatory configuration
-	myconf=(
-		--disable-stripping
-		# This is only for hardcoded cflags; those are used in configure checks that may
-		# interfere with proper detections, bug #671746 and bug #645778
-		# We use optflags, so that overrides them anyway.
-		--disable-optimizations
-		--disable-libcelt # bug #664158
-		"${myconf[@]}"
-	)
-
-	# cross compile support
-	if tc-is-cross-compiler ; then
-		myconf+=( --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}- --host-cc="$(tc-getBUILD_CC)" )
-		case ${CHOST} in
-			*mingw32*)
-				myconf+=( --target-os=mingw32 )
-				;;
-			*linux*)
-				myconf+=( --target-os=linux )
-				;;
-		esac
-	fi
-
-	# Use --extra-libs if needed for LIBS
-	set -- "${S}/configure" \
-		--prefix="${EPREFIX}/usr" \
-		--libdir="${EPREFIX}/usr/$(get_libdir)" \
-		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
-		--cc="$(tc-getCC)" \
-		--cxx="$(tc-getCXX)" \
-		--ar="$(tc-getAR)" \
-		--nm="$(tc-getNM)" \
-		--strip="$(tc-getSTRIP)" \
-		--ranlib="$(tc-getRANLIB)" \
-		--pkg-config="$(tc-getPKG_CONFIG)" \
-		--optflags="${CFLAGS}" \
-		--disable-all \
-		--disable-autodetect \
-		--disable-error-resilience \
-		--disable-everything \
-		--disable-faan \
-		--disable-iconv \
-		--disable-network \
-		--enable-avcodec \
-		--enable-avformat \
-		--enable-avutil \
-		--enable-decoder=aac,flac,h264,libopus,mp3,pcm_alaw,pcm_f32le,pcm_mulaw,pcm_s16be,pcm_s16le,pcm_s24be,pcm_s24le,pcm_s32le,pcm_u8,theora,vorbis,vp8 \
-		--enable-demuxer=aac,flac,matroska,mov,mp3,ogg,wav \
-		--enable-parser=aac,flac,h264,mpegaudio,opus,vorbis,vp3,vp8,vp9 \
-		--enable-pic \
-		--enable-static \
-		"${myconf[@]}" \
-		${EXTRA_FFMPEG_CONF}
-
-	echo "${@}"
-	"${@}" || die
-}
-
-src_compile() {
-	emake V=1 libffmpeg
-}
-
-src_install() {
-	emake V=1 DESTDIR="${D}" install-libffmpeg
-}