[gentoo-commits] repo/gentoo:master commit in: www-client/opera-beta/

["Mike Gilbert" <floppym@gentoo.org>]

commit:     f66e3a3c354700cbafc50b76da7a55cdc2daf0a3
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Wed May 17 00:01:08 2023 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Wed May 17 00:01:08 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f66e3a3c

www-client/opera-beta: remove old

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 www-client/opera-beta/Manifest                     |   1 -
 .../opera-beta/opera-beta-98.0.4759.1.ebuild       | 166 ---------------------
 2 files changed, 167 deletions(-)

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index d8e72d889263..54c884a91f4b 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,4 +1,3 @@
-DIST opera-beta_98.0.4759.1_amd64.deb 104289216 BLAKE2B b8f228b919600517087786f42326825e5c6149328e124d4fa5ffef72f2cba2827250a5f66f94265dfe511066f5c23954198884b3fd219eda1fb68d927218279c SHA512 33311974079c686e6bcf442428f33f21479b72db657976f591c1602132f849838a1a46aa72c5ba9c6504e590709e7c6eace3464c5c4b5e9d8da40c8b823f68b1
 DIST opera-beta_98.0.4759.21_amd64.deb 104397508 BLAKE2B 06fed47bb8039df41d17b5e8683514ff27d57d3c6008da5009bc0ae982a08d05575dfa9284ba36b9b6daabcaeef4087861bd5e92fb04a7cf99d0059df8923e8d SHA512 6dfdf7069d06fd9821aa6bc13b68b7b803953cbd71cceb76ea000494ce716af1edbea8965bc4b7ad66daf11b065c43c486947e1b9d0074b2e92e3b7cd1fe1416
 DIST opera-beta_98.0.4759.3_amd64.deb 104333468 BLAKE2B d661355bf8a96d4f61c10796d164a03fe817bcfa914961e64cff20f8c8f37c283dd29d0106f00db1e50eaae7fdbb549b20778946debeb74802770c398b833bd3 SHA512 97bfd7a7dc32957a61892825280454af0251eb7e6f256b94c1b9cd0c6aecc99da07ae429c4d76752f598824844fbb06ca1dc69fe20a2f3cae85d4ac4a6bf18f8
 DIST opera-beta_99.0.4788.6_amd64.deb 105665800 BLAKE2B 799affa9684d0eff9bcb8690a225d2b3d92e9cfb6a8e69a2d8273dec742199b4720070865b63192e97bf1f7e895c0cfb221f19e6ba6b360b7ea7dd9ae1cefed5 SHA512 8dbfe342edae75f9be888d0809221e132433f83f9e6d4d0752f3a7d36129bd5a06225a8001ff552cb4a701d19c83747b1331c95afacd6a3e8f2f45e577b940fd

diff --git a/www-client/opera-beta/opera-beta-98.0.4759.1.ebuild b/www-client/opera-beta/opera-beta-98.0.4759.1.ebuild
deleted file mode 100644
index 2a9aded891d9..000000000000
--- a/www-client/opera-beta/opera-beta-98.0.4759.1.ebuild
+++ /dev/null
@@ -1,166 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CHROMIUM_LANGS="
-	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
-	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
-	zh-CN zh-TW
-"
-
-# These are intended for ebuild maintainer use to force RPM if DEB is not available.
-: ${OPERA_FORCE_RPM=no}
-
-inherit chromium-2 pax-utils xdg
-
-if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-	inherit rpm
-	OPERA_ARCHIVE_EXT="rpm"
-else
-	inherit unpacker
-	OPERA_ARCHIVE_EXT="deb"
-fi
-
-DESCRIPTION="A fast and secure web browser"
-HOMEPAGE="https://www.opera.com/"
-LICENSE="OPERA-2018"
-SLOT="0"
-
-SRC_URI_BASE=(
-	"https://download1.operacdn.com/pub/${PN}"
-	"https://download2.operacdn.com/pub/${PN}"
-	"https://download3.operacdn.com/pub/${PN}"
-	"https://download4.operacdn.com/pub/${PN}"
-)
-
-if [[ ${PN} == opera ]]; then
-	MY_PN=${PN}-stable
-	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
-else
-	MY_PN=${PN}
-fi
-
-KEYWORDS="-* ~amd64"
-
-FFMPEG_VERSION="110.0.5464.2"
-
-SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
-	proprietary-codecs? (
-		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
-	)"
-
-IUSE="+proprietary-codecs +suid qt5"
-RESTRICT="bindist mirror strip"
-
-RDEPEND="
-	>=app-accessibility/at-spi2-core-2.46.0:2
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	gnome-base/gsettings-desktop-schemas
-	media-libs/alsa-lib
-	media-libs/mesa[gbm(+)]
-	net-misc/curl
-	net-print/cups
-	sys-apps/dbus
-	sys-libs/glibc
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf
-	x11-libs/gtk+:3
-	x11-libs/libdrm
-	x11-libs/libxcb
-	x11-libs/libxkbcommon
-	x11-libs/libxshmfence
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXrandr
-	x11-libs/pango
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5[X]
-		dev-qt/qtwidgets:5
-	)
-"
-
-QA_PREBUILT="*"
-S=${WORKDIR}
-OPERA_HOME="opt/opera${PN#opera}"
-
-pkg_pretend() {
-	# Protect against people using autounmask overzealously
-	use amd64 || die "opera only works on amd64"
-}
-
-pkg_setup() {
-	chromium_suid_sandbox_check_kernel_config
-}
-
-src_unpack() {
-	:
-}
-
-src_install() {
-	dodir /
-	cd "${ED}" || die
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		rpm_src_unpack "${A[0]}"
-	else
-		unpacker
-	fi
-
-	# move to /opt, bug #573052
-	mkdir -p "${OPERA_HOME%${PN}}"
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
-	else
-		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
-	fi
-	rm -r "usr/lib" || die
-
-	# disable auto update
-	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
-
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		rm "${OPERA_HOME}/setup_repo.sh" || die
-	else
-		rm -r "usr/share/lintian" || die
-
-		# fix docs
-		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
-		gzip -d usr/share/doc/${PF}/changelog.gz || die
-	fi
-
-	# fix desktop file
-	sed -i \
-		-e 's|^TargetEnvironment|X-&|g' \
-		usr/share/applications/${PN}.desktop || die
-
-	# remove unused language packs
-	pushd "${OPERA_HOME}/localization" > /dev/null || die
-	chromium_remove_language_paks
-	popd > /dev/null || die
-
-	# setup opera symlink
-	rm "usr/bin/${PN}" || die
-	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
-
-	# install proprietary codecs
-	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
-	if use proprietary-codecs; then
-		mv lib_extra "${OPERA_HOME}"
-	fi
-
-	if ! use qt5; then
-		rm "${OPERA_HOME}/libqt5_shim.so" || die
-	fi
-
-	# pax mark opera, bug #562038
-	pax-mark m "${OPERA_HOME}/opera"
-	# enable suid sandbox if requested
-	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
-}