[gentoo-commits] repo/gentoo:master commit in: dev-python/vcrpy/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     ef485b5077720fd8495dd09613d9e0bec111467f
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Tue May 23 12:46:58 2023 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Tue May 23 12:47:23 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ef485b50

dev-python/vcrpy: Require <dev-python/urllib3-2

Closes: https://bugs.gentoo.org/906979
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>

 dev-python/vcrpy/vcrpy-4.2.1-r1.ebuild | 58 ++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/dev-python/vcrpy/vcrpy-4.2.1-r1.ebuild b/dev-python/vcrpy/vcrpy-4.2.1-r1.ebuild
new file mode 100644
index 000000000000..ba696c0d3e5d
--- /dev/null
+++ b/dev-python/vcrpy/vcrpy-4.2.1-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Automatically mock your HTTP interactions to simplify and speed up testing"
+HOMEPAGE="
+	https://github.com/kevin1024/vcrpy/
+	https://pypi.org/project/vcrpy/
+"
+SRC_URI="
+	https://github.com/kevin1024/vcrpy/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/httplib2-0.9.1[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	>=dev-python/six-1.5[${PYTHON_USEDEP}]
+	<dev-python/urllib3-2[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]
+	dev-python/yarl[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# these tests require Internet
+		tests/integration/test_aiohttp.py
+		tests/integration/test_boto.py
+		tests/integration/test_httplib2.py::test_effective_url
+		tests/integration/test_httpx.py
+		tests/integration/test_urllib2.py::test_effective_url
+		tests/integration/test_urllib3.py::test_redirects
+		tests/integration/test_wild.py::test_amazon_doctype
+		tests/integration/test_wild.py::test_flickr_should_respond_with_200
+		tests/unit/test_stubs.py::TestVCRConnection::testing_connect
+	)
+
+	local -x REQUESTS_CA_BUNDLE=$("${EPYTHON}" -m pytest_httpbin.certs)
+	epytest
+}