[gentoo-commits] repo/gentoo:master commit in: dev-python/docker/

["Michał Górny" <mgorny@gentoo.org>]

commit:     6174c2adc9a10c244082d249090e635afad54ed1
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jun  8 05:27:15 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jun  8 05:55:46 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6174c2ad

dev-python/docker: Bump to 6.1.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/docker/Manifest            |  1 +
 dev-python/docker/docker-6.1.3.ebuild | 56 +++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/dev-python/docker/Manifest b/dev-python/docker/Manifest
index d73f2ade9692..3ffe3016f685 100644
--- a/dev-python/docker/Manifest
+++ b/dev-python/docker/Manifest
@@ -1 +1,2 @@
 DIST docker-py-6.1.2.gh.tar.gz 253183 BLAKE2B 28435f5db00cbcd189cb06af77a4eac95a27944d324718c02b1d8f28c9954242c3a36ae376b0e0118ce1e03cb49f44925250b33b34b3ba5b459ef0df9ae9a6a4 SHA512 13c2711c44ae7b781187abaa7518ed86dd37192a44b6fff2c0090bfd8edb82555d15fb9d1681de9db47839f8dbcf17cc03fb88ed4e0e0052032dbcc9ed4c0078
+DIST docker-py-6.1.3.gh.tar.gz 253192 BLAKE2B b5a54d2bcbb4a89e4861bbf59a9b4565886f5541a518f66691ae205b7581f73af9fe6d491af299b0295f39b4a6e6248871b16e25ea5650fabbeafb7ced6cdaf7 SHA512 ba6ade2487afb8f68606b7d78c0f0dc83ffde622444a9598a5c647d0176695171040c5d1115fb8db6d97cb062a24d552d043274a56923b0eae0f64d98cb92c30

diff --git a/dev-python/docker/docker-6.1.3.ebuild b/dev-python/docker/docker-6.1.3.ebuild
new file mode 100644
index 000000000000..a3fe24f9dc3d
--- /dev/null
+++ b/dev-python/docker/docker-6.1.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+MY_P=docker-py-${PV}
+DESCRIPTION="Python client for Docker"
+HOMEPAGE="
+	https://github.com/docker/docker-py/
+	https://pypi.org/project/docker/
+"
+SRC_URI="
+	https://github.com/docker/docker-py/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/packaging-14.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/paramiko-2.4.3[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/myst-parser'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# localhost has a better chance of being in /etc/hosts
+	sed -e 's:socket[.]gethostname():"localhost":' \
+		-i tests/unit/api_test.py || die
+
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	epytest tests/unit
+}