[gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-ews/

["Matt Turner" <mattst88@gentoo.org>]

commit:     d9673984b681c5ef7aedb783ccafce3f4d3c4937
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri May 26 14:49:03 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri May 26 19:18:30 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d9673984

gnome-extra/evolution-ews: Version bump to 3.48.2

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/31171
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/evolution-ews/Manifest                 |  1 +
 .../evolution-ews/evolution-ews-3.48.2.ebuild      | 72 ++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/gnome-extra/evolution-ews/Manifest b/gnome-extra/evolution-ews/Manifest
index 0c8eee6aaff2..f995062bbd11 100644
--- a/gnome-extra/evolution-ews/Manifest
+++ b/gnome-extra/evolution-ews/Manifest
@@ -1 +1,2 @@
 DIST evolution-ews-3.48.1.tar.xz 701696 BLAKE2B ddce95682a3b4bc75755f9c3e056942c95dfb929bcb40b99d02bf51126897d83f8ef7e68dc6c77af7f82f427dcad4c4e9fb51173b1b22f5d35985a353a1b2040 SHA512 b6166f2dd10c2b5b9ca0e5d5dde0c32ca7082f1c594e8b59642b943870dc5343f1ec4d07a7563c33a1252e989ec1e9ff360f98caf0b590a21dfec42383893a45
+DIST evolution-ews-3.48.2.tar.xz 701356 BLAKE2B 8c941302f383870bacf0dd3f02b28be34105ec7f612b027a505b98be0f66099d65671808e26e86ce756fc47116d012aa1c82fff74c5a501d3778dc7aba6b2498 SHA512 deccc3b442718b03809a7c49297a3f5d7c0bd2873fddfd9f90861a102208759cb95db9bfec1b04cff6932678f58aa81467c48fd4b1e32bb49ed43b9d8c9f4f77

diff --git a/gnome-extra/evolution-ews/evolution-ews-3.48.2.ebuild b/gnome-extra/evolution-ews/evolution-ews-3.48.2.ebuild
new file mode 100644
index 000000000000..675ec4ff7d00
--- /dev/null
+++ b/gnome-extra/evolution-ews/evolution-ews-3.48.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake gnome2 optfeature
+
+DESCRIPTION="Evolution module for connecting to Microsoft Exchange Web Services"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution-ews"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="test"
+
+# libical-glib currently (2020-02-29) oddly behind USE=introspection
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/libical-3.0.5:0=[introspection(-)]
+	>=dev-libs/json-glib-1.0.4
+	>=dev-libs/libmspack-0.4
+	dev-libs/libxml2:2
+	>=gnome-extra/evolution-data-server-${PV}:0=
+	>=mail-client/evolution-${PV}:2.0
+	>=net-libs/libsoup-3.0:3.0
+	>=x11-libs/gtk+-3.10:3
+"
+DEPEND="${RDEPEND}
+	test? ( >=net-libs/uhttpmock-0.9:1.0 )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Unittests fail to find libevolution-ews.so
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+src_prepare() {
+	cmake_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MSPACK=ON
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+}
+
+pkg_postinst() {
+	optfeature "oauth support" gnome-extra/evolution-data-server[oauth]
+}