[gentoo-commits] repo/gentoo:master commit in: media-radio/tucnak/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     54060cc8a7d501bc43f049a118d051278194f4f3
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 18 11:05:04 2023 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Sun Jun 18 11:05:04 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=54060cc8

media-radio/tucnak: add 4.44

Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 media-radio/tucnak/Manifest           |  1 +
 media-radio/tucnak/tucnak-4.44.ebuild | 68 +++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/media-radio/tucnak/Manifest b/media-radio/tucnak/Manifest
index 18f7b1665f31..a45043e85260 100644
--- a/media-radio/tucnak/Manifest
+++ b/media-radio/tucnak/Manifest
@@ -1 +1,2 @@
 DIST tucnak-4.43.tar.gz 3607575 BLAKE2B 96aba674db8357cf86c870ccdb45f0d1c466a0dd2c446b066146935eee68a47352abd21f550d8d882496be153554ac0db5afbe40dfff285a557792c14271ccd5 SHA512 98f70b1c90218f97fdac8cd03029023cc5bc0909036a419664b72eebf03280b9aefee4321efff78b43da75c9e1c6559d04df06e39edf9fa753d3e3a372f16caa
+DIST tucnak-4.44.tar.gz 3613373 BLAKE2B 9bd9ae37c3adadfe5f52b3d1c848427607a44a7527f0493dc5acc674acd358cc100a29658f981248275008b7227957cdd031da80fe622acfa24d482101407bb6 SHA512 ae6115ba4b1d90e63a47ac9e1d659836287bfbd8b616543134152756322d6c794bc795a3fdd9d4cf11869828c8bf81927c3fa71fcc8699d123c6e58cb7d9865c

diff --git a/media-radio/tucnak/tucnak-4.44.ebuild b/media-radio/tucnak/tucnak-4.44.ebuild
new file mode 100644
index 000000000000..781914045c05
--- /dev/null
+++ b/media-radio/tucnak/tucnak-4.44.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	~dev-libs/libzia-4.43
+	media-libs/libsndfile
+	media-libs/libsdl2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib:= )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}