[gentoo-commits] repo/gentoo:master commit in: media-sound/aqualung/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     16f2e324da104c7525cb175138661b1390835ed0
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 11 07:56:06 2023 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Sun Jun 11 07:56:06 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=16f2e324

media-sound/aqualung: bump to 1.2

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/aqualung/Manifest            |   1 +
 media-sound/aqualung/aqualung-1.2.ebuild | 109 +++++++++++++++++++++++++++++++
 2 files changed, 110 insertions(+)

diff --git a/media-sound/aqualung/Manifest b/media-sound/aqualung/Manifest
index 6ddcfae8db39..d9badbacf707 100644
--- a/media-sound/aqualung/Manifest
+++ b/media-sound/aqualung/Manifest
@@ -1 +1,2 @@
 DIST aqualung-1.1.tar.gz 1986368 BLAKE2B 2dd367aefe55c1b9243bd5faee2e2d082825f1077326ad05cfe4c2b088ba2f055f5d9af7d14a032bac3603c8e333cffb53357a73e29f22f417e89ad91548eece SHA512 77f6350c1c6c9160da4c6280273812964d58e01227495a87e03e0bee0a2aaf5589d309b9ce7e08421845a357b35dbd08c5de5ecd495ae5ba7877a67d01e4ad01
+DIST aqualung-1.2.tar.gz 1974910 BLAKE2B 4956865a5897cf92d3ebb65cb30f27164e7717fadbbff8e275b25d5fa9c60382846877f644d3a8393935df82f9b92d282fe41befe27cd86accc3f6885650063f SHA512 0e11f307344c8ada7f3869d953e6fb8b088a8af345d51f3e93af18b4b57ea6f35bbc47eefea40956114d56882e4a0d66c1496a7b9a14dfd82e6a95cfc0ef52c5

diff --git a/media-sound/aqualung/aqualung-1.2.ebuild b/media-sound/aqualung/aqualung-1.2.ebuild
new file mode 100644
index 000000000000..2aa0868884f7
--- /dev/null
+++ b/media-sound/aqualung/aqualung-1.2.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit autotools desktop lua-single xdg
+
+DESCRIPTION="Music player for a wide range of formats designed for gapless playback"
+HOMEPAGE="https://aqualung.jeremyevans.net/ https://github.com/jeremyevans/aqualung"
+SRC_URI="https://github.com/jeremyevans/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa cdda cddb debug flac ffmpeg ifp jack ladspa lame libsamplerate
+	lua mac modplug mp3 musepack oss podcast pulseaudio sndfile speex systray
+	vorbis wavpack"
+
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
+
+BDEPEND="
+	virtual/pkgconfig
+	sys-devel/gettext
+"
+# <ffmpeg-5 dep for bug #834391
+# https://github.com/jeremyevans/aqualung/issues/29
+RDEPEND="
+	app-arch/bzip2
+	dev-libs/libxml2
+	sys-libs/zlib
+	x11-libs/gtk+:2
+	alsa? ( media-libs/alsa-lib )
+	cdda? ( dev-libs/libcdio-paranoia )
+	cddb? ( media-libs/libcddb )
+	ffmpeg? ( <media-video/ffmpeg-5:= )
+	flac? ( media-libs/flac:= )
+	ifp? ( media-libs/libifp )
+	jack? ( virtual/jack )
+	ladspa? ( media-libs/liblrdf )
+	lame? ( media-sound/lame )
+	libsamplerate? ( media-libs/libsamplerate )
+	lua? ( ${LUA_DEPS} )
+	mac? ( media-sound/mac )
+	modplug? ( media-libs/libmodplug )
+	mp3? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	pulseaudio? ( media-libs/libpulse )
+	sndfile? ( media-libs/libsndfile )
+	speex? ( media-libs/speex media-libs/liboggz media-libs/libogg )
+	vorbis? ( media-libs/libvorbis media-libs/libogg )
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.1-configure-lua-version.patch"
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-rpath \
+		--enable-loop \
+		--enable-nls \
+		--enable-transcoding \
+		$(use_enable debug) \
+		$(use_enable podcast) \
+		$(use_enable systray) \
+		$(use_enable jack jack-mgmt) \
+		$(use_with alsa) \
+		$(use_with cdda) \
+		$(use_with cddb) \
+		$(use_with ffmpeg lavc) \
+		$(use_with flac) \
+		$(use_with ifp) \
+		$(use_with jack) \
+		$(use_with ladspa) \
+		$(use_with lame) \
+		$(use_with libsamplerate src) \
+		$(use_with lua) \
+		$(use_with mac) \
+		$(use_with modplug mod) \
+		$(use_with mp3 mpeg) \
+		$(use_with musepack mpc) \
+		$(use_with oss) \
+		$(use_with pulseaudio pulse) \
+		$(use_with sndfile) \
+		$(use_with speex) \
+		$(use_with vorbis vorbis) \
+		$(use_with vorbis vorbisenc) \
+		$(use_with wavpack)
+}
+
+src_install() {
+	default
+
+	newicon src/img/icon_64.png aqualung.png
+	make_desktop_entry aqualung Aqualung
+}