[gentoo-commits] repo/gentoo:master commit in: media-sound/qsampler/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     5516cc2e233e9e091099b97beff2cc8d03b6fedb
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Fri Jun  2 06:52:03 2023 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Fri Jun  2 06:52:03 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5516cc2e

media-sound/qsampler: bump to 0.9.10

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/qsampler/Manifest               |  1 +
 media-sound/qsampler/qsampler-0.9.10.ebuild | 57 +++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/media-sound/qsampler/Manifest b/media-sound/qsampler/Manifest
index 2ceaca0a2854..7ce71025a3cd 100644
--- a/media-sound/qsampler/Manifest
+++ b/media-sound/qsampler/Manifest
@@ -1 +1,2 @@
+DIST qsampler-0.9.10.tar.gz 222310 BLAKE2B 1fc9c4d063dcce9f3cd69e74e0205b4585e2609eb09fea409fccb87560f4eb767ce322b9dc6d18c3e7ae79c5eff7d06a3bc4c408f6880c161f34d9d93f7ca0fd SHA512 599db13d35a0cf25e5d5fcd02a8fe7995500552c2f2b298883395af9876ecd7fd5aca4528fa8aa5dcd678038ea8704b69131df95c7d9de8061a2c0d163ccbde9
 DIST qsampler-0.9.9.tar.gz 220746 BLAKE2B 9c062b21655bc8fd484663a4c439b92c3bf554a1eb3648051f89bb97388740eea13c56b23a584c0c3f02ce150d2400a007dbaf1ad7a5752ab2366e9b2be3d6ab SHA512 0553a158cb257ce35fe784d69e4ac654cd3bd096287e21476ab7eca6369c2f415a8f317d2ae155cb6a475e68dfde958b93348f1d24e33f13e18bd408f3901db9

diff --git a/media-sound/qsampler/qsampler-0.9.10.ebuild b/media-sound/qsampler/qsampler-0.9.10.ebuild
new file mode 100644
index 000000000000..38a795222015
--- /dev/null
+++ b/media-sound/qsampler/qsampler-0.9.10.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://git.code.sf.net/p/qsampler/code"
+	inherit git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Graphical frontend to the LinuxSampler engine"
+HOMEPAGE="https://qsampler.sourceforge.io/ https://www.linuxsampler.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="debug +libgig"
+
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/alsa-lib
+	media-libs/liblscp:=
+	x11-libs/libX11
+	libgig? ( media-libs/libgig:= )
+"
+RDEPEND="${DEPEND}
+	media-sound/linuxsampler
+"
+BDEPEND="dev-qt/linguist-tools:5"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.9.1-cmake-no-git.patch"
+)
+
+DOCS=( ChangeLog README TRANSLATORS )
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -e "/^find_package.*QT/s/Qt6 //" -i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFIG_DEBUG=$(usex debug 1 0)
+		-DCONFIG_LIBGIG=$(usex libgig 1 0)
+	)
+	cmake_src_configure
+}