[gentoo-commits] repo/gentoo:master commit in: media-libs/pcaudiolib/

["William Hubbs" <williamh@gentoo.org>]

commit:     94c82ac54fe4d5e69994d80e492bac4d174188cd
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon May 29 13:41:30 2023 +0000
Commit:     William Hubbs <williamh <AT> gentoo <DOT> org>
CommitDate: Sat Jun 10 20:12:36 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=94c82ac5

media-libs/pcaudiolib: Switch IUSE=pulseaudio to media-libs/libpulse

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
Signed-off-by: William Hubbs <williamh <AT> gentoo.org>

 media-libs/pcaudiolib/pcaudiolib-1.2-r2.ebuild | 50 ++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/media-libs/pcaudiolib/pcaudiolib-1.2-r2.ebuild b/media-libs/pcaudiolib/pcaudiolib-1.2-r2.ebuild
new file mode 100644
index 000000000000..0c5cc45727cd
--- /dev/null
+++ b/media-libs/pcaudiolib/pcaudiolib-1.2-r2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Portable C Audio Library"
+HOMEPAGE="https://github.com/espeak-ng/pcaudiolib"
+SRC_URI="https://github.com/espeak-ng/pcaudiolib/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+ ZLIB"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+alsa oss pulseaudio"
+
+REQUIRED_USE="|| ( alsa oss pulseaudio )"
+
+RDEPEND="
+	alsa? ( >=media-libs/alsa-lib-1.0.18 )
+	pulseaudio? ( media-libs/libpulse )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/0001-Fix-audio-choppiness-on-some-systems.patch"
+	"${FILESDIR}/0002-Fix-latency-related-buffer-sizing.patch"
+	"${FILESDIR}/0003-Copy-audio-buffer-and-send-for-playback-without-bloc.patch"
+	)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local econf_args
+	econf_args=(
+		$(use_with oss)
+		$(use_with alsa)
+		$(use_with pulseaudio)
+	)
+	econf "${econf_args[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}