[gentoo-commits] repo/gentoo:master commit in: dev-util/gef/

["Sam James" <sam@gentoo.org>]

commit:     02adcaab22a7b10ef07fdb62c162d6e6a19392a1
Author:     Mario Haustein <mario.haustein <AT> hrz <DOT> tu-chemnitz <DOT> de>
AuthorDate: Wed Apr 19 21:03:23 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Apr 25 01:57:14 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=02adcaab

dev-util/gef: add 2023.06

Signed-off-by: Mario Haustein <mario.haustein <AT> hrz.tu-chemnitz.de>
Closes: https://github.com/gentoo/gentoo/pull/30656
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/gef/Manifest           |  1 +
 dev-util/gef/gef-2023.06.ebuild | 82 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 83 insertions(+)

diff --git a/dev-util/gef/Manifest b/dev-util/gef/Manifest
index e8817b004f70..884984b821e7 100644
--- a/dev-util/gef/Manifest
+++ b/dev-util/gef/Manifest
@@ -1 +1,2 @@
 DIST gef-2022.06.tar.gz 217503 BLAKE2B b7038e0519f216669c38bdda7e12375fb1c9e5278c8b617df73932a750ee6552531929eebcac22321607f51592834ece70c850ce0ba4629bc383731bc8803bb3 SHA512 585bad8655a5208d060b1ccf455ab87527e47949fce1df188a5ac970ccd1bbfbdd87151f7a940edcfb879dd0ea846b5c4a8650fed856cd5dcaec0ddd3581f100
+DIST gef-2023.06.tar.gz 187126 BLAKE2B e44606249d42760caf4e47f1b2f5e4592255fd8b81b28cab313352d10dcbc47a79a0130e102cc2618fe88dc47a5589ed6bee3e7d80878cc66f5e9abd775c103e SHA512 5362234ae6b753abe719280640148978cd25f535249a1ad9311ebd66f99138d59d5b9f07e9e93ebe00aab4702c73229c2f3d92e2d70fb5daf3f30a49e4d3b8ff

diff --git a/dev-util/gef/gef-2023.06.ebuild b/dev-util/gef/gef-2023.06.ebuild
new file mode 100644
index 000000000000..d6b6691121d0
--- /dev/null
+++ b/dev-util/gef/gef-2023.06.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/mkdocs-material
+"
+
+inherit python-single-r1 docs wrapper
+
+DESCRIPTION="A GDB Enhanced Features for exploit devs & reversers"
+HOMEPAGE="https://github.com/hugsy/gef"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/hugsy/gef"
+else
+	SRC_URI="https://github.com/hugsy/gef/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+# Seem to hang right now?
+RESTRICT="!test? ( test ) test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-util/ropper[${PYTHON_SINGLE_USEDEP}]
+	sys-devel/gdb[python,${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-libs/capstone[python,${PYTHON_USEDEP}]
+		dev-libs/keystone[python,${PYTHON_USEDEP}]
+		dev-python/pylint[${PYTHON_USEDEP}]
+		dev-util/unicorn[python,${PYTHON_USEDEP}]
+	')"
+
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)"
+
+DOCS=( README.md )
+
+src_prepare() {
+	default
+
+	sed -i -e '/pylint/d' tests/requirements.txt || die
+}
+
+src_compile() {
+	# Tries to compile tests
+	:
+
+	docs_compile
+}
+
+src_install() {
+	insinto "/usr/share/${PN}"
+	doins -r *.py
+
+	python_optimize "${ED}/usr/share/${PN}"
+
+	make_wrapper "gdb-gef" \
+		"gdb -x \"/usr/share/${PN}/gef.py\"" || die
+
+	einstalldocs
+}
+
+pkg_postinst() {
+	einfo "\nUsage:"
+	einfo "    ~$ gdb-gef <program>\n"
+}