[gentoo-commits] proj/kde:master commit in: kde-frameworks/krunner/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     3fe5176a5912b83928d8f74051f7454da1415816
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue May  9 13:24:38 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue May  9 13:29:04 2023 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=3fe5176a

kde-frameworks/krunner: 5.106.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-frameworks/krunner/krunner-5.106.0.ebuild | 47 +++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/kde-frameworks/krunner/krunner-5.106.0.ebuild b/kde-frameworks/krunner/krunner-5.106.0.ebuild
new file mode 100644
index 0000000000..8df45d0687
--- /dev/null
+++ b/kde-frameworks/krunner/krunner-5.106.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for providing different actions given a string query"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="activities"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kconfig-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kservice-${PVCUT}*:5
+	=kde-frameworks/plasma-${PVCUT}*:5
+	=kde-frameworks/solid-${PVCUT}*:5
+	=kde-frameworks/threadweaver-${PVCUT}*:5
+	activities? ( =kde-frameworks/kactivities-${PVCUT}*:5 )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package activities KF5Activities)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	# requires virtual dbus, otherwise hangs; bugs #630672, #789351, #838502
+	local myctestargs=(
+		-E "(dbusrunnertest|runnermanagersinglerunnermodetest|runnermanagertest)"
+	)
+	ecm_src_test
+}