[gentoo-commits] repo/gentoo:master commit in: dev-python/tempest/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     b6b98b9d49fc90aec4c00c8c7fc346cf33d2c12a
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Sat May  6 16:40:44 2023 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Sat May  6 16:44:38 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b6b98b9d

dev-python/tempest: add 34.2.0

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/tempest/Manifest              |  1 +
 dev-python/tempest/tempest-34.2.0.ebuild | 75 ++++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index 20a9d3afab52..c779f7352c6c 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1 +1,2 @@
 DIST tempest-34.1.0.tar.gz 1139228 BLAKE2B 32fefb49ad5a341d297cf660387e66f69e0f3f81cba5f0530190bf5562c7a391359667390045fd746977020376e426aea351a2f50652d67693946bdb8dcfba18 SHA512 89cb682edb3d99c22e9c654a9e546e649837abf7e0b798d84c16d70bef4527d094dd6bbe1d11b8996412cd7e6f073fd1a3f80e5214d7d3a44965f3b542fa13e5
+DIST tempest-34.2.0.tar.gz 1141098 BLAKE2B 60d09fc0de49e63213bf23cc223cec92b53f887ff5677fd80cefac441166ef777bc8b96682847697702af26d8481192a2fe19ddbe42cd3b991cc0f16ed09176d SHA512 22cf6e5b6d60398a7a1698ad0bad02d8d16ffd815f573fb526becb9d1be64151bc6b33fb6b8b03f9c52f18565ca06cad1bf9725f2cff2c6116c88f85439b5d7e

diff --git a/dev-python/tempest/tempest-34.2.0.ebuild b/dev-python/tempest/tempest-34.2.0.ebuild
new file mode 100644
index 000000000000..9143d3959fb9
--- /dev/null
+++ b/dev-python/tempest/tempest-34.2.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="
+	https://pypi.org/project/tempest/
+	https://docs.openstack.org/tempest/latest/
+	https://launchpad.net/tempest/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.16.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment. Others expect to run suite using stestr.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+	rm tempest/tests/test_list_tests.py || die
+	rm tempest/tests/lib/cmd/test_check_uuid.py || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	mv "${BUILD_DIR}"/install/{usr/,}etc || die
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1
+	local -x OS_TEST_TIMEOUT=300
+	eunittest -b -s tempest/tests -t .
+}