[gentoo-commits] repo/gentoo:master commit in: dev-python/pandas/

["Michał Górny" <mgorny@gentoo.org>]

commit:     7ff088e015ea7dcd1e37c6b91306ab522e163e15
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 25 12:26:25 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Apr 25 15:00:12 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7ff088e0

dev-python/pandas: Bump to 2.0.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pandas/Manifest            |   1 +
 dev-python/pandas/pandas-2.0.1.ebuild | 219 ++++++++++++++++++++++++++++++++++
 2 files changed, 220 insertions(+)

diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index 455f65648fc5..cf96d3689861 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -2,3 +2,4 @@ DIST pandas-1.5.1.tar.gz 5199286 BLAKE2B 17d98870f3397d7a9289a18708021a614b1d456
 DIST pandas-1.5.2.tar.gz 5201551 BLAKE2B c6a8156a6c116f1b576837882e4ad4ada6cf21bf72acd673d74bdb1dda4f97f88a5e6422e8f8ad2fbbb85a334cd68cb0abae316d5826c54a85baf8b325ab6183 SHA512 1e6b653ff418c839895946123f90fffcfafd57f24dfbd6bae4e9988893b7d57d6276ed101112c8f9730af53f600d006fe3a53bbed597c0376856f2cfc90c1f05
 DIST pandas-1.5.3.tar.gz 5203060 BLAKE2B 846a6caa8ead6a2556303494f92e2091582d8fcde2aee424fa172c4e29c189a7305261f6a931a20249e969668646ff4a3d605ee1b57785fa3677dfbd137b3602 SHA512 3c725c33dcaf78b952d2eb966ced73ff0073162a01d3cbcb722d58d8f12a82163e6e684c27284c735bdfb32dea263b960f70f6a80ff93e6b316316d40835ae35
 DIST pandas-2.0.0.tar.gz 5271334 BLAKE2B 80782f407cb93866ca445518f45ea36e081b789d72ef597f6501746c41c1bb1000f183a7352e04194401d59c523ab796373445cddd42166c19f9d8cac522f426 SHA512 6a960275e03b1171cde1085cc0a853273c35377809eddc75c82bb6deb06c3ed499265efe88012771c86f86872a6f6b2d3e218bcb209259dcfc46781367cd2f51
+DIST pandas-2.0.1.tar.gz 5279594 BLAKE2B 84dbab2c6079c77eb7f367aaabc2f4d0c8205a3d8bd2e4db9f071cf1d25c53a32f91679ae7ff56e21e76447a675b4f4e7c660708f3e2a7a56753137018239dd6 SHA512 ecb150045c82ef649fcdd940c3b45884f0f9f8a51402b331fc247c148f669fe7bece33b331d1ddac84b7fef39d096ad7488057d3772e74d087ea26bb9cac3994

diff --git a/dev-python/pandas/pandas-2.0.1.ebuild b/dev-python/pandas/pandas-2.0.1.ebuild
new file mode 100644
index 000000000000..286d989ac800
--- /dev/null
+++ b/dev-python/pandas/pandas-2.0.1.ebuild
@@ -0,0 +1,219 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+
+inherit distutils-r1 multiprocessing optfeature virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="
+	https://pandas.pydata.org/
+	https://github.com/pandas-dev/pandas/
+	https://pypi.org/project/pandas/
+"
+SRC_URI="
+	https://github.com/pandas-dev/pandas/releases/download/v${PV}/${P}.tar.gz
+"
+S=${WORKDIR}/${P/_/}
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="doc full-support minimal test X"
+RESTRICT="!test? ( test )"
+
+RECOMMENDED_DEPEND="
+	>=dev-python/bottleneck-1.3.2[${PYTHON_USEDEP}]
+	>=dev-python/numexpr-2.7.1[${PYTHON_USEDEP}]
+"
+
+# TODO: add pandas-gbq to the tree
+# TODO: Re-add dev-python/statsmodel[python3_11] dep once it supports python3_11
+# https://github.com/statsmodels/statsmodels/issues/8287
+OPTIONAL_DEPEND="
+	>=dev-python/beautifulsoup4-4.9.3[${PYTHON_USEDEP}]
+	dev-python/blosc[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.1[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.6.3[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-3.6.1[${PYTHON_USEDEP}]
+	>=dev-python/openpyxl-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/pytables-3.6.1[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.4.16[${PYTHON_USEDEP}]
+	>=dev-python/tabulate-0.8.9[${PYTHON_USEDEP}]
+	>=dev-python/xarray-0.21.0[${PYTHON_USEDEP}]
+	>=dev-python/xlrd-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/xlsxwriter-1.4.3[${PYTHON_USEDEP}]
+	>=dev-python/xlwt-1.3.0[${PYTHON_USEDEP}]
+	!hppa? (
+		$(python_gen_cond_dep '
+			dev-python/statsmodels[${PYTHON_USEDEP}]
+		' python3_{8..10} )
+		>=dev-python/scipy-1.7.1[${PYTHON_USEDEP}]
+	)
+	X? (
+		|| (
+			>=dev-python/PyQt5-5.15.1[${PYTHON_USEDEP}]
+			>=dev-python/QtPy-2.2.0[${PYTHON_USEDEP}]
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+COMMON_DEPEND="
+	>=dev-python/numpy-1.23.2[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.2[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2020.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${COMMON_DEPEND}
+	>=dev-python/cython-0.29.33[${PYTHON_USEDEP}]
+	>=dev-python/versioneer-0.28[${PYTHON_USEDEP}]
+	doc? (
+		${VIRTUALX_DEPEND}
+		app-text/pandoc
+		>=dev-python/beautifulsoup4-4.9.3[${PYTHON_USEDEP}]
+		>=dev-python/html5lib-1.1[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		>=dev-python/lxml-4.6.3[${PYTHON_USEDEP}]
+		>=dev-python/matplotlib-3.6.1[${PYTHON_USEDEP}]
+		dev-python/nbsphinx[${PYTHON_USEDEP}]
+		>=dev-python/numpydoc-0.9.1[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-3.0.7[${PYTHON_USEDEP}]
+		>=dev-python/pytables-3.6.1[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/xlrd-2.0.1[${PYTHON_USEDEP}]
+		dev-python/xlwt[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		x11-misc/xclip
+	)
+	test? (
+		${VIRTUALX_DEPEND}
+		${RECOMMENDED_DEPEND}
+		${OPTIONAL_DEPEND}
+		>=dev-python/beautifulsoup4-4.9.3[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.34.2[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-3.0.7[${PYTHON_USEDEP}]
+		>=dev-python/pymysql-1.0.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.17.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/psycopg-2.8.6:2[${PYTHON_USEDEP}]
+		>=dev-python/xlsxwriter-1.4.3[${PYTHON_USEDEP}]
+		x11-misc/xclip
+		x11-misc/xsel
+	)
+"
+# dev-python/statsmodels invokes a circular dep
+#  hence rm from doc? ( ), again
+RDEPEND="
+	${COMMON_DEPEND}
+	!minimal? ( ${RECOMMENDED_DEPEND} )
+	full-support? ( ${OPTIONAL_DEPEND} )
+"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^              'sphinx.ext.intersphinx',/d" \
+		-i doc/source/conf.py || die
+
+	# unnecessary with system tzdata
+	sed -i -e '/tzdata/d' pyproject.toml || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile -j1
+}
+
+python_compile_all() {
+	# To build docs the need be located in $BUILD_DIR,
+	# else PYTHONPATH points to unusable modules.
+	if use doc; then
+		cd "${BUILD_DIR}"/lib || die
+		cp -ar "${S}"/doc . && cd doc || die
+		LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# test for rounding errors, fails if we have better precision
+		# e.g. on amd64 with FMA or on arm64
+		# https://github.com/pandas-dev/pandas/issues/38921
+		pandas/tests/window/test_rolling.py::test_rolling_var_numerical_issues
+
+		# TODO
+		pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated
+		pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated_direct
+		pandas/tests/io/test_clipboard.py::TestClipboard::test_raw_roundtrip
+		pandas/tests/copy_view/test_internals.py::test_switch_options
+
+		# TODO: xdist?
+		pandas/tests/test_expressions.py::TestExpressions::test_run_binary
+
+		# TODO: these require a running db server
+		pandas/tests/io/test_sql.py::TestMySQLAlchemy
+		pandas/tests/io/test_sql.py::TestMySQLAlchemyConn
+		pandas/tests/io/test_sql.py::TestPostgreSQLAlchemy
+		pandas/tests/io/test_sql.py::TestPostgreSQLAlchemyConn
+
+		# OOMs
+		pandas/tests/io/parser/test_c_parser_only.py::test_bytes_exceed_2gb
+
+		# xarray version incompatibility
+		pandas/tests/test_downstream.py::test_xarray_cftimeindex_nearest
+
+		# warning from dask
+		pandas/tests/test_downstream.py::test_construct_dask_float_array_int_dtype_match_ndarray
+
+		# TODO: mpl incompatibility?
+		pandas/tests/plotting/frame/test_frame.py::TestDataFramePlots::test_plain_axes
+	)
+
+	local -x LC_ALL=C.UTF-8
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+	epytest pandas --skip-slow --skip-network -m "not single" \
+		-n "$(makeopts_jobs)" || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+		einfo "An initial build of docs is absent of references to statsmodels"
+		einfo "due to circular dependency. To have them included, emerge"
+		einfo "statsmodels next and re-emerge pandas with USE doc"
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
+	optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
+	optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup4 dev-python/html5lib dev-python/lxml
+	optfeature "for msgpack compression using blosc" dev-python/blosc
+	optfeature "Template engine for conditional HTML formatting" dev-python/jinja
+	optfeature "Plotting support" dev-python/matplotlib
+	optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-3.0.7" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+	optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.6.1"
+	optfeature "R I/O support" dev-python/rpy
+	optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
+	optfeature "SQL database support" ">=dev-python/sqlalchemy-1.4.16"
+	optfeature "miscellaneous statistical functions" dev-python/scipy
+	optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/QtPy dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}