[gentoo-commits] repo/gentoo:master commit in: app-shells/thefuck/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     6e1f6f236fa199a093920192693c1a7d1915f19e
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Mon May  1 07:13:37 2023 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Mon May  1 07:16:51 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6e1f6f23

app-shells/thefuck: PEP517, deselect failing tests

Closes: https://bugs.gentoo.org/804148
Closes: https://bugs.gentoo.org/886163
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 app-shells/thefuck/thefuck-3.32-r1.ebuild | 45 +++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/app-shells/thefuck/thefuck-3.32-r1.ebuild b/app-shells/thefuck/thefuck-3.32-r1.ebuild
new file mode 100644
index 000000000000..8d692b84c0fd
--- /dev/null
+++ b/app-shells/thefuck/thefuck-3.32-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Magnificent app which corrects your previous console command"
+HOMEPAGE="https://github.com/nvbn/thefuck"
+SRC_URI="https://github.com/nvbn/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/pyte[${PYTHON_USEDEP}]"
+DEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# failing tests because of trying to access portage's home dir
+	tests/test_conf.py
+	tests/entrypoints/test_not_configured.py
+	tests/test_utils.py::test_get_all_executables_exclude_paths
+	tests/test_utils.py::TestCache
+)
+
+python_prepare_all() {
+	sed -i -e "/import pip/s/^/#/" -e "/pip.__version__/,+3 s/^/#/" setup.py || die
+	distutils-r1_python_prepare_all
+}