[gentoo-commits] repo/gentoo:master commit in: x11-misc/spacefm/

["Sam James" <sam@gentoo.org>]

commit:     7e089a767a22cd700369a10df55ac7cc84ae1080
Author:     orbea <orbea <AT> riseup <DOT> net>
AuthorDate: Sun May  7 14:40:42 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue May  9 17:50:54 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7e089a76

x11-misc/spacefm: drop 9999

No new commits since Mar 4, 2018 when the current release 1.0.6 was
released.

Signed-off-by: orbea <orbea <AT> riseup.net>
Closes: https://github.com/gentoo/gentoo/pull/30918
Signed-off-by: Sam James <sam <AT> gentoo.org>

 x11-misc/spacefm/spacefm-9999.ebuild | 70 ------------------------------------
 1 file changed, 70 deletions(-)

diff --git a/x11-misc/spacefm/spacefm-9999.ebuild b/x11-misc/spacefm/spacefm-9999.ebuild
deleted file mode 100644
index 0e63a546df0d..000000000000
--- a/x11-misc/spacefm/spacefm-9999.ebuild
+++ /dev/null
@@ -1,70 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit linux-info optfeature xdg
-
-DESCRIPTION="A multi-panel tabbed file manager"
-HOMEPAGE="https://ignorantguru.github.io/spacefm/"
-
-if [[ ${PV} == *9999* ]]; then
-	EGIT_REPO_URI="https://github.com/IgnorantGuru/${PN}.git"
-	EGIT_BRANCH="next"
-	inherit git-r3
-else
-	KEYWORDS="amd64 x86"
-	SRC_URI="https://github.com/IgnorantGuru/spacefm/archive/${PV}.tar.gz -> ${P}.tar.gz"
-fi
-
-LICENSE="GPL-2 LGPL-2.1"
-SLOT="0"
-IUSE="+startup-notification +video-thumbnails"
-
-RDEPEND="dev-libs/glib:2
-	dev-util/desktop-file-utils
-	virtual/udev
-	virtual/freedesktop-icon-theme
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf
-	x11-libs/gtk+:3
-	x11-libs/pango
-	x11-libs/libX11
-	x11-misc/shared-mime-info
-	startup-notification? ( x11-libs/startup-notification )
-	video-thumbnails? ( media-video/ffmpegthumbnailer )"
-DEPEND="${RDEPEND}"
-BDEPEND="dev-util/intltool
-	sys-devel/gettext
-	virtual/pkgconfig"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-9999-include-sysmacros.patch
-	"${FILESDIR}"/${PN}-fno-common.patch
-)
-
-src_configure() {
-	econf \
-		$(use_enable startup-notification) \
-		$(use_enable video-thumbnails) \
-		--disable-hal \
-		--enable-inotify \
-		--disable-pixmaps \
-		--with-gtk3
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "mounting as non-root user" sys-apps/udevil sys-apps/pmount sys-fs/udisks
-	optfeature "supporting ftp/nfs/smb/ssh URLs in the path bar" sys-apps/udevil
-	optfeature "performing as root" x11-misc/ktsuss kde-plasma/kde-cli-tools[kdesu]
-	# sys-apps/util-linux is required for eject
-	optfeature "other optional dependencies" sys-apps/dbus sys-process/lsof sys-apps/util-linux
-
-	if ! has_version 'sys-fs/udisks' ; then
-		elog "When using SpaceFM without udisks, and without the udisks-daemon running,"
-		elog "you may need to enable kernel polling for device media changes to be detected."
-		elog "See /usr/share/doc/${PF}/html/spacefm-manual-en.html#devices-kernpoll"
-	fi
-}