From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1521465-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 81B8015806E
for <garchives@archives.gentoo.org>; Fri, 26 May 2023 01:44:22 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 4DA71E0805;
Fri, 26 May 2023 01:44:21 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 0F53FE0805
for <gentoo-commits@lists.gentoo.org>; Fri, 26 May 2023 01:44:21 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 1972C340F91
for <gentoo-commits@lists.gentoo.org>; Fri, 26 May 2023 01:44:20 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 76CC5A79
for <gentoo-commits@lists.gentoo.org>; Fri, 26 May 2023 01:44:18 +0000 (UTC)
From: "Matt Turner" <mattst88@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Matt Turner" <mattst88@gentoo.org>
Message-ID: <1685065372.62ba75fbdbe8b5cbd83ffeaa86dde62605b630df.mattst88@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/
X-VCS-Repository: repo/gentoo
X-VCS-Files: gnome-extra/gnome-software/Manifest gnome-extra/gnome-software/gnome-software-44.2.ebuild
X-VCS-Directories: gnome-extra/gnome-software/
X-VCS-Committer: mattst88
X-VCS-Committer-Name: Matt Turner
X-VCS-Revision: 62ba75fbdbe8b5cbd83ffeaa86dde62605b630df
X-VCS-Branch: master
Date: Fri, 26 May 2023 01:44:18 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 17bf3446-e2d5-4ba0-89f2-75d6ceb695de
X-Archives-Hash: 100274e70072b5e099af0a2fcd6be002
commit: 62ba75fbdbe8b5cbd83ffeaa86dde62605b630df
Author: Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri May 26 01:21:45 2023 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri May 26 01:42:52 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=62ba75fb
gnome-extra/gnome-software: Version bump to 44.2
Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/31165
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
gnome-extra/gnome-software/Manifest | 1 +
.../gnome-software/gnome-software-44.2.ebuild | 102 +++++++++++++++++++++
2 files changed, 103 insertions(+)
diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index e5f825030345..a6d385d75a05 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1 +1,2 @@
DIST gnome-software-44.1.tar.xz 2422660 BLAKE2B af23ff99a4b5746a1525830bb5454dc823eba519829d390dc21d412a17347396b594df969d5cc80ffc552cf4edf3961e29cf3781f4553bc74293e96bbd33f000 SHA512 4f6d50d8308b3d2694a67f35db0c716f8631380282c7586243499449dd86d11ebfa08a18ccd083839b93bcf7e1b16075433cb427642c2c7b59033e721bb32c9b
+DIST gnome-software-44.2.tar.xz 2423844 BLAKE2B 6dfbefb71a4d8c83bdc2ef293fa11379523fc966a58bef80f72fc1106b332594c06c6749702e07547c5dd4e3412ac57c309fd7d45bdabe94be5139474d6a76f6 SHA512 0f053d1d92285239d7edd62a5dcc5c8ce9e991103e3987808ef82406e2dc665a13e0cd14b043d66dfd420459a6aa7c83e7db2fd6a16a8f3b41a6e93498820251
diff --git a/gnome-extra/gnome-software/gnome-software-44.2.ebuild b/gnome-extra/gnome-software/gnome-software-44.2.ebuild
new file mode 100644
index 000000000000..1f4b773cf8cb
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-44.2.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software https://gitlab.gnome.org/GNOME/gnome-software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc sysprof udev test"
+
+RDEPEND="
+ >=dev-libs/appstream-0.14.0:0=
+ >=x11-libs/gdk-pixbuf-2.32.0:2
+ >=dev-libs/libxmlb-0.1.7:=
+ >=gui-libs/gtk-4.9.2:4
+ >=dev-libs/glib-2.70.0:2
+ >=dev-libs/json-glib-1.6.0
+ >=net-libs/libsoup-3.0:3.0
+ >=gui-libs/libadwaita-1.3_rc:1
+ sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+ gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+ sys-auth/polkit
+ firmware? ( >=sys-apps/fwupd-1.5.6 )
+ flatpak? (
+ >=sys-apps/flatpak-1.14.0-r1
+ dev-util/ostree
+ )
+ udev? ( dev-libs/libgudev )
+ >=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+ test? ( dev-libs/libglib-testing )
+"
+BDEPEND="
+ dev-libs/libxml2:2
+ dev-util/gdbus-codegen
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ gtk-doc? (
+ dev-util/gtk-doc
+ app-text/docbook-xml-dtd:4.3
+ )
+"
+
+src_prepare() {
+ default
+ xdg_environment_reset
+
+ sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+ # We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+ sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use test tests)
+ $(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+ -Dman=true
+ -Dpackagekit=false
+ # -Dpackagekit_autoremove
+ -Dpolkit=true
+ -Deos_updater=false # Endless OS updater
+ $(meson_use firmware fwupd)
+ $(meson_use flatpak)
+ -Dmalcontent=false
+ -Drpm_ostree=false
+ -Dwebapps=true
+ -Dhardcoded_foss_webapps=true
+ -Dhardcoded_proprietary_webapps=true
+ $(meson_use udev gudev)
+ -Dapt=false
+ -Dsnap=false
+ -Dexternal_appstream=false
+ $(meson_use gtk-doc gtk_doc)
+ -Dhardcoded_curated=true
+ -Ddefault_featured_apps=false # TODO: Will this be beneficial to us with flatpak at least? If enabled, it shows some apps under installed (probably merely due to /usr/share/app-info presence), but launching and removal of them is broken
+ -Dmogwai=false #TODO?
+ $(meson_feature sysprof)
+ -Dprofile=''
+ -Dsoup2=false
+ )
+ meson_src_configure
+}
+
+src_test() {
+ virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}