[gentoo-commits] repo/gentoo:master commit in: dev-libs/libjcat/

["Marek Szuba" <marecki@gentoo.org>]

commit:     bc603287c1d560b68b1bcc92022f56c1ac57d8ce
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 13 21:21:31 2023 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Tue Jun 13 21:46:47 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bc603287

dev-libs/libjcat: add 0.1.14

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 dev-libs/libjcat/Manifest              |  1 +
 dev-libs/libjcat/libjcat-0.1.14.ebuild | 68 ++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-libs/libjcat/Manifest b/dev-libs/libjcat/Manifest
index 02e04ee5f7e4..582d6731c78a 100644
--- a/dev-libs/libjcat/Manifest
+++ b/dev-libs/libjcat/Manifest
@@ -1 +1,2 @@
 DIST libjcat-0.1.13.tar.gz 69950 BLAKE2B 5ff85feff37c5728c8cace5e2f38c179c65a82954a23fd26794a5483cdf29e07601cdaffe27c28a28f7d2b0d57aa3800589c20e19e0a512768f5f87176a56789 SHA512 a66082e3c1641b427af971843822a7893cd40dbb82a596737fd6445fe8e1b527a111dd8f48b9e25a563f0d13e77e22d4c2364ddf96cac38d3e2df5010b37708a
+DIST libjcat-0.1.14.tar.gz 70018 BLAKE2B 71329e6fc04ef37e5af215c88b4a5a03fbd65143604da57b0357d4bd07896a22a98b9028d8529234655adb37e5cefe226d09d987e798bce17b47fef1e1142d1f SHA512 837a50ad31a736a36bd9df26b151c198e18873df0e7444502b7a6e26a86df15f1df970112f2dd22658960389fdfb78a2c601274e2b5c46ec82fceef5aad778c1

diff --git a/dev-libs/libjcat/libjcat-0.1.14.ebuild b/dev-libs/libjcat/libjcat-0.1.14.ebuild
new file mode 100644
index 000000000000..45b6002047d2
--- /dev/null
+++ b/dev-libs/libjcat/libjcat-0.1.14.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson python-any-r1 vala xdg-utils
+
+DESCRIPTION="Library and tool for reading and writing Jcat files"
+HOMEPAGE="https://github.com/hughsie/libjcat"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+gpg gtk-doc +introspection +man +pkcs7 test vala"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/json-glib:=
+	gpg? (
+		app-crypt/gpgme:=
+		dev-libs/libgpg-error
+	)
+	introspection? ( dev-libs/gobject-introspection:= )
+	pkcs7? ( net-libs/gnutls )
+	vala? ( dev-lang/vala:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	$(python_gen_any_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	')
+	gtk-doc? ( dev-util/gtk-doc )
+	man? ( sys-apps/help2man )
+	test? ( net-libs/gnutls[tools] )"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.1.11-disable_installed_tests.patch
+)
+
+python_check_deps() {
+	python_has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use vala && vala_setup
+}
+
+src_prepare() {
+	xdg_environment_reset
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtkdoc)
+		$(meson_use gpg)
+		$(meson_use introspection)
+		$(meson_use man)
+		$(meson_use pkcs7)
+		$(meson_use test tests)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}