[gentoo-commits] repo/gentoo:master commit in: dev-python/pypy3_10-exe/

["Michał Górny" <mgorny@gentoo.org>]

commit:     31fcd7747a1849965eee74bde9ebec6b802d3c00
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 16 12:56:47 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Jun 16 17:03:29 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=31fcd774

dev-python/pypy3_10-exe: Bump to 7.3.12

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pypy3_10-exe/Manifest                   |   2 +
 dev-python/pypy3_10-exe/pypy3_10-exe-7.3.12.ebuild | 127 +++++++++++++++++++++
 2 files changed, 129 insertions(+)

diff --git a/dev-python/pypy3_10-exe/Manifest b/dev-python/pypy3_10-exe/Manifest
index a5f10a112902..09ca609fe384 100644
--- a/dev-python/pypy3_10-exe/Manifest
+++ b/dev-python/pypy3_10-exe/Manifest
@@ -1,2 +1,4 @@
+DIST pypy3.10-gentoo-patches-7.3.12.tar.xz 3736 BLAKE2B 9283b05e84b385289900a07a8591d830589c5ae9cb77dc5350cb0c6a4c8f71118ed13d270060d900079ec8f7d57c256a973f55016299d001e8be585ba2a2ad30 SHA512 9ec7d8d6e16719971d43cc37cf3fdfaf76b1a707ae37b02681b0a07d17c60df503e926fa8034c9f4866d46136089a0059ee165a0c222f56f2537f374e915b3ca
 DIST pypy3.10-gentoo-patches-7.3.12rc2.tar.xz 3416 BLAKE2B 5aac048a8758aff3ea43de12da8b5bcffb5ca1a97d58b307d9badb9583376f0c2513d034ec394216b5d20ab5985a7f1142bd20f9affd5c48b8b86a5286194bad SHA512 3980fef808ac4d9530f9cc4f17ff70eff2612c31f7470c62a4ad83d727216c19cac62d6874d7187004ba83e1fbd349efebc303e0f74c3491baebaf8a630f6a89
+DIST pypy3.10-v7.3.12-src.tar.bz2 23009064 BLAKE2B ad45d90de9ae51803ebcfa202763889f92f7e5c2939331433a496e53ca67dd6eeaf9c61e16cb648945409dff3c6dd6b8a2a01dfe1bed6cd6a9df98f112bff181 SHA512 080520c7de267e17a2823f06cd0a15c108a2c32fc296d6e24782050eb546fa74852d948ede2c381dba110774121b20efc3a07b553acd0ac0db4a844dfc09069e
 DIST pypy3.10-v7.3.12rc2-src.tar.bz2 23030434 BLAKE2B a94e427450350c239bd514a9747813337b1208edafeb6a05c18c0b7cd2075edd480d2081d605e62ec9b1ed227154396ed30bba05294db722a43de33c46e34893 SHA512 9e850d3ba16db7dc36069e50c3026d812f08763c5a92fc5e43fff0fcf54fad202c2a13b7101c49d52ee2fb89062fab335473334ccdd067d69ace6d9ecf7f92d2

diff --git a/dev-python/pypy3_10-exe/pypy3_10-exe-7.3.12.ebuild b/dev-python/pypy3_10-exe/pypy3_10-exe-7.3.12.ebuild
new file mode 100644
index 000000000000..90c4bbea14a2
--- /dev/null
+++ b/dev-python/pypy3_10-exe/pypy3_10-exe-7.3.12.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit check-reqs pax-utils toolchain-funcs
+
+PYPY_PV=${PV%_p*}
+PYVER=3.10
+MY_P="pypy${PYVER}-v${PYPY_PV/_}"
+PATCHSET="pypy${PYVER}-gentoo-patches-${PV/_}"
+
+DESCRIPTION="PyPy3 executable (build from source)"
+HOMEPAGE="https://www.pypy.org/"
+SRC_URI="
+	https://buildbot.pypy.org/pypy/${MY_P}-src.tar.bz2
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
+"
+S="${WORKDIR}/${MY_P}-src"
+
+LICENSE="MIT"
+SLOT="${PYPY_PV}"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+jit low-memory ncurses cpu_flags_x86_sse2"
+
+RDEPEND="
+	app-arch/bzip2:0=
+	dev-libs/expat:0=
+	dev-libs/libffi:0=
+	>=sys-libs/zlib-1.1.3:0=
+	virtual/libintl:0=
+	ncurses? ( sys-libs/ncurses:0= )
+	!dev-python/pypy3-exe-bin:${SLOT}
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	dev-python/pypy
+"
+
+check_env() {
+	if use low-memory; then
+		CHECKREQS_MEMORY="1750M"
+		use amd64 && CHECKREQS_MEMORY="3500M"
+	else
+		CHECKREQS_MEMORY="3G"
+		use amd64 && CHECKREQS_MEMORY="6G"
+	fi
+
+	check-reqs_pkg_pretend
+}
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && check_env
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && check_env
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+	default
+}
+
+src_configure() {
+	tc-export CC
+
+	local jit_backend
+	if use jit; then
+		jit_backend='--jit-backend='
+
+		# We only need the explicit sse2 switch for x86.
+		# On other arches we can rely on autodetection which uses
+		# compiler macros. Plus, --jit-backend= doesn't accept all
+		# the modern values...
+
+		if use x86; then
+			if use cpu_flags_x86_sse2; then
+				jit_backend+=x86
+			else
+				jit_backend+=x86-without-sse2
+			fi
+		else
+			jit_backend+=auto
+		fi
+	fi
+
+	local args=(
+		--no-shared
+		$(usex jit -Ojit -O2)
+
+		${jit_backend}
+
+		pypy/goal/targetpypystandalone
+		--withmod-bz2
+		$(usex ncurses --with{,out}mod-_minimal_curses)
+	)
+
+	local interp=( pypy )
+	if use low-memory; then
+		local -x PYPY_GC_MAX_DELTA=200MB
+		interp+=( --jit loop_longevity=300 )
+	fi
+
+	# translate into the C sources
+	# we're going to build them ourselves since otherwise pypy does not
+	# free up the unneeded memory before spawning the compiler
+	set -- "${interp[@]}" rpython/bin/rpython --batch --source "${args[@]}"
+	echo -e "\033[1m${@}\033[0m"
+	"${@}" || die "translation failed"
+}
+
+src_compile() {
+	emake -C "${T}"/usession*-0/testing_1
+}
+
+src_install() {
+	cd "${T}"/usession*-0 || die
+	newbin "testing_1/pypy${PYVER}-c" "pypy${PYVER}-c-${PYPY_PV}"
+	insinto "/usr/include/pypy${PYVER}/${PYPY_PV}"
+	doins *.h
+	pax-mark m "${ED}/usr/bin/pypy${PYVER}-c-${PYPY_PV}"
+}