[gentoo-commits] repo/gentoo:master commit in: dev-util/astyle/

["Sam James" <sam@gentoo.org>]

commit:     4661851df75f7b5146b5d2e503ad36f38fc945ea
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 19 20:39:20 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Jun 19 21:26:52 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4661851d

dev-util/astyle: add 3.4

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/astyle/Manifest          |  1 +
 dev-util/astyle/astyle-3.4.ebuild | 77 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/dev-util/astyle/Manifest b/dev-util/astyle/Manifest
index 80f3b13b6025..bb94130b5155 100644
--- a/dev-util/astyle/Manifest
+++ b/dev-util/astyle/Manifest
@@ -1 +1,2 @@
+DIST astyle-3.4.tar.bz2 226981 BLAKE2B 1d3db58a7123e516657f224c217ac300fc9d75a50c3ed5cddf8d51868e251397c45ffb43dac9a9f414eaf47896171002bd5eb857ffe4336153fb1bddff3d7eb7 SHA512 c81fb18a8ebba89500639377291d320107983ebc842fa99973d00efa08c41950ffac7fe78faddb3d025b30eae58ccf8d643582965c1a3df2604f0a0240fd8e82
 DIST astyle_3.1_linux.tar.gz 185589 BLAKE2B d0bc9bf3403de89d207f33ac885c7cd57fd1e71314c947e1593ee24ade9ce36c83c6fd8e7021f44d8d3b344ea3add63fa5a7b246c40f10193dc38b51e7ad36bc SHA512 2e8f13d291abda66bbba30174c364c81a81a490e0a21376f7da7cf471644c22caa37b9eefb100d093bf26d1a8bfa9d2f14b4c2a9b75b3cb84428b4514e277ff2

diff --git a/dev-util/astyle/astyle-3.4.ebuild b/dev-util/astyle/astyle-3.4.ebuild
new file mode 100644
index 000000000000..729799088abb
--- /dev/null
+++ b/dev-util/astyle/astyle-3.4.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs java-pkg-opt-2
+
+DESCRIPTION="Artistic Style is a re-indenter and reformatter for C++, C and Java source code"
+HOMEPAGE="https://astyle.sourceforge.net/"
+SRC_URI="mirror://sourceforge/astyle/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0/3.2"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="examples java static-libs"
+
+DEPEND="
+	app-arch/xz-utils
+	java? ( >=virtual/jdk-1.6:= )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	if use java ; then
+		java-pkg-opt-2_src_prepare
+		sed	-e "s:^\(JAVAINCS\s*\)=.*$:\1= $(java-pkg_get-jni-cflags):" \
+			-e "s:ar crs:$(tc-getAR) crs:" \
+			-i build/gcc/Makefile || die
+	else
+		default
+	fi
+}
+
+src_configure() {
+	tc-export CXX
+	default
+}
+
+src_compile() {
+	# ../build/clang/Makefile is identical except for CXX line.
+	emake CXX="$(tc-getCXX)" -f ../build/gcc/Makefile -C src \
+		${PN} \
+		shared \
+		$(usev java) \
+		$(usev static-libs static)
+}
+
+src_install() {
+	doheader src/${PN}.h
+
+	pushd src/bin >/dev/null || die
+	dobin ${PN}
+
+	local libastylename="lib${PN}.so.${SLOT##*/}.0"
+	local libastylejname="lib${PN}j.so.${SLOT##*/}.0"
+	local libdestdir="/usr/$(get_libdir)"
+
+	dolib.so "${libastylename}"
+	dosym "${libastylename}" "${libdestdir}/lib${PN}.so.$(ver_cut 1 ${SLOT##*/})"
+	dosym "${libastylename}" "${libdestdir}/lib${PN}.so"
+	if use java ; then
+		dolib.so "${libastylejname}"
+		dosym "${libastylejname}" "${libdestdir}/lib${PN}j.so.$(ver_cut 1 ${SLOT##*/})"
+		dosym "${libastylejname}" "${libdestdir}/lib${PN}j.so"
+	fi
+	if use static-libs ; then
+		dolib.a lib${PN}.a
+	fi
+	popd >/dev/null || die
+	if use examples ; then
+		docinto examples
+		dodoc -r file/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	local HTML_DOCS=( doc/. )
+	einstalldocs
+}