[gentoo-commits] repo/gentoo:master commit in: media-sound/ardour/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     f32ed13d4e1de492bd47eba31ef5c88b66a9a9db
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 28 06:45:31 2023 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Fri Apr 28 06:45:36 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f32ed13d

media-sound/ardour: bump to 7.4

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/ardour/Manifest          |   1 +
 media-sound/ardour/ardour-7.4.ebuild | 185 +++++++++++++++++++++++++++++++++++
 2 files changed, 186 insertions(+)

diff --git a/media-sound/ardour/Manifest b/media-sound/ardour/Manifest
index 33ef2c14d55b..d8cf7dc01774 100644
--- a/media-sound/ardour/Manifest
+++ b/media-sound/ardour/Manifest
@@ -1,2 +1,3 @@
 DIST Ardour-6.9.0.tar.bz2 12297369 BLAKE2B 62037130b9f2d15a7f527b549c552a281105298dc85e3019d0f7ac09cb791f2b5460c4a7bd2f2098ccade6b87c70a16e6414691d90ec4baafeb6065f26d10a66 SHA512 ace45f5bfe6d0c9e4bb1712ae53ebaee2f15f883045650cae3ddcae251d4fd2f645ba745effb739b47c73a0568ae9e8ae443b711dd610584e04575fd9046b234
 DIST Ardour-7.3.0.tar.bz2 12897398 BLAKE2B 518de10fd43220e843c775c9374347cf827562ff979a99ecdb9507f69daad642345a1c2ddec6f601511b599167a6904905dcdd25ac15f71616c3cb432897545d SHA512 4c0119768015aea447ea5c4ef15708a6440e189bd3578aca74b8ea2cac86920a8c8bd975e03f2af25108f76231d8afccf0003e6a2f8de1de28bcdce9085fe98c
+DIST Ardour-7.4.0.tar.bz2 12940403 BLAKE2B 4f3ca19e44a9ab5908fb6a6cf29adefb6a7abf4a9f43f810f0a0fdbe8fc1e11cdb49e2a66336fddb0e5d49a0780ac5af7b9363d2f14d9e309b787ceb8c8dd060 SHA512 2533167986a8b7550848e03475931fcd1409f188abed0c7c2a5999869995a73576976d02080cf2ac310113b57ff62d39031615c92cb4fafbe5d96edfc3a4ec45

diff --git a/media-sound/ardour/ardour-7.4.ebuild b/media-sound/ardour/ardour-7.4.ebuild
new file mode 100644
index 000000000000..534c435d20b3
--- /dev/null
+++ b/media-sound/ardour/ardour-7.4.ebuild
@@ -0,0 +1,185 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE='threads(+)'
+PLOCALES="ca cs de el en_GB es eu fr it ja ko nn pl pt pt_PT ru sv zh"
+inherit toolchain-funcs flag-o-matic plocale python-any-r1 waf-utils desktop xdg
+
+DESCRIPTION="Digital Audio Workstation"
+HOMEPAGE="https://ardour.org/"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://git.ardour.org/ardour/ardour.git"
+	inherit git-r3
+else
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://dev.gentoo.org/~fordfrog/distfiles/Ardour-${PV}.0.tar.bz2"
+	S="${WORKDIR}/Ardour-${PV}.0"
+fi
+
+LICENSE="GPL-2"
+SLOT="7"
+IUSE="doc jack nls phonehome pulseaudio cpu_flags_ppc_altivec cpu_flags_x86_sse cpu_flags_x86_mmx cpu_flags_x86_3dnow"
+
+RDEPEND="
+	dev-cpp/glibmm:2
+	dev-cpp/gtkmm:2.4
+	dev-libs/boost:=
+	dev-libs/glib:2
+	dev-libs/libsigc++:2
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=gnome-base/libgnomecanvas-2
+	media-libs/alsa-lib
+	media-libs/aubio
+	media-libs/flac:=
+	media-libs/freetype:2
+	media-libs/libart_lgpl
+	media-libs/liblo
+	media-libs/liblrdf
+	media-libs/libsamplerate
+	media-libs/libsndfile
+	media-libs/libsoundtouch
+	media-libs/raptor:2
+	media-libs/rubberband
+	media-libs/taglib
+	media-libs/vamp-plugin-sdk
+	net-misc/curl
+	sys-libs/readline:0=
+	sci-libs/fftw:3.0[threads]
+	virtual/libusb:1
+	x11-libs/cairo
+	x11-libs/gtk+:2
+	x11-libs/pango
+	jack? ( virtual/jack )
+	pulseaudio? ( media-sound/pulseaudio )
+	media-libs/lilv
+	media-libs/sratom
+	dev-libs/sord
+	media-libs/suil[gtk2]
+	media-libs/lv2"
+#	!bundled-libs? ( media-sound/fluidsynth ) at least libltc is missing to be able to unbundle...
+
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-util/itstool
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] )
+	jack? ( virtual/jack )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-6.8-metadata.patch"
+)
+
+pkg_pretend() {
+	[[ $(tc-getLD) == *gold* ]] && (has_version sci-libs/fftw[openmp] || has_version sci-libs/fftw[threads]) && \
+		ewarn "Linking with gold linker might produce broken executable, see bug #733972"
+}
+
+pkg_setup() {
+	if has_version \>=dev-libs/libsigc++-2.6 ; then
+		append-cxxflags -std=c++11
+	fi
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	sed 's/'full-optimization\'\ :\ \\[.*'/'full-optimization\'\ :\ \'\','/' -i "${S}"/wscript || die
+	MARCH=$(get-flag march)
+	OPTFLAGS=""
+	if use cpu_flags_x86_sse; then
+		if [[ ${MARCH} == "i686" ]] || [[ ${MARCH} == "i486" ]]; then
+			elog "You enabled sse but use an march that does not support sse!"
+			elog "We add -msse to the flags now, but please consider switching your march in make.conf!"
+		fi
+		OPTFLAGS="sse"
+	fi
+	if use cpu_flags_x86_mmx; then
+		if [[ ${MARCH} == "i486" ]]; then
+			elog "You enabled mmx with i486 set as march! You have been warned!"
+		fi
+		OPTFLAGS="${OPTFLAGS} mmx"
+	fi
+	if use cpu_flags_x86_3dnow; then
+		OPTFLAGS="${OPTFLAGS} 3dnow"
+	fi
+	sed 's/flag_line\ =\ o.*/flag_line\ =\ \": '"${OPTFLAGS}"' just some place holders\"/' \
+		-i "${S}"/wscript || die
+	sed 's/cpu\ ==\ .*/cpu\ ==\ "LeaveMarchAsIs":/' -i "${S}"/wscript || die
+	append-flags "-lboost_system"
+	python_fix_shebang "${S}"/wscript
+	python_fix_shebang "${S}"/waf
+	my_lcmsg() {
+		rm -f {gtk2_ardour,gtk2_ardour/appdata,libs/ardour,libs/gtkmm2ext}/po/${1}.po
+	}
+	plocale_for_each_disabled_locale my_lcmsg
+}
+
+src_configure() {
+	# avoid bug https://bugs.gentoo.org/800067
+	local -x AS="$(tc-getCC) -c"
+
+	local backends="alsa,dummy"
+	use jack && backends+=",jack"
+	use pulseaudio && backends+=",pulseaudio"
+
+	tc-export CC CXX
+	mkdir -p "${D}"
+	local myconf=(
+		--configdir=/etc
+		--freedesktop
+		--noconfirm
+		--optimize
+		--with-backends=${backends}
+		$({ use cpu_flags_ppc_altivec || use cpu_flags_x86_sse; } && echo "--fpu-optimization" || echo "--no-fpu-optimization")
+		$(usex doc "--docs" '')
+		$(usex nls "--nls" "--no-nls")
+		$(usex phonehome "--phone-home" "--no-phone-home")
+		# not possible right now  --use-external-libs
+	)
+
+	waf-utils_src_configure "${myconf[@]}"
+}
+
+src_compile() {
+	waf-utils_src_compile
+	use nls && waf-utils_src_compile i18n
+}
+
+src_install() {
+	local s
+
+	waf-utils_src_install
+
+	mv ${PN}.1 ${PN}${SLOT}.1 || die
+	doman ${PN}${SLOT}.1
+
+	for s in 16 22 32 48 256 512; do
+		newicon -s ${s} gtk2_ardour/resources/Ardour-icon_${s}px.png ardour${SLOT}.png
+	done
+
+	# the build system still installs ardour6.png files so we get rid of those to not conflict with ardour:6
+	find "${D}/usr/share/icons/" -name ardour6.png -delete
+
+	sed -i \
+		-e "s/\(^Name=\).*/\1Ardour ${SLOT}/" \
+		-e 's/;AudioEditing;/;X-AudioEditing;/' \
+		build/gtk2_ardour/ardour${SLOT}.desktop || die
+	domenu build/gtk2_ardour/ardour${SLOT}.desktop
+
+	insinto /usr/share/mime/packages
+	newins build/gtk2_ardour/ardour.xml ardour${SLOT}.xml
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "Please do _not_ report problems with the package to ${PN} upstream."
+	elog "If you think you've found a bug, check the upstream binary package"
+	elog "before you report anything to upstream."
+}