[gentoo-commits] repo/gentoo:master commit in: dev-python/cheroot/

["Michał Górny" <mgorny@gentoo.org>]

commit:     b84f6668b53c213bf67834104f3f129661d2ec0b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun May 21 04:09:47 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun May 21 04:55:21 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b84f6668

dev-python/cheroot: Bump to 10.0.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/cheroot/Manifest              |  1 +
 dev-python/cheroot/cheroot-10.0.0.ebuild | 77 ++++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/dev-python/cheroot/Manifest b/dev-python/cheroot/Manifest
index e520c631ec3d..bf99f1cab2a0 100644
--- a/dev-python/cheroot/Manifest
+++ b/dev-python/cheroot/Manifest
@@ -1 +1,2 @@
+DIST cheroot-10.0.0.tar.gz 148461 BLAKE2B d6a07878b03529be0d7ebefc91096f89b437374f9ede1db357a286bc199403798d35e9695dc1251d5045b6febc37940986693d9b36c89968ac3147ec68a481ea SHA512 02e32e52a596463cbb9874a800dbcdc5680dd7d9dfa95ca6e73c81f9248a488087c514ae70cdba94fe9df1f5d3ab1c68efcb720561cbeb7b667109fe5962f85b
 DIST cheroot-9.0.0.tar.gz 152562 BLAKE2B 5f5dd172cfc8fdd1318b22fc27060444a34343b6b83bbda4bd40c16d7cb0568c356f5fd14b0a7cdc74895d6707077ec54fcae54fb29b0d16a7c06e2cd36b1ee7 SHA512 86ea0dd2cb4cde25f86b489b1d0bb27e3e7c1ba5449759ccecaae689cdcb349b968fd0c8fb8bc8273deff5e32a078bf40f4342f0c5a1f53bb8d2b968f44a453b

diff --git a/dev-python/cheroot/cheroot-10.0.0.ebuild b/dev-python/cheroot/cheroot-10.0.0.ebuild
new file mode 100644
index 000000000000..8ecfaae8b79a
--- /dev/null
+++ b/dev-python/cheroot/cheroot-10.0.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="High-performance, pure-Python HTTP server used by CherryPy"
+HOMEPAGE="
+	https://cherrypy.dev/
+	https://pypi.org/project/cheroot/
+	https://github.com/cherrypy/cheroot/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test-rust"
+
+RDEPEND="
+	>=dev-python/more-itertools-2.6[${PYTHON_USEDEP}]
+	dev-python/jaraco-functools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/jaraco-context[${PYTHON_USEDEP}]
+		dev-python/jaraco-text[${PYTHON_USEDEP}]
+		dev-python/portend[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-1.11.0[${PYTHON_USEDEP}]
+		dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+		dev-python/urllib3[${PYTHON_USEDEP}]
+		test-rust? (
+			dev-python/pyopenssl[${PYTHON_USEDEP}]
+			dev-python/trustme[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -e '/--cov/d' \
+		-e '/--testmon/d' \
+		-e '/--numproc/d' \
+		-i pytest.ini || die
+
+	# broken
+	sed -i -e '/False.*localhost/d' cheroot/test/test_ssl.py || die
+	# pypytools is py2 stuff
+	sed -i -e '/pypytools/d' cheroot/test/test_server.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires pypytools, see above
+		cheroot/test/test_server.py::test_high_number_of_file_descriptors
+	)
+
+	local EPYTEST_IGNORE=()
+	if ! has_version "dev-python/pyopenssl[${PYTHON_USEDEP}]" ||
+		! has_version "dev-python/trustme[${PYTHON_USEDEP}]"
+	then
+		EPYTEST_IGNORE+=(
+			cheroot/test/test_ssl.py
+		)
+	fi
+
+	epytest -p no:flaky
+}