[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgusb/

["Matt Turner" <mattst88@gentoo.org>]

commit:     89b7360359998618e12e4367b4a605556ba33a61
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 11 16:15:31 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Jun 11 16:17:46 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=89b73603

dev-libs/libgusb: Version bump to 0.4.6

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libgusb/Manifest             |  1 +
 dev-libs/libgusb/libgusb-0.4.6.ebuild | 72 +++++++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-libs/libgusb/Manifest b/dev-libs/libgusb/Manifest
index b014b757c612..eb076531387e 100644
--- a/dev-libs/libgusb/Manifest
+++ b/dev-libs/libgusb/Manifest
@@ -1 +1,2 @@
 DIST libgusb-0.4.5.tar.xz 50384 BLAKE2B 3844d0ec189292e4fed4520d818d095255ddaafa9052ec083a5df3171fa36a8261802526483228412fd69f073444ba422cd16c9d07d5f38770cb14a3ffcd23c6 SHA512 8b91ebfd7b6e07f1ab104f78c638bd28875e3ba1e47360307be16af9b2e4fb598e9911f50181590b5e08608a14557d15bc5dfaa6804a6056b6ee6669b2f6f81e
+DIST libgusb-0.4.6.tar.xz 50660 BLAKE2B 4a2d0f502609f487ca84d970a157cb35c5fc1676a074a868ecb269f2028c39d2ad581a156054987095eb869d7edd7572921b188005262dce12ae3b83271f14dc SHA512 586650f1694cdac50d08f53b117686c38a1be19468ebbf56baa7fc13482f07e0f67c854807b827b6410b094409e117e46afd8cf2706f1390076ad34978b871c1

diff --git a/dev-libs/libgusb/libgusb-0.4.6.ebuild b/dev-libs/libgusb/libgusb-0.4.6.ebuild
new file mode 100644
index 000000000000..6dd274c99bd4
--- /dev/null
+++ b/dev-libs/libgusb/libgusb-0.4.6.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson-multilib python-any-r1 vala
+
+DESCRIPTION="GObject wrapper for libusb"
+HOMEPAGE="https://github.com/hughsie/libgusb"
+SRC_URI="https://github.com/hughsie/libgusb/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="gtk-doc +introspection test +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2[${MULTILIB_USEDEP}]
+	virtual/libusb:1[udev,${MULTILIB_USEDEP}]
+	>=dev-libs/json-glib-1.1.1[${MULTILIB_USEDEP},introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	sys-apps/hwdata
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-util/umockdev-0.17.7[${MULTILIB_USEDEP}] )"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	gtk-doc? ( dev-util/gi-docgen )
+	vala? ( $(vala_depend) )
+	virtual/pkgconfig
+"
+
+python_check_deps() {
+	python_has_version "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddefault_library=shared
+		$(meson_use test tests)
+		$(meson_native_use_bool vala vapi)
+		-Dusb_ids="${EPREFIX}"/usr/share/hwdata/usb.ids
+		$(meson_native_use_bool gtk-doc docs)
+		$(meson_native_use_bool introspection)
+		$(meson_feature test umockdev)
+
+	)
+	meson_src_configure
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/ || die
+		mv "${ED}"/usr/share/{doc,gtk-doc}/libgusb || die
+	fi
+}