[gentoo-commits] repo/gentoo:master commit in: net-libs/libdom/

["Michael Orlitzky" <mjo@gentoo.org>]

commit:     dbaf8ae84492dc8a4f42e5ecb6fe3a56ec9e6d7b
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Sat May 27 18:40:44 2023 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Sat May 27 22:01:24 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dbaf8ae8

net-libs/libdom: add 9999

Signed-off-by: Michael Orlitzky <mjo <AT> gentoo.org>

 net-libs/libdom/libdom-9999.ebuild | 57 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/net-libs/libdom/libdom-9999.ebuild b/net-libs/libdom/libdom-9999.ebuild
new file mode 100644
index 000000000000..e4b422d0883c
--- /dev/null
+++ b/net-libs/libdom/libdom-9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit git-r3 netsurf
+
+DESCRIPTION="implementation of the W3C DOM, written in C"
+HOMEPAGE="https://www.netsurf-browser.org/projects/libdom/"
+
+EGIT_REPO_URI="https://git.netsurf-browser.org/${PN}.git"
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS=""
+IUSE="expat test xml"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/libparserutils
+	dev-libs/libwapcaplet
+	net-libs/libhubbub
+	xml? (
+		expat? ( dev-libs/expat )
+		!expat? ( dev-libs/libxml2 )
+	)"
+DEPEND="${RDEPEND}
+	test? (
+		dev-perl/XML-XPath
+		dev-perl/libxml-perl
+		dev-perl/Switch
+	)"
+BDEPEND="
+	dev-util/netsurf-buildsystem
+	virtual/pkgconfig"
+
+REQUIRED_USE="test? ( xml )"
+
+_emake() {
+	netsurf_define_makeconf
+	emake "${NETSURF_MAKECONF[@]}" COMPONENT_TYPE=lib-shared \
+		WITH_EXPAT_BINDING=$(usex xml $(usex expat yes no) no) \
+		WITH_LIBXML_BINDING=$(usex xml $(usex expat no yes) no) \
+		$@
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake DESTDIR="${D}" install
+}