[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

["Marek Szuba" <marecki@gentoo.org>]

commit:     5bff8000ddcb3c6bb4a72afd407f53fccee88089
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 13 21:46:21 2023 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Tue Jun 13 21:46:48 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5bff8000

sys-apps/fwupd: add 1.8.16

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 sys-apps/fwupd/Manifest            |   1 +
 sys-apps/fwupd/fwupd-1.8.16.ebuild | 193 +++++++++++++++++++++++++++++++++++++
 2 files changed, 194 insertions(+)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index 6f92e9a5db7f..961de78eadd6 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,2 +1,3 @@
 DIST fwupd-1.8.14.tar.xz 3733176 BLAKE2B 6d17ee9ce1fb46a9d0a8a97d54f1873888635805af00a05ad365b32d48d6e58b48b52d706400067ca8cf6f6b846f6b8799c44d66ec64ab2fca5812b199ac2ac5 SHA512 80669f1c8ca60ac646f9a7aa4028edd23d1fc6853d999f60d292fabbfc81733f06b1f76a2987f0af62a739aa2cf5cc75fc40c9283fd37f4d8157f1a08df6fcd2
 DIST fwupd-1.8.15.tar.xz 3734344 BLAKE2B 1b098b98b7700e4a9322c53d1c52408e581d124822d1cc7f4a9d25cf3a9169f3596c559f7b9997930e43a9da983fb0c232674726520c9565c250e6db3e4bc0fa SHA512 c7ad249118d84dab903644975761030bcc16d65d9cd4f8d4a58399f79b30a4889cc62d502d28037d61738da7287998328e6042d29c21c5113c29bfc1ba4c0b75
+DIST fwupd-1.8.16.tar.xz 3735128 BLAKE2B ae72b850f859e5c7cadbe78b86c2d9d0fc7b27f2de5838ab5c1ab7d7adf41d14ab5bfcb7db72795ca90b7626cf19212f3bb61e15e7ecdbd00a9a454aa80523f8 SHA512 25dd773ca703ab6ad11eb042948bb719c2f3974a2e89ac8f9ae524384bce2c8a3d41e5754a5e0ab5595c14720737d53921dbf2859dd33519dcc480d227aac6c6

diff --git a/sys-apps/fwupd/fwupd-1.8.16.ebuild b/sys-apps/fwupd/fwupd-1.8.16.ebuild
new file mode 100644
index 000000000000..26cd89fbc3f1
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.8.16.ebuild
@@ -0,0 +1,193 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-single-r1 vala udev xdg
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="amt +archive bash-completion bluetooth cbor dell elogind fastboot flashrom gnutls gtk-doc +gusb introspection logitech lzma minimal modemmanager nvme policykit spi +sqlite synaptics systemd test tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( elogind minimal systemd )
+	dell? ( uefi )
+	fastboot? ( gusb )
+	logitech? ( gusb )
+	minimal? ( !introspection )
+	modemmanager? ( gusb )
+	spi? ( lzma )
+	synaptics? ( gnutls )
+	test? ( archive gusb )
+	uefi? ( gnutls )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+	>=dev-util/meson-0.60.0
+	virtual/pkgconfig
+	gtk-doc? (
+		$(python_gen_cond_dep '
+			>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+		')
+		>=dev-util/gi-docgen-2021.1
+	)
+	bash-completion? ( >=app-shells/bash-completion-2.0 )
+	introspection? ( dev-libs/gobject-introspection )
+	test? (
+		dev-util/umockdev
+		net-libs/gnutls[tools]
+	)
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	app-arch/xz-utils
+	>=dev-libs/glib-2.58:2
+	dev-libs/json-glib
+	dev-libs/libgudev:=
+	>=dev-libs/libjcat-0.1.4[gpg,pkcs7]
+	>=dev-libs/libxmlb-0.1.13:=[introspection?]
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	')
+	net-misc/curl
+	archive? ( app-arch/libarchive:= )
+	cbor? ( dev-libs/libcbor:= )
+	dell? (
+		>=app-crypt/tpm2-tss-2.0
+		>=sys-libs/libsmbios-2.4.0
+	)
+	elogind? ( >=sys-auth/elogind-211 )
+	flashrom? ( >=sys-apps/flashrom-1.2-r3 )
+	gnutls? ( net-libs/gnutls )
+	gusb? ( >=dev-libs/libgusb-0.3.5[introspection?] )
+	logitech? ( dev-libs/protobuf-c:= )
+	lzma? ( app-arch/xz-utils )
+	modemmanager? ( net-misc/modemmanager[qmi] )
+	policykit? ( >=sys-auth/polkit-0.114 )
+	sqlite? ( dev-db/sqlite )
+	systemd? ( >=sys-apps/systemd-211 )
+	tpm? ( app-crypt/tpm2-tss:= )
+	uefi? (
+		sys-apps/fwupd-efi
+		sys-boot/efibootmgr
+		sys-fs/udisks
+		sys-libs/efivar
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	sys-apps/dbus
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	x11-libs/pango[introspection]
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.8.13-installed_tests.patch
+)
+
+src_prepare() {
+	default
+
+	vala_setup
+
+	# c.f. https://github.com/fwupd/fwupd/issues/1414
+	sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
+		-i plugins/thunderbolt/meson.build || die
+
+	sed -e "/install_dir.*'doc'/s/doc/gtk-doc/" \
+		-i docs/meson.build || die
+
+	python_fix_shebang "${S}"/contrib/*.py
+}
+
+src_configure() {
+	local plugins=(
+		-Dplugin_gpio="enabled"
+		$(meson_feature amt plugin_intel_me)
+		$(meson_feature dell plugin_dell)
+		$(meson_feature fastboot plugin_fastboot)
+		$(meson_feature flashrom plugin_flashrom)
+		$(meson_feature gusb plugin_uf2)
+		$(meson_feature logitech plugin_logitech_bulkcontroller)
+		$(meson_feature modemmanager plugin_modem_manager)
+		$(meson_feature nvme plugin_nvme)
+		$(meson_use spi plugin_intel_spi)
+		$(meson_feature synaptics plugin_synaptics_mst)
+		$(meson_feature synaptics plugin_synaptics_rmi)
+		$(meson_feature tpm plugin_tpm)
+		$(meson_feature uefi plugin_uefi_capsule)
+		$(meson_use uefi plugin_uefi_capsule_splash)
+		$(meson_feature uefi plugin_uefi_pk)
+	)
+	if use ppc64 || use riscv ; then
+		plugins+=( -Dplugin_msr="disabled" )
+	fi
+
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dbuild="$(usex minimal standalone all)"
+		-Dconsolekit="disabled"
+		-Dcurl="enabled"
+		-Defi_binary="false"
+		-Dman="true"
+		-Dsupported_build="enabled"
+		-Dudevdir="${EPREFIX}$(get_udevdir)"
+		$(meson_feature archive libarchive)
+		$(meson_use bash-completion bash_completion)
+		$(meson_feature bluetooth bluez)
+		$(meson_feature cbor)
+		$(meson_feature elogind)
+		$(meson_feature gnutls)
+		$(meson_feature gtk-doc docs)
+		$(meson_feature gusb)
+		$(meson_feature lzma)
+		$(meson_feature introspection)
+		$(meson_feature policykit polkit)
+		$(meson_feature sqlite)
+		$(meson_feature systemd)
+		$(meson_use test tests)
+
+		${plugins[@]}
+	)
+	use uefi && emesonargs+=( -Defi_os_dir="gentoo" )
+	export CACHE_DIRECTORY="${T}"
+	meson_src_configure
+}
+
+src_test() {
+	LC_ALL="C" meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use minimal ; then
+		newinitd "${FILESDIR}"/${PN}-r2 ${PN}
+
+		if ! use systemd ; then
+			# Don't timeout when fwupd is running (#673140)
+			sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+				-i "${ED}"/etc/${PN}/daemon.conf || die
+		fi
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	use minimal || udev_reload
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	use minimal || udev_reload
+}