[gentoo-commits] repo/proj/guru:dev commit in: dev-python/pg8000/

["Anna Vyalkova" <cyber+gentoo@sysrq.in>]

commit:     ee4e40b02fa2f837dd8d14ca4b86a2e9271dddce
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Fri Apr 28 18:15:01 2023 +0000
Commit:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Fri Apr 28 18:20:15 2023 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=ee4e40b0

dev-python/pg8000: add 1.29.1, drop 1.29.4

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 dev-python/pg8000/Manifest             |  2 +-
 dev-python/pg8000/pg8000-1.29.1.ebuild | 35 --------------
 dev-python/pg8000/pg8000-1.29.4.ebuild | 88 ++++++++++++++++++++++++++++++++++
 3 files changed, 89 insertions(+), 36 deletions(-)

diff --git a/dev-python/pg8000/Manifest b/dev-python/pg8000/Manifest
index 674e97bca..4ec0976bf 100644
--- a/dev-python/pg8000/Manifest
+++ b/dev-python/pg8000/Manifest
@@ -1,2 +1,2 @@
-DIST pg8000-1.29.1.tar.gz 92221 BLAKE2B a1e43f445848283472b0aee84f05d3e1c0f8f2d6b8c619789f9e1d961dae240c9ebfb8a1fb22af55f4635bb89f036f8dd1ece477b3b68bff5c1b68ccac32b0b4 SHA512 27ced0ae82e522fabdf3a69b07927223695a7c5658f56f75dbfa43f6923b7a914ec54143421324839c07850e10f5f61ca9bc31155af3e4e600429a1889aedea7
 DIST pg8000-1.29.2.tar.gz 92786 BLAKE2B de39587bb34f21b5c9c4477dd5380d3f790091970867a342c87fac91383e68e8b06e883f25130eefbb88d929d869018881558750f735c81615fbcdc96f9c796b SHA512 3e40d254800c7354097372cc58abbd633316e9e9340d02cc20f21a2dc6c87b559a157c9719b6f15cf2d96c393e0c904c6d1310ea9d6367bb808c3c13114ec431
+DIST pg8000-1.29.4.tar.gz 126629 BLAKE2B 7d71e64c3ac37d9271b3dad20e80ed208c3f062149f7877a964c3ad72b1b245d0210b2e53ee0747f6318de7a81bfa4d03f16312263557b62e751fe89595eab23 SHA512 b96c5a4c42354f74bde3ee3af1688164cd74280c432c458d2d71563329162b7551e48f08c31ca8b1d3c1ff068aeccfd0b385265d2f64da34f1d2c59daca0c5dc

diff --git a/dev-python/pg8000/pg8000-1.29.1.ebuild b/dev-python/pg8000/pg8000-1.29.1.ebuild
deleted file mode 100644
index f44f29a3a..000000000
--- a/dev-python/pg8000/pg8000-1.29.1.ebuild
+++ /dev/null
@@ -1,35 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..10} )
-
-inherit distutils-r1
-
-DESCRIPTION="A Pure-Python PostgreSQL Driver"
-HOMEPAGE="
-	https://github.com/tlocke/pg8000
-	https://pypi.org/project/pg8000/
-"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-SLOT="0"
-LICENSE="BSD"
-KEYWORDS="~amd64"
-
-RDEPEND=">=dev-python/scramp-1.4.1[${PYTHON_USEDEP}]"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	test? (
-		dev-db/postgresql
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/pytest-benchmark[${PYTHON_USEDEP}]
-		dev-python/pytz[${PYTHON_USEDEP}]
-	)
-"
-
-RESTRICT="test" # tests require a running postgresql
-
-distutils_enable_tests pytest

diff --git a/dev-python/pg8000/pg8000-1.29.4.ebuild b/dev-python/pg8000/pg8000-1.29.4.ebuild
new file mode 100644
index 000000000..42ff16674
--- /dev/null
+++ b/dev-python/pg8000/pg8000-1.29.4.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit databases distutils-r1 edo pypi
+
+DESCRIPTION="PostgreSQL interface library"
+HOMEPAGE="
+	https://github.com/tlocke/pg8000
+	https://pypi.org/project/pg8000/
+"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/scramp-1.4.3[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/versioningit[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_impl_dep "ssl")
+		$(epostgres --get-depend "xml")
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+
+SSL_TESTS=(
+	test/dbapi/auth/test_md5_ssl.py
+	test/dbapi/auth/test_scram-sha-256_ssl.p
+	test/legacy/auth/test_md5_ssl.py
+	test/legacy/auth/test_scram-sha-256_ssl.py
+	test/native/auth/test_md5_ssl.py
+	test/native/auth/test_scram-sha-256_ssl.py
+)
+
+EPYTEST_DESELECT=(
+	# TODO: ssl tests (need certificates and stuff)
+	"${SSL_TESTS[@]}"
+
+	# "could not determine data type of parameter $1" and other errors
+	test/test_readme.py
+
+	# "database doesn't exist" errors
+	test/dbapi/auth/test_gss.py
+	test/legacy/auth/test_gss.py
+	test/native/auth/test_gss.py
+
+	# too flaky
+	test/native/test_typeconversion.py::test_roundtrip_oid
+)
+
+EPYTEST_IGNORE=(
+	# need pytest-benchmark
+	test/dbapi/test_benchmarks.py
+	test/legacy/test_benchmarks.py
+	test/native/test_benchmarks.py
+)
+
+distutils_enable_tests pytest
+
+python_test_ssl() {
+	epytest "${SSL_TESTS[@]}"
+}
+
+src_test() {
+	epsql() {
+		edo psql -q -h "${sockdir}" -U postgres "${@}"
+	}
+
+	local -x PGPORT="65432"
+	local -x PGPASSWORD="cpsnow"
+	local sockdir=$(epostgres --get-sockdir)
+
+	epostgres --start ${PGPORT}
+	epsql -c "ALTER ROLE postgres WITH PASSWORD '${PGPASSWORD}';"
+	epsql -c "CREATE EXTENSION hstore;"
+	epsql -c "SELECT pg_reload_conf();"
+
+	distutils-r1_src_test
+	epostgres --stop
+}